From 5625fcd35454c1af54fbb4a12bc8785894edc2ef Mon Sep 17 00:00:00 2001
From: Mike Gilbert <floppym@gentoo.org>
Date: Sat, 4 May 2019 12:44:37 -0400
Subject: dev-libs/libbytesize: use python-r1

Package-Manager: Portage-2.3.62_p4, Repoman-2.3.12_p87
Signed-off-by: Mike Gilbert <floppym@gentoo.org>
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 dev-libs/libbytesize/libbytesize-2.0-r1.ebuild | 60 -------------------
 dev-libs/libbytesize/libbytesize-2.0-r2.ebuild | 82 ++++++++++++++++++++++++++
 2 files changed, 82 insertions(+), 60 deletions(-)
 delete mode 100644 dev-libs/libbytesize/libbytesize-2.0-r1.ebuild
 create mode 100644 dev-libs/libbytesize/libbytesize-2.0-r2.ebuild

(limited to 'dev-libs')

diff --git a/dev-libs/libbytesize/libbytesize-2.0-r1.ebuild b/dev-libs/libbytesize/libbytesize-2.0-r1.ebuild
deleted file mode 100644
index 6da71cd71480..000000000000
--- a/dev-libs/libbytesize/libbytesize-2.0-r1.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{5,6,7} )
-
-inherit autotools python-single-r1
-
-DESCRIPTION="Tiny library providing a C \"class\" for working with arbitrary big sizes in bytes"
-HOMEPAGE="https://github.com/storaged-project/libbytesize"
-SRC_URI="https://github.com/storaged-project/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-LICENSE="LGPL-2+"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
-IUSE="doc python test tools"
-
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-RDEPEND="
-	dev-libs/gmp:0=
-	dev-libs/mpfr:=
-	dev-libs/libpcre2
-	python? ( ${PYTHON_DEPS} )
-"
-
-DEPEND="${RDEPEND}"
-
-BDEPEND="
-	sys-devel/gettext
-	doc? ( dev-util/gtk-doc )
-	test? (
-		dev-python/pocketlint[${PYTHON_USEDEP}]
-		dev-python/polib[${PYTHON_USEDEP}]
-	)
-"
-
-DOCS=( NEWS.rst README.md )
-
-RESTRICT="test"
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-src_configure() {
-	local myeconfargs=(
-		$(use_with doc gtk-doc)
-		$(use_with python python3)
-		$(use_with tools)
-	)
-	econf "${myeconfargs[@]}"
-}
-
-src_install() {
-	default
-	use python && python_optimize
-	find "${ED}" -name "*.la*" -delete || die
-}
diff --git a/dev-libs/libbytesize/libbytesize-2.0-r2.ebuild b/dev-libs/libbytesize/libbytesize-2.0-r2.ebuild
new file mode 100644
index 000000000000..bfb8a984b132
--- /dev/null
+++ b/dev-libs/libbytesize/libbytesize-2.0-r2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit autotools python-r1
+
+DESCRIPTION="Tiny library providing a C \"class\" for working with arbitrary big sizes in bytes"
+HOMEPAGE="https://github.com/storaged-project/libbytesize"
+SRC_URI="https://github.com/storaged-project/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc python test tools"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	dev-libs/gmp:0=
+	dev-libs/mpfr:=
+	dev-libs/libpcre2
+	python? ( ${PYTHON_DEPS} )
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	sys-devel/gettext
+	doc? ( dev-util/gtk-doc )
+	test? (
+		dev-python/pocketlint[${PYTHON_USEDEP}]
+		dev-python/polib[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( NEWS.rst README.md )
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+python_do() {
+	if use python; then
+		python_foreach_impl run_in_build_dir "$@"
+	else
+		"$@"
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with doc gtk-doc)
+		$(use_with python python3)
+		$(use_with tools)
+	)
+	local ECONF_SOURCE="${S}"
+	python_do econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	python_do emake
+}
+
+src_test() {
+	python_do emake check
+}
+
+install_helper() {
+	emake DESTDIR="${D}" install
+	use python && python_optimize
+}
+
+src_install() {
+	python_do install_helper
+	einstalldocs
+	find "${ED}" -name "*.la" -type f -delete || die
+}
-- 
cgit v1.2.3-65-gdbad