From c948ef6f3cc0d058d0a9ae090a816f448ff0fc90 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sat, 24 Apr 2021 12:03:30 +0200
Subject: kde-apps/kwave: 21.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/kwave/Manifest             |  1 +
 kde-apps/kwave/kwave-21.04.0.ebuild | 87 +++++++++++++++++++++++++++++++++++++
 2 files changed, 88 insertions(+)
 create mode 100644 kde-apps/kwave/kwave-21.04.0.ebuild

(limited to 'kde-apps/kwave')

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index 3f6e50bcf089..c9987f144cce 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1 +1,2 @@
 DIST kwave-20.12.3.tar.xz 6911104 BLAKE2B 17cc2c5a1b14b8c46548fc3d8c65a37c5f42f49a6656f54cef4549d5b8fbda08f3e491a11a5c46e328c3abc6fbcb4e09dc45529fe14e7a78ab031b1d0937cbdf SHA512 9854836fc328dfded8494c03137d940c8ecfc0409e0f8ea85b34d51fb1f7d077c3f3e9e8e439acdf9da66037de0da65dabe8db7422b5bccbadcbaff599e9893a
+DIST kwave-21.04.0.tar.xz 6880684 BLAKE2B 619ac081b912de78609cf6cbe77d6d6831a5bbd2a52732e685550a16a26c2f7e733e08d462b08172a91bf4dc49a22a50275e2642966da2cf590cb1d2639502ba SHA512 84e704e96b39d7685629c6a90c59b99b6ea44ce28525c148c79ba7442254aa5a3603e626b8e33326274e12903995b560cb89d288120b7d0154306bb62d180f7a
diff --git a/kde-apps/kwave/kwave-21.04.0.ebuild b/kde-apps/kwave/kwave-21.04.0.ebuild
new file mode 100644
index 000000000000..ca7d1cee7548
--- /dev/null
+++ b/kde-apps/kwave/kwave-21.04.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/en/kwave"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}
-- 
cgit v1.2.3-65-gdbad