2 files changed, 64 insertions, 0 deletions
diff --git a/x11-misc/j4-dmenu-desktop/Manifest b/x11-misc/j4-dmenu-desktop/Manifest
index 0f75d6cf1999..11475aab7087 100644
--- a/x11-misc/j4-dmenu-desktop/Manifest
+++ b/x11-misc/j4-dmenu-desktop/Manifest
@@ -1 +1,2 @@
 DIST j4-dmenu-desktop-2.18.tar.gz 34785 BLAKE2B 26d5861d6d7ddcd9653a464d1175d19532001705de193811087fd42fddbdead89b8d49bd14f8e323288d6a7ba37bd4e11f4c7c52dd9b0a454f95a83a14853bcb SHA512 f8b0c825d567d60da0fb418e6f0b24a6d9daa9fb142b194b0a8b249303f4e09b6694fce72bf031007ac67253e488fc7666d4ba7beb032bc74cc2a32aca0f6c96
+DIST j4-dmenu-desktop-3.0.tar.gz 87265 BLAKE2B 63fb87b98e500b1adba188b0b523ef0c2449826e7fa5b5ca442c451ff5003160a9f6803cdb3c918da366447355b9312b9bf0ece4a7d2eebe427da4edf219f881 SHA512 9823428477600f3ab284dc80f6baef20b5f22b34269317f491c65e7331817f5a0115af20e05acb7f2c66f021f7c2d683c332a334f03088d867319926eaa4568a
diff --git a/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-3.0.ebuild b/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-3.0.ebuild
new file mode 100644
index 000000000000..b2f37ec6fa79
--- /dev/null
+++ b/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-3.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_PV="r${PV}"
+
+DESCRIPTION="A fast desktop replacement for i3-dmenu-desktop"
+HOMEPAGE="https://github.com/enkore/j4-dmenu-desktop"
+SRC_URI="https://github.com/enkore/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+dmenu test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-cpp/catch:1 )"
+DEPEND="
+	dev-libs/libfmt:=
+	dev-libs/spdlog:=
+"
+RDEPEND="
+	${DEPEND}
+	dmenu? ( x11-misc/dmenu )
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Respect users CFLAGS
+	sed -i -e "s/-pedantic -O2//" CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DNO_DOWNLOAD="ON"
+		-DWITH_GIT_CATCH="no"
+		-DWITH_TESTS="$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	doman j4-dmenu-desktop.1
+}
+
+pkg_postinst() {
+	if ! use dmenu; then
+		elog "As you have disabled the 'dmenu' use flag,"
+		elog "x11-misc/dmenu won't be installed by default."
+		elog ""
+		elog "Since x11-misc/j4-dmenu-desktop uses x11-misc/dmenu as default,"
+		elog "you must configure your own replacement with --dmenu=<command>,"
+		elog "as otherwise it won't work."
+	fi
+}