From 970472e195c28544c78509265fa2b8a7864cdf13 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Mon, 6 Nov 2023 12:45:13 +0100
Subject: dev-python/dirty-equals: Remove the dep on <dev-python/pydantic-2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Remove the dependency on <dev-python/pydantic-2.  It is used only
for the IsUrl class, and this class is not used by any reverse
dependency.  Furthermore, there does not seem to be any progress
on fixing it to work with >=dev-python/pydantic-2.

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../dirty-equals/dirty-equals-0.6.0-r2.ebuild      | 47 ----------------
 .../dirty-equals/dirty-equals-0.6.0-r3.ebuild      | 65 ++++++++++++++++++++++
 2 files changed, 65 insertions(+), 47 deletions(-)
 delete mode 100644 dev-python/dirty-equals/dirty-equals-0.6.0-r2.ebuild
 create mode 100644 dev-python/dirty-equals/dirty-equals-0.6.0-r3.ebuild

(limited to 'dev-python')

diff --git a/dev-python/dirty-equals/dirty-equals-0.6.0-r2.ebuild b/dev-python/dirty-equals/dirty-equals-0.6.0-r2.ebuild
deleted file mode 100644
index 45dacef97239..000000000000
--- a/dev-python/dirty-equals/dirty-equals-0.6.0-r2.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 2022-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{10..12} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="Doing dirty (but extremely useful) things with equals"
-HOMEPAGE="
-	https://dirty-equals.helpmanual.io/
-	https://github.com/samuelcolvin/dirty-equals/
-	https://pypi.org/project/dirty-equals/
-"
-SRC_URI="
-	https://github.com/samuelcolvin/dirty-equals/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
-
-RDEPEND="
-	<dev-python/pydantic-2[${PYTHON_USEDEP}]
-	>=dev-python/pytz-2021.3[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/packaging[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		# require unpackaged pytest-examples
-		tests/test_docs.py
-	)
-
-	local -x TZ=UTC
-	epytest
-}
diff --git a/dev-python/dirty-equals/dirty-equals-0.6.0-r3.ebuild b/dev-python/dirty-equals/dirty-equals-0.6.0-r3.ebuild
new file mode 100644
index 000000000000..d11e92a9c462
--- /dev/null
+++ b/dev-python/dirty-equals/dirty-equals-0.6.0-r3.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Doing dirty (but extremely useful) things with equals"
+HOMEPAGE="
+	https://dirty-equals.helpmanual.io/
+	https://github.com/samuelcolvin/dirty-equals/
+	https://pypi.org/project/dirty-equals/
+"
+SRC_URI="
+	https://github.com/samuelcolvin/dirty-equals/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
+
+RDEPEND="
+	>=dev-python/pytz-2021.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# hackaround IsUrl use in global scope (for parametrize)
+	if ! has_version "dev-python/pydantic[${PYTHON_USEDEP}]"; then
+		sed -i -e 's:IsUrl([^)]*):IsUrl:g' tests/test_other.py || die
+	fi
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# require unpackaged pytest-examples
+		tests/test_docs.py
+	)
+	local args=()
+
+	if ! has_version "<dev-python/pydantic-2[${PYTHON_USEDEP}]"; then
+		args+=(
+			# IsUrl is not used in any revdeps, and it's broken
+			# with pydantic-2
+			# https://github.com/samuelcolvin/dirty-equals/issues/72
+			-k "not is_url"
+		)
+	fi
+
+	local -x TZ=UTC
+	epytest "${args[@]}"
+}
-- 
cgit v1.2.3-65-gdbad