sys-power/power-profiles-daemon: add 0.21

Closes: https://bugs.gentoo.org/930172
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 99 insertions, 0 deletions

diff --git a/sys-power/power-profiles-daemon/Manifest b/sys-power/power-profiles-daemon/Manifest
index b87be2ce6cb0..64131b4f22b8 100644
--- a/sys-power/power-profiles-daemon/Manifest
+++ b/sys-power/power-profiles-daemon/Manifest
@@ -1,2 +1,3 @@
 DIST power-profiles-daemon-0.13.tar.bz2 49079 BLAKE2B 2a7c81b0ac8b4ac4a9805f5dcd722959ff0abe736782eba7678f49eb3c5790d59b2bcc35577733aaae9fc8baa76a65ca9a973ac9f0d9154061c3af86abe0e65d SHA512 dab0c44968480a2f5ae2074f07a48d901970c9b3b3ec104d14108615f85b1eb0f9f3e1b5f0ff766659e4d76b243da2cd4c025cd81b992b7149fb671e103a7d6b
 DIST power-profiles-daemon-0.20.tar.bz2 58388 BLAKE2B f25bc2618441f53624567c4f40d9960b28bf46fb2098eb0e2098207149df3d4923a13c40d781885e37708bf896b537ccb969ec7a928669a3776722e5e58801cf SHA512 2236aac94dafbf6fd951f3bd44953f1a14bc7c5e55349307374d836e20377e1768dcf1250fa8dcf9f01d4eddea8ab64082881189b4e958fbfcd5e2e90d3e823a
+DIST power-profiles-daemon-0.21.tar.bz2 63984 BLAKE2B 206c954272fb93b17a09e4108c74462d2524ef9160880ce59709504314fd38f413c7eb65ab4f0a085f6458b04f85b4833e0df3786f0aff08e7bdc0a3a65d8d2a SHA512 8038ff7c164bbcbeebc50c911f3129e79d4f8d63278bc674e10bf2920af0bc9b0b139d5a2e056889b0b7ec86df19cc7be3e8c84e70e777544e117ee7a036b375
diff --git a/sys-power/power-profiles-daemon/power-profiles-daemon-0.21.ebuild b/sys-power/power-profiles-daemon/power-profiles-daemon-0.21.ebuild
new file mode 100644
index 000000000000..c8ac68231b5b
--- /dev/null
+++ b/sys-power/power-profiles-daemon/power-profiles-daemon-0.21.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-single-r1 shell-completion systemd
+
+DESCRIPTION="Makes power profiles handling available over D-Bus"
+HOMEPAGE="https://gitlab.freedesktop.org/upower/power-profiles-daemon/"
+SRC_URI="https://gitlab.freedesktop.org/upower/${PN}/-/archive/${PV}/${P}.tar.bz2"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~x86"
+
+IUSE="bash-completion gtk-doc man selinux test zsh-completion"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
+	dev-libs/glib:2
+	>=dev-libs/libgudev-234
+	>=sys-auth/polkit-0.99
+	sys-power/upower
+	selinux? ( sec-policy/selinux-powerprofiles )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	bash-completion? (
+		>=app-shells/bash-completion-2.0
+		$(python_gen_cond_dep '>=dev-python/shtab-1.7.0[${PYTHON_USEDEP}]')
+	)
+	gtk-doc? (
+		dev-util/gi-docgen
+		dev-util/gtk-doc
+	)
+	man? (
+		$(python_gen_cond_dep 'dev-python/argparse-manpage[${PYTHON_USEDEP}]')
+	)
+	test? (
+		dev-util/umockdev
+		$(python_gen_cond_dep '
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+		')
+	)
+	zsh-completion? (
+		$(python_gen_cond_dep '>=dev-python/shtab-1.7.0[${PYTHON_USEDEP}]')
+	)
+"
+
+python_check_deps() {
+	if use test; then
+		python_has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+	else
+		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+	fi
+
+	if use bash-completion || use zsh-completion; then
+		python_has_version ">=dev-python/shtab-1.7.0[${PYTHON_USEDEP}]"
+	fi
+
+	use man && python_has_version "dev-python/argparse-manpage[${PYTHON_USEDEP}]"
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dpylint=disabled
+		-Dsystemdsystemunitdir="$(systemd_get_systemunitdir)"
+		$(meson_feature bash-completion bashcomp)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_feature man manpage)
+		$(meson_use test tests)
+	)
+	use zsh-completion && emesonargs+=( -Dzshcomp="$(get_zshcompdir)" )
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${D}"/usr/bin/powerprofilesctl
+	newinitd "${FILESDIR}/power-profiles-daemon.initd" power-profiles-daemon
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "You need to enable the service:"
+		if systemd_is_booted; then
+			elog "# systemctl enable ${PN}"
+		else
+			elog "# rc-update add ${PN} default"
+		fi
+	fi
+}