# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-tv/xawdecode/xawdecode-1.9.1.ebuild,v 1.1 2004/08/29 10:57:14 mholzer Exp $

IUSE="alsa jpeg encode ffmpeg xvid lirc xosd xinerama"

DESCRIPTION="TV viewer with support for AVI recording and plugins"
HOMEPAGE="http://xawdecode.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86 ~ppc ~sparc"

RDEPEND="virtual/x11
	>=media-libs/zvbi-0.2.4
	|| ( x11-libs/neXtaw x11-libs/Xaw3d )
	x86? ( >=media-libs/divx4linux-20030428 )
	ffmpeg? ( >=media-video/ffmpeg-0.4.7 )
	xvid? ( =media-libs/xvid-1* )
	encode? ( >=media-sound/lame-3.93 )
	jpeg? ( media-libs/jpeg )
	lirc? ( app-misc/lirc )
	alsa? ( >=media-libs/alsa-lib-0.9 )
	xosd? ( >=x11-libs/xosd-2.2.2 )"

DEPEND="${RDEPEND}
	sys-apps/sed"

src_unpack() {
	unpack ${A}
	cp ${S}/configure ${S}/configure.orig
	sed -e 's:XVID_INIT_PARAM:xvid_gbl_init_t:' \
		< ${S}/configure.orig > ${S}/configure
}

src_compile() {
	econf \
		`use_enable x86 divx4linux` \
		`use_enable alsa` \
		`use_enable jpeg` \
		`use_enable lirc` \
		`use_enable ffmpeg` \
		`use_enable xvid` \
		`use_enable xosd` \
		`use_enable xinerama` \
		--disable-cpu-detection \
		|| die "Configuration failed."

	emake OPT="${CFLAGS}" PERF_FLAGS="${CFLAGS}" || die "Compilation failed."
}

src_install() {

	sed -i "/^SUBDIRS/s:font::" Makefile

	gzip font/led-fixed.pcf
	insinto /usr/X11R6/lib/X11/fonts/misc
	doins font/led-fixed.pcf.gz

	insinto /usr/share/applications
	doins gentoo/xawdecode.desktop

	einstall \
		ROOT=${D} || die "Installation failed."

	dodoc COPYING ChangeLog AUTHORS INSTALL
	dodoc FAQ* README.* TODO lisez-moi* libavc-rate-control.txt
	dodoc xawdecoderc.sample lircrc.*.sample

	docinto alevt
	dodoc alevt/README alevt/ReadmeGR alevt/CHANGELOG alevt/COPYRIGHT
}

pkg_postinst() {
	if [ "${ROOT}" = "/" ]
	then
		mkfontdir /usr/X11R6/lib/X11/fonts/misc > /dev/null 2>&1
	fi
	einfo "Please note that this ebuild created a suid-binary:"
	einfo "/usr/bin/xawdecode_v4l-conf"
}

pkg_postrm() {
	if [ "${ROOT}" = "/" ]
	then
		mkfontdir /usr/X11R6/lib/X11/fonts/misc > /dev/null 2>&1
	fi
}