games-engines/freesci/freesci-0.3.4c.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-engines/freesci/freesci-0.3.4c.ebuild,v 1.6 2006/01/31 05:37:50 mr_bones_ Exp $

inherit flag-o-matic games

DESCRIPTION="Sierra script interpreter for your old Sierra adventures"
HOMEPAGE="http://freesci.linuxgames.com/"
SRC_URI="http://www-plan.cs.colorado.edu/creichen/freesci/${P}.tar.bz2
	http://teksolv.de/~jameson/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86"
IUSE="X ggi directfb alsa sdl ncurses"

RDEPEND="
	X? (
		|| ( ( x11-libs/libXi
				x11-libs/libXrender )
			virtual/x11 )
		=media-libs/freetype-2*
	)
	ggi? ( media-libs/libggi )
	directfb? ( dev-libs/DirectFB )
	alsa? ( >=media-libs/alsa-lib-0.5.0 )
	sdl? ( >=media-libs/libsdl-1.1.8 )
	ncurses? ( sys-libs/ncurses )"
DEPEND="${RDEPEND}
	X? (
		|| ( ( x11-libs/libXft
				x11-libs/libXt )
			virtual/x11 )
	)"

src_compile() {
	sed -i \
		-e 's:DSPF_RGB15:DSPF_ARGB1555:' \
		src/gfx/drivers/directfb_driver.c \
		|| die "sed failed"
	use X && append-flags -I/usr/include/freetype2
	egamesconf \
		$(use_with X x) \
		$(use_with sdl) \
		$(use_with directfb) \
		$(use_with ggi) \
		$(use_with alsa) \
		|| die
	sed -i \
		-e "/^datadir/ s:/games::" desktop/Makefile \
		|| die "sed desktop/Makefile failed"
	sed -i \
		-e '/^datadir/ s:$(prefix):/usr:' conf/Makefile \
		|| die "sed conf/Makefile failed"
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"
	rm -rf "${D}/usr/games/share"
	dodoc AUTHORS ChangeLog NEWS README README.Unix THANKS TODO
	prepgamesdirs
}