media-sound/qtractor: bump to 0.9.90

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 117 insertions, 0 deletions

diff --git a/media-sound/qtractor/Manifest b/media-sound/qtractor/Manifest
index a5179e8f3346..3d926f6e899c 100644
--- a/media-sound/qtractor/Manifest
+++ b/media-sound/qtractor/Manifest
@@ -1 +1,2 @@
 DIST qtractor-0.9.39.tar.gz 2619142 BLAKE2B 062b363c2db748da731a2b5ee375e1a820bae9ea2d312a2f9f313fc2df11049e86452308c725fff58d7ffd05e916c3d3bbe42e8fd07f10012a34005edf874967 SHA512 3b2a4dde182147d73c773cff0ee6e3d086dd8b598b884a7ca564f10a1fdb56c3e86b3d135739f2629476a587e13b11d4a42abe7c498b76a0321151d9c0ff2852
+DIST qtractor-0.9.90.tar.gz 2647835 BLAKE2B a9bf283f062f946e630e4e878c194326d1cc7028c27dc91dbcb8f8567612d88c4005b73ca9a8270e837b27ea20f419bad4d54d85441338863bf6b7558c07ba50 SHA512 caed9a454e84fd2701c7d37f33bfcff32383127e891af5c2823045f710f953bf2e2040b7261ce5b24b1fc330a06ffb47132fe4b9a378c9cfe3e40f6b4e6f01cb
diff --git a/media-sound/qtractor/qtractor-0.9.90.ebuild b/media-sound/qtractor/qtractor-0.9.90.ebuild
new file mode 100644
index 000000000000..8f2299f5dc0c
--- /dev/null
+++ b/media-sound/qtractor/qtractor-0.9.90.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic xdg
+
+DESCRIPTION="Audio/MIDI multi-track sequencer written in C++ with the Qt framework"
+HOMEPAGE="https://qtractor.sourceforge.io https://github.com/rncbc/qtractor"
+SRC_URI="mirror://sourceforge/qtractor/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="aubio cpu_flags_x86_sse debug dssi ladspa libsamplerate mad osc rubberband vorbis zlib"
+REQUIRED_USE="dssi? ( ladspa )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtx11extras:5
+	media-libs/alsa-lib
+	media-libs/libsndfile
+	media-libs/lilv
+	media-libs/lv2
+	media-libs/suil
+	virtual/jack
+	x11-libs/libxcb:=
+	aubio? ( media-libs/aubio:= )
+	dssi? ( media-libs/dssi )
+	ladspa? ( media-libs/ladspa-sdk )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	osc? ( media-libs/liblo )
+	rubberband? ( media-libs/rubberband )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	zlib? ( sys-libs/zlib )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	# -Werror=odr
+	# https://bugs.gentoo.org/927061
+	# https://github.com/rncbc/qtractor/commit/83ed590eed798f24b6aa1a792b38c2fc61051356
+	#
+	# Remove on next version bump.
+	filter-lto
+
+	local mycmakeargs=(
+		-DCONFIG_DSSI=$(usex dssi 1 0)
+		-DCONFIG_GRADIENT=1
+		-DCONFIG_JACK_LATENCY=1
+		-DCONFIG_JACK_METADATA=1
+		-DCONFIG_JACK_SESSION=1
+		-DCONFIG_LADSPA=$(usex ladspa 1 0)
+		-DCONFIG_LIBAUBIO=$(usex aubio 1 0)
+		-DCONFIG_LIBLILV=1
+		-DCONFIG_LIBLO=$(usex osc 1 0)
+		-DCONFIG_LIBMAD=$(usex mad 1 0)
+		-DCONFIG_LIBRUBBERBAND=$(usex rubberband 1 0)
+		-DCONFIG_LIBSAMPLERATE=$(usex libsamplerate 1 0)
+		-DCONFIG_LIBVORBIS=$(usex vorbis 1 0)
+		-DCONFIG_LIBZ=$(usex zlib 1 0)
+		-DCONFIG_LV2=1
+		-DCONFIG_LV2_UI_GTK2=0
+		-DCONFIG_NSM=0
+		-DCONFIG_QT6=0
+		-DCONFIG_SSE=$(usex cpu_flags_x86_sse 1 0)
+		-DCONFIG_STACKTRACE=$(usex debug 1 0)
+		-DCONFIG_VESTIGE=1
+		-DCONFIG_VST2=1
+		-DCONFIG_VST3=0
+		-DCONFIG_XUNIQUE=0
+	)
+	# Following options are left to the default
+	# CONFIG_LV2_ATOM
+	# CONFIG_LV2_BUF_SIZE
+	# CONFIG_LV2_CVPORT
+	# CONFIG_LV2_EVENT
+	# CONFIG_LV2_EXTERNAL_UI
+	# CONFIG_LV2_MIDNAM
+	# CONFIG_LV2_OPTIONS
+	# CONFIG_LV2_PARAMETERS
+	# CONFIG_LV2_PATCH
+	# CONFIG_LV2_PORT_EVENT
+	# CONFIG_LV2_PRESETS
+	# CONFIG_LV2_PROGRAMS
+	# CONFIG_LV2_STATE
+	# CONFIG_LV2_STATE_FILES
+	# CONFIG_LV2_STATE_MAKE_PATH
+	# CONFIG_LV2_TIME
+	# CONFIG_LV2_TIME_POSITION
+	# CONFIG_LV2_UI
+	# CONFIG_LV2_UI_IDLE
+	# CONFIG_LV2_UI_REQ_VALUE
+	# CONFIG_LV2_UI_SHOW
+	# CONFIG_LV2_UI_TOUCH
+	# CONFIG_LV2_WORKER
+	# CONFIG_LV2_UI_X11
+	cmake_src_configure
+}