From f21f66667be7601f9721f0d67bb1cec3478fe8bb Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Wed, 8 Mar 2017 19:46:32 +0100
Subject: sci-biology/biosql: Modernise to EAPI 6

Package-Manager: Portage-2.3.4, Repoman-2.3.2
---
 sci-biology/biosql/biosql-1.0.1-r1.ebuild | 43 +++++++++++++++++++++++++++++++
 sci-biology/biosql/biosql-1.0.1.ebuild    | 32 -----------------------
 2 files changed, 43 insertions(+), 32 deletions(-)
 create mode 100644 sci-biology/biosql/biosql-1.0.1-r1.ebuild
 delete mode 100644 sci-biology/biosql/biosql-1.0.1.ebuild

(limited to 'sci-biology')

diff --git a/sci-biology/biosql/biosql-1.0.1-r1.ebuild b/sci-biology/biosql/biosql-1.0.1-r1.ebuild
new file mode 100644
index 000000000000..6508d6a3a2e8
--- /dev/null
+++ b/sci-biology/biosql/biosql-1.0.1-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="A generic bioinformatics relational database model"
+HOMEPAGE="http://www.biosql.org/"
+SRC_URI="http://biosql.org/DIST/${P}.tar.bz2"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="mysql postgres"
+
+# WARNING: bioperl-db is claimed to be incompatible with >=postgresql-8.3 (see INSTALL)
+
+DEPEND="
+	mysql? ( dev-perl/DBD-mysql )
+	postgres? ( dev-perl/DBD-Pg )"
+RDEPEND="
+	${DEPEND}
+	dev-lang/perl"
+
+src_install() {
+	insinto /usr/share/${PN}
+	doins -r sql scripts/.
+
+	dodoc Changes README Release.txt doc/*.pdf
+
+	docinto biopython
+	dodoc doc/{README,schema-overview.txt,biopython/{cor6_6.gb,*.pdf}}
+	docompress -x /usr/share/doc/${PF}/biopython
+
+	docinto html
+	dodoc doc/{biopython/,}*.htm*
+}
+
+pkg_postinst() {
+	elog
+	elog "Please read the BioSQL schema installation instructions in"
+	elog "${EROOT%/}/usr/share/doc/${PF} to begin using the schema."
+	elog
+}
diff --git a/sci-biology/biosql/biosql-1.0.1.ebuild b/sci-biology/biosql/biosql-1.0.1.ebuild
deleted file mode 100644
index 950e6d347f84..000000000000
--- a/sci-biology/biosql/biosql-1.0.1.ebuild
+++ /dev/null
@@ -1,32 +0,0 @@
-# Copyright 1999-2009 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-DESCRIPTION="A generic bioinformatics relational database model"
-HOMEPAGE="http://www.biosql.org/"
-SRC_URI="http://biosql.org/DIST/${P}.tar.bz2"
-
-LICENSE="LGPL-3"
-SLOT="0"
-IUSE="mysql postgres"
-KEYWORDS="amd64 x86"
-
-# WARNING: bioperl-db is claimed to be incompatible with >=postgresql-8.3 (see INSTALL)
-
-DEPEND="mysql? ( dev-perl/DBD-mysql )
-	postgres? ( dev-perl/DBD-Pg )"
-RDEPEND="${DEPEND}"
-
-src_install() {
-	insinto /usr/share/${PN}
-	doins -r sql scripts/* || die
-	insinto /usr/share/doc/${P}
-	doins -r doc/*
-	dodoc Changes INSTALL README Release.txt
-}
-
-pkg_postinst() {
-	echo
-	elog "Please read the BioSQL schema installation instructions in"
-	elog "/usr/share/doc/${P} to begin using the schema."
-	echo
-}
-- 
cgit v1.2.3-65-gdbad