3 files changed, 270 insertions, 0 deletions
diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index 01fa2b6c8ec4..01230f49129e 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1,5 +1,7 @@
 DIST qmmp-0.10.5.tar.bz2 1342190 SHA256 c1ac6aa5241f0ade901793a2e581183903e6c861a9f275f3f9735753f5e463ac SHA512 24751504101d3cf753f032515b61faf0e7f3b3b70ac1a8f7742e650868be3adb7ecae54c01bc5e7e407c6f3796da0a4347c908d976205448743163b22e211942 WHIRLPOOL 12ba0e0ef6bd3116326af6624628ebf2128d9d882e32ef3474bc4a6d4047c68de404bec07e893f101bdd8b6a0b843f5e3b1941e537fcdf436997a545b19ee027
 DIST qmmp-0.10.6.tar.bz2 1341977 SHA256 9ec1df1128182dfe1d5686bfb857148577f4f2f1a10e5a0459998464ae6cd272 SHA512 fd549a381f957d38923fa675b284c0d57128eecb88d672d2ac82b8fb2e9b40004fd1f870425bd356badd3394ba36b8b9abfc7b61cc3b650512a9f203e0745db7 WHIRLPOOL 3039fb8d96bfde5b84a830fd6bcecb70dd94a3b7376a902345fb8166c77f6579df2bd67a3363119d15720ad65cbe1ac4de204d943c68962d25e1f0ebdafeb906
+DIST qmmp-0.10.8.tar.bz2 1343497 SHA256 0458bb57a89c8891481ed854ef6b9c0a5f6d1e27eb86a1ac6b7c14a28abcc353 SHA512 8dc67b8b9da6e0c105287967c88c6b8182f9985523ea5a0fdecef240e2f5bec810090be2644ac8eb701133d2a483e9c2971db7414f4247dc67d04ce5b2e556bc WHIRLPOOL 4c4374777ede2100f4801e140051fc37ce2f89032c8a1af3de05a4ac3a448f3f74e96c04f03b43e2da609d48d1fd336b5136571c3ed07805b2f7ab495426c65e
 DIST qmmp-1.0.10.tar.bz2 1107784 SHA256 02bcd01b1d8f6ca8b805a5deaeaa059ee44a38fafd20bec7ee3560a021250ee3 SHA512 45231ef8b1f0a0825336752fe9314cc0df1b937ebcf85b18c89c66e52f38cf69583eccd8ffcf92d89add11643e1f40ccf0fe720fd6279f3cf4f73db336d4d59b WHIRLPOOL 0bb7d873e58b8cdbbb71576af3080031fc0e03cc3fc3153812e2a105bad40f02ac4a3838454aef5551890e278d050bbe04caf0e77ddb1cd3b43f7fd2c77cd5e7
 DIST qmmp-1.1.6.tar.bz2 1133591 SHA256 aff540547ed1e804b964edcb1eeb418c12906a88ab07e44fa4d88b066cd81015 SHA512 1bef5e6414021e0dfb213bc83818004b66b81cba81c0f4b53233acc9cf85cbf1f2f7c7bf15891f744fb9822e6ffabf16c87625617525bca5911cfcc99cf86eab WHIRLPOOL 129e429670280b2833c820ccd7174c2d263511bef71fdf614be69c95df6ff32f18447d854b7340fd7563543b9be24caf7ace6076db386e447a65a37c956e21de
 DIST qmmp-1.1.7.tar.bz2 1135005 SHA256 464f79d9a54e6456c5abcb570d7f062e48d3eaa3d60ad2b09c58bc62af5b87a7 SHA512 058187d34b848c0917077a167bcb52c63e39b5150409295ea658484d99fcd5582f7871979d3d3eea40aa97f0d9bf2a2d72ae721b827bcc0366b1bbc652aa3a72 WHIRLPOOL 1c1f22a22329619f63a1a24590b41b352d398bb4653117c81918b2e940e887c6aaa06f178674a97893de7418673022bdc800a09643d3fb38096f6dc78b7774c3
