sci-libs/cartopy: Version bump

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>

2 files changed, 66 insertions, 0 deletions

diff --git a/sci-libs/cartopy/Manifest b/sci-libs/cartopy/Manifest
index b4a3dc8825c2..def25f780222 100644
--- a/sci-libs/cartopy/Manifest
+++ b/sci-libs/cartopy/Manifest
@@ -1 +1,2 @@
+DIST cartopy-0.18.0.tar.gz 14191937 BLAKE2B bb10791ef2534dad404cc492e378161a4a078813b09d6e2c16d0d465c7dcfbaa7f24d3818cfe0f1f46e7683bdf2e00440640534835ce064492d5321489e355bc SHA512 912d5ab57c96b9e6c51b3ad26f94d77e495eb9c3a8fb8a68bdd957c11b1bc8a3ddc97e76e0d8a5ec9afca9302b01fe5753f4208ec3829df8741ee0ebbaafe30f
 DIST cartopy-0.18.0_beta1.tar.gz 14215372 BLAKE2B 5bb1e98f18fdf57c0459202bfe77d4e4a476a3008e2f21a77cf643711cc3c438626915c31ee48886e980466f952985503987e3ed571295e2beb6c12754b382c4 SHA512 95d3bd87e57bea89eb2c25d6a709285ba59fb0f994abc3b37faf29b272b73647d0bc8979a25b1480f48bb55c957f4183ac3c3ad49b830ce686e931227c797abe
diff --git a/sci-libs/cartopy/cartopy-0.18.0.ebuild b/sci-libs/cartopy/cartopy-0.18.0.ebuild
new file mode 100644
index 000000000000..0be07b470778
--- /dev/null
+++ b/sci-libs/cartopy/cartopy-0.18.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+inherit distutils-r1 virtualx
+
+MY_PV=${PV/_beta/b}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Python package for geospatial data processing and analysis"
+HOMEPAGE="https://scitools.org.uk/cartopy"
+SRC_URI="https://github.com/SciTools/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/pyshp[${PYTHON_USEDEP}]
+	sci-libs/Shapely[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	sci-libs/gdal[python,${PYTHON_USEDEP}]
+"
+
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	sci-libs/geos
+	sci-libs/proj
+"
+
+distutils_enable_tests pytest
+
+DEPEND+="test? (
+		dev-python/filelock[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}"/${MY_P}
+
+python_prepare_all() {
+	# drop test file requiring network access, which got not covered by markers
+	rm "${S}"/lib/cartopy/tests/mpl/test_crs.py || die
+	# prepare matplotlib backend for test suite
+	export MPLCONFIGDIR="${T}"
+	echo "backend : Agg" > "${MPLCONFIGDIR}"/matplotlibrc || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${BUILD_DIR}"
+	# drop all tests needing network access
+	virtx pytest -vv -m "not network and not natural_earth" || die "test failed"
+}