games-strategy/wesnoth: Bump to version 1.14.6

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 117 insertions, 0 deletions

diff --git a/games-strategy/wesnoth/Manifest b/games-strategy/wesnoth/Manifest
index e7fa1df1e401..af0ef226cf25 100644
--- a/games-strategy/wesnoth/Manifest
+++ b/games-strategy/wesnoth/Manifest
@@ -1 +1,2 @@
 DIST wesnoth-1.14.5.tar.gz 489848620 BLAKE2B abbf1ae2bb20cfdd2575f5e21eea7db9b32f0a9c7e85101652206477f3dca8ae0aefbf4b0a252c4522565c08900b0a04d39fd5eadb5feb49168dc95db732e50e SHA512 115c7fda3ef77079d871aeae4bc448bf8de1829d7723179f634db10f23ab8c15d2d92c5a36c11aa8dc79fb8f914e95f06143565e2ae950947da35af5f71e1b6e
+DIST wesnoth-1.14.6.tar.gz 491891860 BLAKE2B e15512eefbb7b118ec80a5612c23edce41555fc2869b652d4799bc052f26592852a2b4d1cb76dee3203d8a26c18c4cf9de58dea1ee81403b9881642e902cf2f3 SHA512 f29b78605f5e3c2e9af8884925b43a262d6fce469bf30a4697e2c8bef8a49d0fea17bd6dc1a3e78113a50e6f21e29aedb5ee26ff2b0493371120f8c64b894096
diff --git a/games-strategy/wesnoth/wesnoth-1.14.6.ebuild b/games-strategy/wesnoth/wesnoth-1.14.6.ebuild
new file mode 100644
index 000000000000..971ba1f87a94
--- /dev/null
+++ b/games-strategy/wesnoth/wesnoth-1.14.6.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit cmake-utils user
+
+DESCRIPTION="Battle for Wesnoth - A fantasy turn-based strategy game"
+HOMEPAGE="http://www.wesnoth.org
+	https://github.com/wesnoth/wesnoth"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="dbus dedicated doc fribidi libressl nls openmp server"
+
+RDEPEND="
+	>=dev-libs/boost-1.50:=[nls,threads,icu]
+	>=media-libs/libsdl2-2.0.4:0[joystick,video,X]
+	!dedicated? (
+		dev-libs/glib:2
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+		>=media-libs/fontconfig-2.4.1
+		>=media-libs/sdl2-image-2.0.0[jpeg,png]
+		>=media-libs/sdl2-mixer-2.0.0[vorbis]
+		>=media-libs/sdl2-ttf-2.0.12
+		media-libs/libvorbis
+		>=x11-libs/pango-1.22.0
+		>=x11-libs/cairo-1.10.0
+		sys-libs/readline:0=
+		dbus? ( sys-apps/dbus )
+		fribidi? ( dev-libs/fribidi )
+	)"
+DEPEND="${RDEPEND}
+	x11-libs/libX11
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	if use openmp; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+
+	enewgroup ${PN}
+	enewuser ${PN} -1 /bin/bash -1 ${PN}
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if ! use doc ; then
+		sed -i \
+			-e '/manual/d' \
+			doc/CMakeLists.txt || die
+	fi
+
+	# respect LINGUAS (bug #483316)
+	if [[ ${LINGUAS+set} ]] ; then
+		local lang langs=()
+		for lang in $(cat po/LINGUAS) ; do
+			has ${lang} ${LINGUAS} && langs+=( ${lang} )
+		done
+		echo "${langs[@]}" > po/LINGUAS || die
+	fi
+}
+
+src_configure() {
+	filter-flags -ftracer -fomit-frame-pointer
+	if [[ $(gcc-major-version) -eq 3 ]] ; then
+		filter-flags -fstack-protector
+		append-flags -fno-stack-protector
+	fi
+
+	# Work around eclass
+	append-flags -UNDEBUG
+
+	if use dedicated || use server ; then
+		mycmakeargs=(
+			-DENABLE_CAMPAIGN_SERVER="ON"
+			-DENABLE_SERVER="ON"
+			-DSERVER_UID="${PN}"
+			-DSERVER_GID="${PN}"
+			-DFIFO_DIR="/run/wesnothd"
+			)
+	else
+		mycmakeargs=(
+			-DENABLE_CAMPAIGN_SERVER="OFF"
+			-DENABLE_SERVER="OFF"
+			)
+	fi
+	mycmakeargs+=(
+		-Wno-dev
+		-DENABLE_GAME="$(usex !dedicated)"
+		-DENABLE_DESKTOP_ENTRY="$(usex !dedicated)"
+		-DENABLE_NLS="$(usex nls)"
+		-DENABLE_NOTIFICATIONS="$(usex dbus)"
+		-DENABLE_FRIBIDI="$(usex fribidi)"
+		-DENABLE_OMP="$(usex openmp)"
+		-DENABLE_STRICT_COMPILATION="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	local DOCS=( README.md changelog.md )
+	cmake-utils_src_install
+	if use dedicated || use server; then
+		rmdir "${ED}/run/wesnothd" || die
+		newinitd "${FILESDIR}"/wesnothd.rc-r1 wesnothd
+	fi
+}