+DIST qmmp-1.1.8.tar.bz2 1135090 SHA256 17bc88d00ea0753e6fc7273592e894320f05cae807f7cc2c6a5351c73217f010 SHA512 f5335922febcf8397b0d8d9b83b305752a85e036ffc33b950107344eb344ca5737db287a57876c7d67ebfe78dfdd0697d87105df73e5eedf248923d9991f5edd WHIRLPOOL 0fa5ae11c93f3b0a47a692007a6e463dcc3c090a8bba964f23f6751a91883d67baec9d0d01ffbd615c281eef5797ac3bcbc011fad47fe9656314e0a4be8c5b68
diff --git a/media-sound/qmmp/qmmp-0.10.8.ebuild b/media-sound/qmmp/qmmp-0.10.8.ebuild
new file mode 100644
index 000000000000..9c17a3c486ff
--- /dev/null
+++ b/media-sound/qmmp/qmmp-0.10.8.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+[ "$PV" == "9999" ] && inherit subversion
+
+DESCRIPTION="Qt4-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~ppc ~x86"
+else
+	ESVN_REPO_URI="https://svn.code.sf.net/p/qmmp-dev/code/trunk/qmmp/"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="analyzer aac +alsa bs2b cdda cover crossfade cue curl enca ffmpeg flac jack game kde ladspa
+lyrics +mad midi mms modplug mplayer mpris musepack notifier opus oss projectm
+pulseaudio qsui scrobbler sndfile soxr stereo tray udisks +vorbis wavpack"
+
+RDEPEND="media-libs/taglib
+	dev-qt/qtcore:4
+	dev-qt/qtdbus:4
+	dev-qt/qtgui:4
+	dev-qt/qtmultimedia:4
+	alsa? ( media-libs/alsa-lib )
+	bs2b? ( media-libs/libbs2b )
+	cdda? ( dev-libs/libcdio-paranoia )
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	aac? ( media-libs/faad2 )
+	enca? ( app-i18n/enca )
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( media-libs/libmad )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	vorbis? ( media-libs/libvorbis
+		media-libs/libogg )
+	jack? ( media-sound/jack-audio-connection-kit
+		media-libs/libsamplerate )
+	ffmpeg? ( virtual/ffmpeg )
+	opus? ( media-libs/opusfile )
+	projectm? ( media-libs/libprojectm
+		dev-qt/qtopengl:4 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	wavpack? ( media-sound/wavpack )
+	scrobbler? ( net-misc/curl )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )"
+DEPEND="${RDEPEND}"
+
+DOCS="AUTHORS ChangeLog README"
+
+CMAKE_IN_SOURCE_BUILD="1"
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FFMPEG_LEGACY=OFF
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_KDENOTIFY="$(usex kde)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPRIS="$(usex mpris)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_UDISKS=OFF
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+		)
+
+	cmake-utils_src_configure
+}
diff --git a/media-sound/qmmp/qmmp-1.1.8.ebuild b/media-sound/qmmp/qmmp-1.1.8.ebuild
new file mode 100644
index 000000000000..d7b854b1781b
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.1.8.ebuild
@@ -0,0 +1,146 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+[[ ${PV} = 9999 ]] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	QMMP_DEV_BRANCH="1.1"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer bs2b cdda cover crossfade cue curl +dbus enca ffmpeg flac game gnome
+jack ladspa libav lyrics +mad midi mms modplug mplayer musepack notifier opus oss projectm
+pulseaudio qsui qtmedia scrobbler sid sndfile soxr stereo tray udisks +vorbis wavpack"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio
+		dev-libs/libcdio-paranoia
+	)
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:= )
+		libav? ( media-video/libav:= )
+	)
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		media-sound/jack-audio-connection-kit
+	)
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( media-libs/libmad )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	projectm? (
+		dev-qt/qtgui:5[-gles2]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm
+	)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	sndfile? ( media-libs/libsndfile )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+REQUIRED_USE="gnome? ( dbus ) udisks? ( dbus )"
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake-utils_src_configure
+}