net-p2p/transmission: add 4.0.0_beta1

Closes: https://bugs.gentoo.org/875893
Signed-off-by: Mike Gilbert <floppym@gentoo.org>

3 files changed, 166 insertions, 12 deletions

diff --git a/net-p2p/transmission/Manifest b/net-p2p/transmission/Manifest
index 1b20bc82f39b..47e9e8b93d51 100644
--- a/net-p2p/transmission/Manifest
+++ b/net-p2p/transmission/Manifest
@@ -1 +1,2 @@
 DIST transmission-3.00.tar.xz 3995080 BLAKE2B fb1be44aa630e6a1cf15511ab4ab40156edb16f9410b83058c53548f466fb9502c23157756a29e921e4468db1ebac7832b755cfcf98451c663c64401559f5498 SHA512 c8fb96086ba4b18f04d6181a29f6e2af85864840c533f3470a202dfa686e9431caeccd25f12c975a9a8f9b7802ca0bd73c4edc1ca06bdbada682326cad188a76
+DIST transmission-4.0.0-beta.1+r98cf7d9b3c.tar.xz 9481044 BLAKE2B 99d287645f4c28a9f021c0923712ca2b0246be53c26b2654a50e00dc7b3db51b7de304280f6ae2d57c879d96ebe811163af3c38a29e64764712d926fa5c3fb0f SHA512 1bd4265e708070577a5624ee33ab8b0a71baa6d12d121974be6c104078289892f35cab6ddb22070c749d8c1333996ad83eb6f08adf96ea492d96104cab550d60
diff --git a/net-p2p/transmission/transmission-4.0.0_beta1.ebuild b/net-p2p/transmission/transmission-4.0.0_beta1.ebuild
new file mode 100644
index 000000000000..ba2762346471
--- /dev/null
+++ b/net-p2p/transmission/transmission-4.0.0_beta1.ebuild
@@ -0,0 +1,144 @@
+# Copyright 2006-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake systemd xdg-utils
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/transmission/transmission"
+else
+	MY_PV="${PV/_beta/-beta.}"
+	MY_P="${PN}-${MY_PV}+r98cf7d9b3c"
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://github.com/transmission/transmission/releases/download/${MY_PV}/${MY_P}.tar.xz"
+	#KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+DESCRIPTION="A fast, easy, and free BitTorrent client"
+HOMEPAGE="https://transmissionbt.com/"
+
+# web/LICENSE is always GPL-2 whereas COPYING allows either GPL-2 or GPL-3 for the rest
+# transmission in licenses/ is for mentioning OpenSSL linking exception
+# MIT is in several libtransmission/ headers
+LICENSE="|| ( GPL-2 GPL-3 Transmission-OpenSSL-exception ) GPL-2 MIT"
+SLOT="0"
+IUSE="appindicator cli gtk lightweight nls mbedtls qt5 systemd test web"
+RESTRICT="!test? ( test )"
+
+ACCT_DEPEND="
+	acct-group/transmission
+	acct-user/transmission
+"
+BDEPEND="${ACCT_DEPEND}
+	virtual/pkgconfig
+	nls? (
+		gtk? ( sys-devel/gettext )
+		qt5? ( dev-qt/linguist-tools:5 )
+	)
+"
+COMMON_DEPEND="
+	>=dev-libs/libevent-2.1.0:=
+	!mbedtls? ( dev-libs/openssl:0= )
+	mbedtls? ( net-libs/mbedtls:0= )
+	net-libs/libnatpmp
+	>=net-libs/libpsl-0.21.1
+	>=net-libs/miniupnpc-1.7:=
+	>=net-misc/curl-7.28.0[ssl]
+	sys-libs/zlib:=
+	nls? ( virtual/libintl )
+	gtk? (
+		>=dev-cpp/gtkmm-3.24.0:3.0
+		>=dev-cpp/glibmm-2.60.0:2
+		appindicator? ( >=dev-libs/libappindicator-0.4.90:3 )
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtdbus:5
+	)
+	systemd? ( >=sys-apps/systemd-209:= )
+"
+DEPEND="${COMMON_DEPEND}
+	nls? ( virtual/libintl )
+"
+RDEPEND="${COMMON_DEPEND}
+	${ACCT_DEPEND}
+"
+
+src_prepare() {
+	cmake_src_prepare
+	rm -f libtransmission/version.h || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=share/doc/${PF}
+
+		-DENABLE_GTK=$(usex gtk ON OFF)
+		-DENABLE_QT=$(usex qt5 ON OFF)
+		-DENABLE_MAC=OFF
+		-DENABLE_WEB=$(usex web ON OFF)
+		-DENABLE_CLI=$(usex cli ON OFF)
+		-DENABLE_TESTS=$(usex test ON OFF)
+		-DENABLE_LIGHTWEIGHT=$(usex lightweight ON OFF)
+		-DENABLE_NLS=$(usex nls ON OFF)
+
+		-DRUN_CLANG_TIDY=OFF
+
+		-DUSE_SYSTEM_EVENT2=ON
+		-DUSE_SYSTEM_DEFLATE=OFF
+		-DUSE_SYSTEM_DHT=OFF
+		-DUSE_SYSTEM_MINIUPNPC=ON
+		-DUSE_SYSTEM_NATPMP=ON
+		-DUSE_SYSTEM_UTP=OFF
+		-DUSE_SYSTEM_B64=OFF
+		-DUSE_SYSTEM_PSL=ON
+		-DUSE_QT_VERSION=5
+
+		-DWITH_CRYPTO=$(usex mbedtls polarssl openssl)
+		-DWITH_INOTIFY=ON
+		-DWITH_LIBAPPINDICATOR=$(usex appindicator ON OFF)
+		-DWITH_SYSTEMD=$(usex systemd ON OFF)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	newinitd "${FILESDIR}"/transmission-daemon.initd.10 transmission-daemon
+	newconfd "${FILESDIR}"/transmission-daemon.confd.4 transmission-daemon
+
+	if use systemd; then
+		# Service sets Type=notify
+		systemd_dounit daemon/transmission-daemon.service
+		systemd_install_serviced "${FILESDIR}"/transmission-daemon.service.conf
+	fi
+
+	insinto /usr/lib/sysctl.d
+	doins "${FILESDIR}"/60-transmission.conf
+
+	if [[ ${EUID} == 0 ]]; then
+		diropts -o transmission -g transmission
+	fi
+	keepdir /var/lib/transmission
+}
+
+pkg_postrm() {
+	if use gtk || use qt5; then
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}
+
+pkg_postinst() {
+	if use gtk || use qt5; then
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}
diff --git a/net-p2p/transmission/transmission-9999.ebuild b/net-p2p/transmission/transmission-9999.ebuild
index ddaddc2cac6e..ba2762346471 100644
--- a/net-p2p/transmission/transmission-9999.ebuild
+++ b/net-p2p/transmission/transmission-9999.ebuild
@@ -9,8 +9,11 @@ if [[ ${PV} == 9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/transmission/transmission"
 else
-	SRC_URI="https://github.com/transmission/transmission-releases/raw/master/${P}.tar.xz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+	MY_PV="${PV/_beta/-beta.}"
+	MY_P="${PN}-${MY_PV}+r98cf7d9b3c"
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://github.com/transmission/transmission/releases/download/${MY_PV}/${MY_P}.tar.xz"
+	#KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
 fi
 
 DESCRIPTION="A fast, easy, and free BitTorrent client"
@@ -36,19 +39,19 @@ BDEPEND="${ACCT_DEPEND}
 	)
 "
 COMMON_DEPEND="
-	>=dev-libs/libevent-2.0.10:=
+	>=dev-libs/libevent-2.1.0:=
 	!mbedtls? ( dev-libs/openssl:0= )
 	mbedtls? ( net-libs/mbedtls:0= )
 	net-libs/libnatpmp
 	>=net-libs/libpsl-0.21.1
 	>=net-libs/miniupnpc-1.7:=
-	>=net-misc/curl-7.16.3[ssl]
+	>=net-misc/curl-7.28.0[ssl]
 	sys-libs/zlib:=
 	nls? ( virtual/libintl )
 	gtk? (
 		>=dev-cpp/gtkmm-3.24.0:3.0
-		>=dev-cpp/glibmm-2.50.1:2
-		appindicator? ( >=dev-libs/libappindicator-0.4.30:3 )
+		>=dev-cpp/glibmm-2.60.0:2
+		appindicator? ( >=dev-libs/libappindicator-0.4.90:3 )
 	)
 	qt5? (
 		dev-qt/qtcore:5
@@ -66,17 +69,25 @@ RDEPEND="${COMMON_DEPEND}
 	${ACCT_DEPEND}
 "
 
+src_prepare() {
+	cmake_src_prepare
+	rm -f libtransmission/version.h || die
+}
+
 src_configure() {
 	local mycmakeargs=(
 		-DCMAKE_INSTALL_DOCDIR=share/doc/${PF}
 
-		-DENABLE_CLI=$(usex cli ON OFF)
 		-DENABLE_GTK=$(usex gtk ON OFF)
-		-DENABLE_LIGHTWEIGHT=$(usex lightweight ON OFF)
-		-DENABLE_NLS=$(usex nls ON OFF)
 		-DENABLE_QT=$(usex qt5 ON OFF)
-		-DENABLE_TESTS=$(usex test ON OFF)
+		-DENABLE_MAC=OFF
 		-DENABLE_WEB=$(usex web ON OFF)
+		-DENABLE_CLI=$(usex cli ON OFF)
+		-DENABLE_TESTS=$(usex test ON OFF)
+		-DENABLE_LIGHTWEIGHT=$(usex lightweight ON OFF)
+		-DENABLE_NLS=$(usex nls ON OFF)
+
+		-DRUN_CLANG_TIDY=OFF
 
 		-DUSE_SYSTEM_EVENT2=ON
 		-DUSE_SYSTEM_DEFLATE=OFF
@@ -88,8 +99,6 @@ src_configure() {
 		-DUSE_SYSTEM_PSL=ON
 		-DUSE_QT_VERSION=5
 
-		-DRUN_CLANG_TIDY=OFF
-
 		-DWITH_CRYPTO=$(usex mbedtls polarssl openssl)
 		-DWITH_INOTIFY=ON
 		-DWITH_LIBAPPINDICATOR=$(usex appindicator ON OFF)