From 5ace34150b61d55161796d966d41925b678a8720 Mon Sep 17 00:00:00 2001
From: Louis Sautier <sbraz@gentoo.org>
Date: Tue, 19 Jun 2018 00:10:17 +0200
Subject: dev-python/plyvel: bump to 1.0.4, add PyPy 3 support

Package-Manager: Portage-2.3.40, Repoman-2.3.9
---
 dev-python/plyvel/Manifest            |  1 +
 dev-python/plyvel/plyvel-1.0.4.ebuild | 49 +++++++++++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)
 create mode 100644 dev-python/plyvel/plyvel-1.0.4.ebuild

(limited to 'dev-python/plyvel')

diff --git a/dev-python/plyvel/Manifest b/dev-python/plyvel/Manifest
index 7271bed75b31..65d9d5a92299 100644
--- a/dev-python/plyvel/Manifest
+++ b/dev-python/plyvel/Manifest
@@ -1 +1,2 @@
 DIST plyvel-0.9.tar.gz 121513 BLAKE2B 78aa0dc3565a9e2298978ea4f2014670cbaa376e35f21be6b3c26a39db2c560d08667c385894bc3df6ae33da266eabf9cf72b81156759a28d75856760ca7cf73 SHA512 21a3bf0bff075e429fef63418c2a2578b22a4904cc2f4f66fc5fbccec22c762d918bea0622a22dcbeee2e60f8d35210ae8f1e63b6d37405f0fdf29ca2fe80586
+DIST plyvel-1.0.4.tar.gz 338470 BLAKE2B dbc33ac9962ed3b74d83158e973ac956bd9fa81c7e1980c1d79187f6e629d0605d821debe4bfd4532120f343b87ee3acd825514884d78b471d3717364837ce42 SHA512 ee397d4f7e2dac4e7b382841559895184dc0356b84da4ff4ccdad43c32aebcb1dcc5020230a5564c875ed5d4401cc8b009438ca3b2e0b50e6467e384f0366171
diff --git a/dev-python/plyvel/plyvel-1.0.4.ebuild b/dev-python/plyvel/plyvel-1.0.4.ebuild
new file mode 100644
index 000000000000..8cac70ffdf33
--- /dev/null
+++ b/dev-python/plyvel/plyvel-1.0.4.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Tests fail with PyPy: https://github.com/wbolster/plyvel/issues/38
+PYTHON_COMPAT=( pypy3 python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python interface to LevelDB"
+HOMEPAGE="https://github.com/wbolster/plyvel"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-libs/leveldb-1.20:="
+DEPEND="
+	${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+python_compile() {
+	# https://wiki.gentoo.org/wiki/Project:Python/Strict_aliasing
+	python_is_python3 || local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build doc doc/_build/html || die
+		HTML_DOCS=( doc/_build/html/. )
+	fi
+}
+
+python_test() {
+	# We need to copy the extension to the package folder
+	local ext="$(ls "${BUILD_DIR}/lib/${PN}/"*.so | head -n1 || die)"
+	ln -s "${ext}" "${PN}" || die
+	py.test || die "tests failed with ${EPYTHON}"
+	rm "${PN}/$(basename "${ext}")" || die
+}
-- 
cgit v1.2.3-65-gdbad