From 31b0c969d35a867a09891a405d9a9e06dd3bfe8f Mon Sep 17 00:00:00 2001
From: Maciej Barć <xgqt@gentoo.org>
Date: Mon, 23 Oct 2023 22:01:54 +0200
Subject: app-text/pandoc-bin: update blockers
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/916190
Signed-off-by: Maciej Barć <xgqt@gentoo.org>
---
 app-text/pandoc-bin/pandoc-bin-3.1.8-r1.ebuild | 62 ++++++++++++++++++++++++++
 app-text/pandoc-bin/pandoc-bin-3.1.8.ebuild    | 56 -----------------------
 2 files changed, 62 insertions(+), 56 deletions(-)
 create mode 100644 app-text/pandoc-bin/pandoc-bin-3.1.8-r1.ebuild
 delete mode 100644 app-text/pandoc-bin/pandoc-bin-3.1.8.ebuild

(limited to 'app-text')

diff --git a/app-text/pandoc-bin/pandoc-bin-3.1.8-r1.ebuild b/app-text/pandoc-bin/pandoc-bin-3.1.8-r1.ebuild
new file mode 100644
index 000000000000..e37ad183025c
--- /dev/null
+++ b/app-text/pandoc-bin/pandoc-bin-3.1.8-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=${PN//-bin/}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Conversion between markup formats (binary package)"
+HOMEPAGE="https://pandoc.org/
+	https://github.com/jgm/pandoc/"
+
+BASE_URI="https://github.com/jgm/${MY_PN}/releases/download/${PV}/${MY_P}"
+SRC_URI="
+	amd64? ( ${BASE_URI}-linux-amd64.tar.gz )
+	arm64? ( ${BASE_URI}-linux-arm64.tar.gz )
+"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="-* amd64 arm64"
+IUSE="+pandoc-symlink"
+
+RDEPEND="
+	pandoc-symlink? (
+		!${CATEGORY}/${MY_PN}
+		!app-text/pandoc-cli
+		!dev-haskell/pandoc[doc]
+	)
+"
+
+QA_FLAGS_IGNORED="usr/bin/${PN}"
+QA_PRESTRIPPED="${QA_FLAGS_IGNORED}"
+
+src_unpack() {
+	default
+
+	# Manpages are gzipped.
+	unpack "${S}"/share/man/man1/*.1.gz
+}
+
+src_install() {
+	exeinto /usr/bin
+	newexe bin/${MY_PN} ${PN}
+	dosym ${PN} /usr/bin/pandoc-lua-bin
+	dosym ${PN} /usr/bin/pandoc-server-bin
+
+	newman "${WORKDIR}"/${MY_PN}-lua.1 pandoc-lua-bin.1
+	newman "${WORKDIR}"/${MY_PN}-server.1 pandoc-server-bin.1
+	newman "${WORKDIR}"/${MY_PN}.1 ${PN}.1
+
+	if use pandoc-symlink ; then
+		dosym ${PN} /usr/bin/${MY_PN}
+		dosym pandoc-lua-bin /usr/bin/${MY_PN}-lua
+		dosym pandoc-server-bin /usr/bin/${MY_PN}-server
+
+		dosym ${PN}.1 /usr/share/man/man1/${MY_PN}.1
+		dosym pandoc-lua-bin.1 /usr/share/man/man1/${MY_PN}-lua.1
+		dosym pandoc-server-bin.1 /usr/share/man/man1/${MY_PN}-server.1
+	fi
+}
diff --git a/app-text/pandoc-bin/pandoc-bin-3.1.8.ebuild b/app-text/pandoc-bin/pandoc-bin-3.1.8.ebuild
deleted file mode 100644
index 254155b50637..000000000000
--- a/app-text/pandoc-bin/pandoc-bin-3.1.8.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-MY_PN=${PN//-bin/}
-MY_P=${MY_PN}-${PV}
-
-DESCRIPTION="Conversion between markup formats (binary package)"
-HOMEPAGE="https://pandoc.org/
-	https://github.com/jgm/pandoc/"
-
-BASE_URI="https://github.com/jgm/${MY_PN}/releases/download/${PV}/${MY_P}"
-SRC_URI="
-	amd64? ( ${BASE_URI}-linux-amd64.tar.gz )
-	arm64? ( ${BASE_URI}-linux-arm64.tar.gz )
-"
-S="${WORKDIR}"/${MY_P}
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="-* amd64 arm64"
-IUSE="+pandoc-symlink"
-
-RDEPEND="pandoc-symlink? ( !${CATEGORY}/${MY_PN} )"
-
-QA_FLAGS_IGNORED="usr/bin/${PN}"
-QA_PRESTRIPPED="${QA_FLAGS_IGNORED}"
-
-src_unpack() {
-	default
-
-	# Manpages are gzipped.
-	unpack "${S}"/share/man/man1/*.1.gz
-}
-
-src_install() {
-	exeinto /usr/bin
-	newexe bin/${MY_PN} ${PN}
-	dosym ${PN} /usr/bin/pandoc-lua-bin
-	dosym ${PN} /usr/bin/pandoc-server-bin
-
-	newman "${WORKDIR}"/${MY_PN}-lua.1 pandoc-lua-bin.1
-	newman "${WORKDIR}"/${MY_PN}-server.1 pandoc-server-bin.1
-	newman "${WORKDIR}"/${MY_PN}.1 ${PN}.1
-
-	if use pandoc-symlink ; then
-		dosym ${PN} /usr/bin/${MY_PN}
-		dosym pandoc-lua-bin /usr/bin/${MY_PN}-lua
-		dosym pandoc-server-bin /usr/bin/${MY_PN}-server
-
-		dosym ${PN}.1 /usr/share/man/man1/${MY_PN}.1
-		dosym pandoc-lua-bin.1 /usr/share/man/man1/${MY_PN}-lua.1
-		dosym pandoc-server-bin.1 /usr/share/man/man1/${MY_PN}-server.1
-	fi
-}
-- 
cgit v1.2.3-65-gdbad