www-apps/nikola: version bump to 7.6.3

Bump pygal dep to 2.0.1

Package-Manager: portage-2.2.20.1

2 files changed, 70 insertions, 0 deletions

diff --git a/www-apps/nikola/Manifest b/www-apps/nikola/Manifest
index 7bc59a8521db..92383e13e6cc 100644
--- a/www-apps/nikola/Manifest
+++ b/www-apps/nikola/Manifest
@@ -3,3 +3,4 @@ DIST nikola-7.2.0.tar.gz 1843614 SHA256 05bf72f9894eaf83a61ebc1386ab61ffa1be1e49
 DIST nikola-7.6.0.tar.gz 2457863 SHA256 b68d4f6511d5b1c38c9ab9030dd51ceb4a7357a08d5cb852f7e3a7503b9ddc36 SHA512 b13d9f733eb4e67bfa237788b67f01cb114c25ea064c44fa12c84e2dee2ddb25d0cac1b105b66cc8a42cf55f514a9567a1e62be8cdac72bd982dccc5c4ae4fff WHIRLPOOL c359faef51b50faa3cb12a7662c8e9a277a067c92183674cf10a715bf5a4ed6ee039d174be3567d1404588d5ef3fe449829b91287003182220d8dc3fc685e2bd
 DIST nikola-7.6.1.tgz 2290620 SHA256 7c11e3a91456787e5569c78d13641bc5831efc9d71b5a488c389c97bc8017c54 SHA512 8be2378f9c5e121c0923010bc92f9defdbc9f3ec57b4b7cc491a84ebbc5a3c987d8eaba7a7a5fae432350e38eb190bbfab11044dbe74f32eda6a063649267e89 WHIRLPOOL e4d634846d8063c710c127897e107fc17ed8c99e99bbfda621e656f3fe9fae7377a51119a7e383644e2ca3f4dea2efffcbdb034fb264dd55940d19ef80c3d04d
 DIST nikola-7.6.2.tar.gz 2305251 SHA256 569bf6a097021161d194845dc0c0e3dbbf028b2d90fb0934921e13bfcbb5b2fc SHA512 f5b146ab2ed880a2caf4afc9cd25bcb1fb5b64d99b415c08d45fbe1cd925e5d5d6a03c6b966736dc85311684d4406c410329f834cd68b73bd3e49d7458c3c7b0 WHIRLPOOL 3497fb211c740259f5603e823fbb39d6691fef4b2da02f89dde261bdcf438020326ce9baf76fdc4ffab1bb928d01d3b773cbbb7f1f018c22d3dfcbea5554619f
+DIST nikola-7.6.3.tar.gz 2365230 SHA256 f07a0eb00cb1653bf778dea0d7fe6983dce01f845e6b53ba1ce1678ff2c87c3d SHA512 eef8b8cc4d3af03e009ae31247ba19eb37b9a3ed9691d942b44291562df80d0f12b8306a2d7c0a2a1fb0555f700da09db06a1b002ed58c0338234d2ca2336b5b WHIRLPOOL 5584f1254503c89044822bf6aa51a487ffcd0863f351fee41195217b596a549d2160470f63b0ce60f4131533577adf88d199a818a32caf351dd1edcf350545a7
diff --git a/www-apps/nikola/nikola-7.6.3.ebuild b/www-apps/nikola/nikola-7.6.3.ebuild
new file mode 100644
index 000000000000..994f72e1fdfe
--- /dev/null
+++ b/www-apps/nikola/nikola-7.6.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+inherit distutils-r1
+
+DESCRIPTION="A static website and blog generator"
+HOMEPAGE="http://getnikola.com/"
+SRC_URI="http://dev.gentoo.org/~yngwin/distfiles/a-study-in-scarlet.txt"
+MY_PN="Nikola"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://github.com/ralsina/${PN}.git"
+else
+	SRC_URI+=" mirror://pypi/${MY_PN:0:1}/${MY_PN}/${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT Apache-2.0 CC0-1.0 public-domain"
+SLOT="0"
+IUSE="assets charts ghpages hyphenation ipython jinja markdown watchdog webmedia websocket"
+RESTRICT="test" # needs coveralls
+
+DEPEND=">=dev-python/docutils-0.12[${PYTHON_USEDEP}]" # needs rst2man to build manpage
+RDEPEND="${DEPEND}
+	>=dev-python/blinker-1.3[${PYTHON_USEDEP}]
+	>=dev-python/doit-0.28.0[${PYTHON_USEDEP}]
+	>=dev-python/logbook-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.3.5[${PYTHON_USEDEP}]
+	>=dev-python/mako-1.0[${PYTHON_USEDEP}]
+	>=dev-python/natsort-3.5.2[${PYTHON_USEDEP}]
+	>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
+	>=dev-python/PyRSS2Gen-1.1[${PYTHON_USEDEP}]
+	~dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-5.4.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/unidecode-0.04.16[${PYTHON_USEDEP}]
+	>=dev-python/yapsy-1.11.223[${PYTHON_USEDEP}]
+	virtual/python-imaging[${PYTHON_USEDEP}]
+	assets? ( >=dev-python/webassets-0.10.1[${PYTHON_USEDEP}] )
+	charts? ( ~dev-python/pygal-2.0.1[${PYTHON_USEDEP}] )
+	ghpages? ( >=dev-python/ghp-import-0.4.1[${PYTHON_USEDEP}] )
+	hyphenation? ( >=dev-python/pyphen-0.9.1[${PYTHON_USEDEP}] )
+	ipython? ( >=dev-python/ipython-2.0.0[notebook,${PYTHON_USEDEP}] )
+	jinja? ( >=dev-python/jinja-2.7.2[${PYTHON_USEDEP}] )
+	markdown? ( >=dev-python/markdown-2.4.0[${PYTHON_USEDEP}] )
+	watchdog? ( ~dev-python/watchdog-0.8.3[${PYTHON_USEDEP}] )
+	webmedia? ( >=dev-python/micawber-0.3.0[${PYTHON_USEDEP}] )
+	websocket? ( ~dev-python/ws4py-0.3.4[${PYTHON_USEDEP}] )"
+#	typography? ( >=dev-python/typogrify-2.0.4[${PYTHON_USEDEP}] ) # needs smartypants
+
+src_prepare() {
+	# replace Gutenberg licensed version with our public domain version (bug #552372)
+	rm nikola/data/samplesite/stories/a-study-in-scarlet.txt || die
+	cp "${DISTDIR}"/a-study-in-scarlet.txt nikola/data/samplesite/stories/ || die
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# hackish way to remove docs that ended up in the wrong place
+	rm -rf "${D}"/usr/share/doc/${PN}
+
+	dodoc AUTHORS.txt CHANGES.txt README.rst docs/*.txt
+	doman docs/man/${PN}.1.gz
+}