From 515b2e39c12141f3ab943741a25e0f321ed56c27 Mon Sep 17 00:00:00 2001
From: "Andreas K. Hüttel" <dilfridge@gentoo.org>
Date: Thu, 22 Feb 2018 23:53:58 +0100
Subject: x11-plugins/asclock: EAPI bump

Package-Manager: Portage-2.3.24, Repoman-2.3.6
---
 x11-plugins/asclock/asclock-2.0.12-r1.ebuild | 64 --------------------------
 x11-plugins/asclock/asclock-2.0.12-r2.ebuild | 67 ++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+), 64 deletions(-)
 delete mode 100644 x11-plugins/asclock/asclock-2.0.12-r1.ebuild
 create mode 100644 x11-plugins/asclock/asclock-2.0.12-r2.ebuild

(limited to 'x11-plugins/asclock')

diff --git a/x11-plugins/asclock/asclock-2.0.12-r1.ebuild b/x11-plugins/asclock/asclock-2.0.12-r1.ebuild
deleted file mode 100644
index eb6bcd3414b2..000000000000
--- a/x11-plugins/asclock/asclock-2.0.12-r1.ebuild
+++ /dev/null
@@ -1,64 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=3
-inherit eutils toolchain-funcs
-
-IUSE=""
-DESCRIPTION="Clock applet for AfterStep"
-SRC_URI="http://www.tigr.net/afterstep/download/asclock/${P}.tar.gz"
-HOMEPAGE="http://tigr.net/afterstep/applets/"
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ~mips ppc sparc x86 ~amd64-linux ~x86-linux ~x64-solaris"
-
-DEPEND="x11-libs/libXpm"
-RDEPEND="${DEPEND}
-	x11-proto/xextproto
-	x11-proto/xproto"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${PN}-gcc41.patch
-	ln -s themes/classic default_theme
-}
-
-src_configure() { :; }
-
-src_compile() {
-	local x
-	# will break Solaris
-	[[ ${CHOST} == *-linux-gnu ]] && CFLAGS="${CFLAGS} \
-		-Dlinux \
-		-D_POSIX_C_SOURCE=199309L \
-		-D_POSIX_SOURCE \
-		-D_XOPEN_SOURCE"
-	for x in asclock parser symbols config
-	do
-		$(tc-getCC) \
-			${CPPFLAGS} ${CFLAGS} ${ASFLAGS} \
-			-I"${EPREFIX}"/usr/include \
-			-D_BSD_SOURCE \
-			-D_SVID_SOURCE \
-			-DFUNCPROTO=15 \
-			-DNARROWPROTO \
-			-c -o ${x}.o ${x}.c || die "compile asclock failed"
-	done
-	$(tc-getCC) \
-		${LDFLAGS} \
-		-o asclock \
-		asclock.o parser.o symbols.o config.o \
-		-L"${EPREFIX}"/usr/lib \
-		-L"${EPREFIX}"/usr/lib/X11 \
-		-lXpm -lXext -lX11 || die "link asclock failed"
-}
-
-src_install() {
-	dobin asclock
-	local themesdir="/usr/share/${PN}/themes"
-	insinto ${themesdir}
-	doins -r themes/*
-	dodoc README README.THEMES TODO
-	cd "${D}"/${themesdir}
-	rm -f Freeamp/Makefile{,.*}
-	ln -s classic default_theme
-}
diff --git a/x11-plugins/asclock/asclock-2.0.12-r2.ebuild b/x11-plugins/asclock/asclock-2.0.12-r2.ebuild
new file mode 100644
index 000000000000..e7b14ca2e97a
--- /dev/null
+++ b/x11-plugins/asclock/asclock-2.0.12-r2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils toolchain-funcs
+
+IUSE=""
+DESCRIPTION="Clock applet for AfterStep"
+SRC_URI="http://www.tigr.net/afterstep/download/asclock/${P}.tar.gz"
+HOMEPAGE="http://tigr.net/afterstep/applets/"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~mips ppc sparc x86 ~amd64-linux ~x86-linux ~x64-solaris"
+
+DEPEND="x11-libs/libXpm"
+RDEPEND="${DEPEND}
+	x11-proto/xextproto
+	x11-proto/xproto"
+
+PATCHES=( "${FILESDIR}"/${PN}-gcc41.patch )
+
+src_prepare() {
+	default
+	ln -s themes/classic default_theme
+}
+
+src_configure() { :; }
+
+src_compile() {
+	local x
+	# will break Solaris
+	[[ ${CHOST} == *-linux-gnu ]] && CFLAGS="${CFLAGS} \
+		-Dlinux \
+		-D_POSIX_C_SOURCE=199309L \
+		-D_POSIX_SOURCE \
+		-D_XOPEN_SOURCE"
+	for x in asclock parser symbols config
+	do
+		$(tc-getCC) \
+			${CPPFLAGS} ${CFLAGS} ${ASFLAGS} \
+			-I"${EPREFIX}"/usr/include \
+			-D_BSD_SOURCE \
+			-D_SVID_SOURCE \
+			-DFUNCPROTO=15 \
+			-DNARROWPROTO \
+			-c -o ${x}.o ${x}.c || die "compile asclock failed"
+	done
+	$(tc-getCC) \
+		${LDFLAGS} \
+		-o asclock \
+		asclock.o parser.o symbols.o config.o \
+		-L"${EPREFIX}"/usr/lib \
+		-L"${EPREFIX}"/usr/lib/X11 \
+		-lXpm -lXext -lX11 || die "link asclock failed"
+}
+
+src_install() {
+	dobin asclock
+	local themesdir="/usr/share/${PN}/themes"
+	insinto ${themesdir}
+	doins -r themes/*
+	dodoc README README.THEMES TODO
+	cd "${D}"/${themesdir} || die
+	rm -f Freeamp/Makefile{,.*} || die
+	ln -s classic default_theme || die
+}
-- 
cgit v1.2.3-65-gdbad