From 98abe1c50c9568376cde43c0e8790436fa27af95 Mon Sep 17 00:00:00 2001
From: "Andreas K. Hüttel" <dilfridge@gentoo.org>
Date: Mon, 28 Jan 2019 00:56:00 +0100
Subject: x11-wm/vtwm: EAPI bump
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Package-Manager: Portage-2.3.58, Repoman-2.3.12
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>
---
 x11-wm/vtwm/vtwm-5.4.7-r1.ebuild | 71 ----------------------------------------
 x11-wm/vtwm/vtwm-5.4.7-r2.ebuild | 71 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+), 71 deletions(-)
 delete mode 100644 x11-wm/vtwm/vtwm-5.4.7-r1.ebuild
 create mode 100644 x11-wm/vtwm/vtwm-5.4.7-r2.ebuild

(limited to 'x11-wm/vtwm')

diff --git a/x11-wm/vtwm/vtwm-5.4.7-r1.ebuild b/x11-wm/vtwm/vtwm-5.4.7-r1.ebuild
deleted file mode 100644
index f1f31db2b33b..000000000000
--- a/x11-wm/vtwm/vtwm-5.4.7-r1.ebuild
+++ /dev/null
@@ -1,71 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="2"
-
-inherit eutils toolchain-funcs
-
-DESCRIPTION="one of many TWM descendants and implements a Virtual Desktop"
-HOMEPAGE="http://www.vtwm.org/"
-SRC_URI="http://www.vtwm.org/downloads/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
-IUSE="rplay"
-
-RDEPEND="x11-libs/libX11
-	x11-libs/libXmu
-	x11-libs/libXt
-	x11-libs/libXext
-	x11-libs/libXpm
-	rplay? ( media-sound/rplay )"
-DEPEND="${RDEPEND}
-	app-text/rman
-	sys-devel/bison
-	sys-devel/flex
-	x11-base/xorg-proto
-	x11-misc/imake"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${P}-do-not-rm.patch
-	sed -i Imakefile \
-		-e 's:-L/usr/local/lib::g' \
-		-e 's:-I/usr/local/include::g' \
-		|| die "sed Imakefile"
-	if ! use rplay ; then
-		sed -i Imakefile \
-			-e 's:^XCOMM\ \(.*NO_SOUND\):\1:' \
-			-e 's:^\(SOUNDLIB.*\):XCOMM\ \1:' \
-			-e 's:sound\..::g' \
-			|| die "sed Imakefile"
-		epatch "${FILESDIR}"/${P}-NO_SOUND_SUPPORT.patch
-	fi
-}
-
-src_configure() {
-	xmkmf || die "xmkmf failed"
-	emake depend || die "emake depend"
-}
-
-src_compile() {
-	emake \
-		CC=$(tc-getCC) \
-		CCOPTIONS="${CFLAGS}" \
-		EXTRA_LDOPTIONS="${LDFLAGS}" \
-		|| die "emake failed"
-}
-
-src_install() {
-	emake BINDIR=/usr/bin \
-		LIBDIR=/etc/X11 \
-		MANPATH=/usr/share/man \
-		DESTDIR="${D}" install || die "emake install failed"
-
-	echo "#!/bin/sh" > vtwm
-	echo "xsetroot -cursor_name left_ptr &" >> vtwm
-	echo "/usr/bin/vtwm" >> vtwm
-	exeinto /etc/X11/Sessions
-	doexe vtwm || die
-	dodoc doc/{4.7.*,CHANGELOG,BUGS,DEVELOPERS,HISTORY,SOUND,WISHLIST} || die
-}
diff --git a/x11-wm/vtwm/vtwm-5.4.7-r2.ebuild b/x11-wm/vtwm/vtwm-5.4.7-r2.ebuild
new file mode 100644
index 000000000000..449d88600609
--- /dev/null
+++ b/x11-wm/vtwm/vtwm-5.4.7-r2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="TWM descendant that implements a Virtual Desktop"
+HOMEPAGE="http://www.vtwm.org/"
+SRC_URI="http://www.vtwm.org/downloads/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
+IUSE="rplay"
+
+RDEPEND="x11-libs/libX11
+	x11-libs/libXmu
+	x11-libs/libXt
+	x11-libs/libXext
+	x11-libs/libXpm
+	rplay? ( media-sound/rplay )"
+DEPEND="${RDEPEND}
+	app-text/rman
+	sys-devel/bison
+	sys-devel/flex
+	x11-base/xorg-proto
+	x11-misc/imake"
+
+src_prepare() {
+	eapply "${FILESDIR}"/${P}-do-not-rm.patch
+	sed -i Imakefile \
+		-e 's:-L/usr/local/lib::g' \
+		-e 's:-I/usr/local/include::g' \
+		|| die "sed Imakefile"
+	if ! use rplay ; then
+		sed -i Imakefile \
+			-e 's:^XCOMM\ \(.*NO_SOUND\):\1:' \
+			-e 's:^\(SOUNDLIB.*\):XCOMM\ \1:' \
+			-e 's:sound\..::g' \
+			|| die "sed Imakefile"
+		eapply "${FILESDIR}"/${P}-NO_SOUND_SUPPORT.patch
+	fi
+	default
+}
+
+src_configure() {
+	xmkmf || die "xmkmf failed"
+	emake depend
+}
+
+src_compile() {
+	emake \
+		CC=$(tc-getCC) \
+		CCOPTIONS="${CFLAGS}" \
+		EXTRA_LDOPTIONS="${LDFLAGS}"
+}
+
+src_install() {
+	emake BINDIR=/usr/bin \
+		LIBDIR=/etc/X11 \
+		MANPATH=/usr/share/man \
+		DESTDIR="${D}" install
+
+	echo "#!/bin/sh" > vtwm
+	echo "xsetroot -cursor_name left_ptr &" >> vtwm
+	echo "/usr/bin/vtwm" >> vtwm
+	exeinto /etc/X11/Sessions
+	doexe vtwm
+	dodoc doc/{4.7.*,CHANGELOG,BUGS,DEVELOPERS,HISTORY,SOUND,WISHLIST}
+}
-- 
cgit v1.2.3-65-gdbad