From b4b2fc1a667dfb4ada426f60f4f08bf732a8e640 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Wed, 22 Aug 2018 19:32:17 +0200
Subject: games-board/cockatrice: Fix missing (R)DEPENDs, superfluous inherits

Sort dependencies, add missing sys-libs/zlib slot op
Add completely missing RDEPEND (since 2f2b7ec5b6fb49b79bd936219f0b0ae5baa70514)
Add missing USE-dep on dev-qt/qtnetwork:5[ssl]

Closes: https://bugs.gentoo.org/664290
Package-Manager: Portage-2.3.48, Repoman-2.3.10
---
 .../cockatrice/cockatrice-20170505-r1.ebuild       | 53 ++++++++++++++++++++++
 games-board/cockatrice/cockatrice-20170505.ebuild  | 47 -------------------
 2 files changed, 53 insertions(+), 47 deletions(-)
 create mode 100644 games-board/cockatrice/cockatrice-20170505-r1.ebuild
 delete mode 100644 games-board/cockatrice/cockatrice-20170505.ebuild

(limited to 'games-board')

diff --git a/games-board/cockatrice/cockatrice-20170505-r1.ebuild b/games-board/cockatrice/cockatrice-20170505-r1.ebuild
new file mode 100644
index 000000000000..902b7730730e
--- /dev/null
+++ b/games-board/cockatrice/cockatrice-20170505-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="An open-source multiplatform software for playing card games over a network"
+HOMEPAGE="https://github.com/Cockatrice/Cockatrice"
+SRC_URI="${HOMEPAGE}/archive/2017-05-05-Release-2.3.17.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+client +oracle server"
+
+RDEPEND="
+	dev-libs/protobuf
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtwidgets:5
+	client? (
+		dev-qt/qtmultimedia:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtsvg:5
+	)
+	oracle? ( sys-libs/zlib:= )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+# As the default help/about display the sha1 we need it
+SHA1='c96f234'
+
+S=${WORKDIR}/"Cockatrice-2017-05-05-Release-2.3.17"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_CLIENT=$(usex client)
+		-DWITH_ORACLE=$(usex oracle)
+		-DWITH_SERVER=$(usex server)
+		-DICONDIR="/usr/share/icons"
+		-DDESKTOPDIR="/usr/share/applications" )
+
+	# Add date in the help about, come from git originally
+	sed -e 's/^set(PROJECT_VERSION_FRIENDLY.*/set(PROJECT_VERSION_FRIENDLY \"'${SHA1}'\")/' \
+		-i cmake/getversion.cmake || die "sed failed!"
+
+	cmake-utils_src_configure
+}
diff --git a/games-board/cockatrice/cockatrice-20170505.ebuild b/games-board/cockatrice/cockatrice-20170505.ebuild
deleted file mode 100644
index a8edee2cae16..000000000000
--- a/games-board/cockatrice/cockatrice-20170505.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit cmake-utils eutils gnome2-utils
-
-DESCRIPTION="An open-source multiplatform software for playing card games over a network"
-HOMEPAGE="https://github.com/Cockatrice/Cockatrice"
-SRC_URI="${HOMEPAGE}/archive/2017-05-05-Release-2.3.17.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="server +client +oracle"
-
-DEPEND="
-	dev-libs/libgcrypt:0
-	dev-libs/protobuf
-	dev-qt/linguist-tools:5
-	dev-qt/qtconcurrent:5
-	dev-qt/qtprintsupport:5
-	dev-qt/qtcore:5
-	client? (
-		dev-qt/qtgui:5
-		dev-qt/qtmultimedia:5
-		dev-qt/qtsvg:5 )
-	oracle? (
-		sys-libs/zlib
-	)"
-
-# As the default help/about display the sha1 we need it
-SHA1='c96f234'
-
-S=${WORKDIR}/"Cockatrice-2017-05-05-Release-2.3.17"
-
-src_configure() {
-	local mycmakeargs=(
-		-DWITH_CLIENT=$(usex client)
-		-DWITH_ORACLE=$(usex oracle)
-		-DWITH_SERVER=$(usex server)
-		-DICONDIR="/usr/share/icons"
-		-DDESKTOPDIR="/usr/share/applications" )
-
-	# Add date in the help about, come from git originally
-	sed -i 's/^set(PROJECT_VERSION_FRIENDLY.*/set(PROJECT_VERSION_FRIENDLY \"'${SHA1}'\")/' cmake/getversion.cmake || die "Sed failed!"
-	cmake-utils_src_configure
-}
-- 
cgit v1.2.3-65-gdbad