www-client/opera-developer: automated bump (87.0.4374.0)

Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 159 insertions, 0 deletions

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index cdd26ec04b40..dad56e418089 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,5 +1,6 @@
 DIST opera-developer_86.0.4351.0_amd64.deb 83885412 BLAKE2B 0503f7fe19ae650b58e59cb98b1e6ce23d075e01f56e60a37f0fcba786041d88cbc49bb1ee8526ba48b6762d32b925f66176ca31e176f2011997555b32a108c7 SHA512 d24a9e34f86356153e0bb4a03a512c26d917b0264e311e3653fc17de687ec819c498aafcdb3878e7c9d316ecbaa09e27881e7c0f231e72c92fa3a93786146c04
 DIST opera-developer_86.0.4359.0_amd64.deb 84302996 BLAKE2B b0d847f05a724026e5eed29f995a51db7d379f093a1bd03fa14ffa83d19426ef59e2defeb6a9fe8b660c6d7c1119308079b467151b8389820d12536cc62d8a1b SHA512 6720d1aa7ccf968419fa85c8d307db7bf1d74669a89c42ada8ec1f3157f58a635ae3e903a1dd0cb01f729921dbde646cab7ba103db932a7a085fa08bd5173f83
 DIST opera-developer_87.0.4366.0_amd64.deb 84566188 BLAKE2B e725f0cc2b06d72131fc4a5b9a2f090bfeef388669582a12e863e3c1f50ea8a0591c5177cbd9cba3338f7e1d704400f580108b689d86b9a5ecc4a7c168d947d2 SHA512 9f0a3bcf64b3fbe85e81bb9db275799bd18681db288d1ebcb87d1dbe7881a66ae577e005620b6b0c9933cd0427ce6a76ce5da4a5e2799f617d3ef24fe2dfc605
+DIST opera-developer_87.0.4374.0_amd64.deb 84474932 BLAKE2B 414eb6032c03e6107f88daceb48ab480422addc7cfb1e14cdb81277778033a91e19f34350071cae7d057344165a30d865839ed0667068b2683808764d77860e4 SHA512 46d159f72e094cb516a1a76667c4c357b8b5e61bfa40eb8355856ba5eb8ff924170ba398e556252e7c8c527a83db0cdaef39db4393f29c9d344e0950bbcce550
 DIST opera-ffmpeg-codecs-100.0.4896.20.tar.xz 1393360 BLAKE2B be608a42042b2713fff66716c171959609e06d94b6c56cd8081e05313915378eff25c7098228ff6727a430c9f02bd4e9c9dcce4e715f09e10ac62d89ccd6ae1c SHA512 7dab4a091ac3562cd9c09cf37bc70edf9000ad1b3d31f27278e2edc68b9f55fd4f821ebc90a761ae5803542195718015c859e107344b31a5f7f9ad6cf028df42
 DIST opera-ffmpeg-codecs-99.0.4818.2.tar.xz 1394204 BLAKE2B b18569d0adef52d88f0c39391da330e3df5fae1fa323dcda82d6d432c5e8bc9c24008cbff61eeded6a61255ef0fabf4a1cef554b3acad42c500cbfde89c254dc SHA512 8ab7836c663a540e34a92f7a38571b968bf23fd44af554ee8ba3b7affb991031bf9aba2a848e68e478e7431efccf4410c7398bacee831f1b16be91dd65b151bb
diff --git a/www-client/opera-developer/opera-developer-87.0.4374.0.ebuild b/www-client/opera-developer/opera-developer-87.0.4374.0.ebuild
new file mode 100644
index 000000000000..d1fbcd0074a1
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-87.0.4374.0.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="100.0.4896.20"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}