dev-lang/swi-prolog: bump development version

Signed-off-by: Keri Harris <keri@gentoo.org>
Package-Manager: Portage-2.3.89, Repoman-2.3.11

2 files changed, 107 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index de6dcdaced97..75340c179790 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -3,3 +3,4 @@ DIST swipl-8.1.21.tar.gz 10867376 BLAKE2B 740ac827190d86e5803c61e09b6c122667fa3d
 DIST swipl-8.1.22.tar.gz 10893825 BLAKE2B 7457570728dcf07d9df5c6049366fbe00497063b54eaed3540f80cfab3296da68236afb4816ff65f1fdc74691d0136f3ababc0aceb4da0209675229a13cbdc55 SHA512 7b0154d88688f4dd97ccf198e3e1f11c958345f08f62a5302d33c9530cdad09bf54c47a7f4b107ff2839bc1a354da284bc71f7caaf77e80d53ec412a2c566e5c
 DIST swipl-8.1.23.tar.gz 10907184 BLAKE2B c24f088c50e4af0d961902268d43cfaadbc3c5cc135dc6791d06a0e2cb9d5b255b52121d34facf26f9466d9e57e09a7f986948d28b8a142c6903a1c878ca212f SHA512 71e282dbaab6dd34d8a5ef77e41324de47eb294de630a2d4aacf132b0f5e85c75512a182481aaf245539829af280679c97094e206c38b8eead631cfcffc578d9
 DIST swipl-8.1.24.tar.gz 10893950 BLAKE2B d3fc9273b9998c76076e7dd5aa6c9ffdd35a6273dc3987744546c0d5446947ba5435edecfd3c919b6ebb78e69538aa0cea2bd93cbcccc32505a14da1c46c12f4 SHA512 521f5a04954b640f20cf8a40ad598c889da85f1b559354805aa27de0cbe52e543ba179da0a3c456771a7dfbcbb713b43fca5aa2f54a270555fb590a8ee2c1be8
+DIST swipl-8.1.25.tar.gz 10896679 BLAKE2B 69c20e02d59d25d317f1d4c339b430af8faa7d9027e91a5224eeb13ffc6b92a0eb08b9ff8602f17e449410da4cd007c59b08f43f29049f0b475004bebde6f65b SHA512 f034ae521da9d27d9c8681a3b9404047b61c77449d6257fea599b3ba0a5ba572b559f0dcd2653ebbf70eb7588bbf99d3d43149411e373a346d27e16c620fe638
diff --git a/dev-lang/swi-prolog/swi-prolog-8.1.25.ebuild b/dev-lang/swi-prolog/swi-prolog-8.1.25.ebuild
new file mode 100644
index 000000000000..8f4583928061
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.1.25.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	EPATCH_FORCE=yes
+	EPATCH_SUFFIX=patch
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		epatch "${WORKDIR}"/${PV}
+	fi
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+
+	eapply_user
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	XDG_CONFIG_DIRS="${HOME}" \
+	XDG_DATA_DIRS="${HOME}" \
+		cmake-utils_src_compile
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}