1 files changed, 0 insertions, 70 deletions
diff --git a/media-libs/glew/glew-1.9.0.ebuild b/media-libs/glew/glew-1.9.0.ebuild
deleted file mode 100644
index b2ca9008f61d..000000000000
--- a/media-libs/glew/glew-1.9.0.ebuild
+++ /dev/null
@@ -1,70 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=4
-inherit multilib toolchain-funcs
-
-DESCRIPTION="The OpenGL Extension Wrangler Library"
-HOMEPAGE="http://glew.sourceforge.net/"
-SRC_URI="mirror://sourceforge/${PN}/${P}.tgz"
-
-LICENSE="BSD MIT"
-SLOT="0"
-KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
-IUSE="doc static-libs"
-
-RDEPEND="virtual/glu
-	virtual/opengl
-	x11-libs/libX11
-	x11-libs/libXext
-	x11-libs/libXi
-	x11-libs/libXmu"
-DEPEND=${RDEPEND}
-
-pkg_setup() {
-	myglewopts=(
-		AR="$(tc-getAR)"
-		STRIP=true
-		CC="$(tc-getCC)"
-		LD="$(tc-getCC) ${LDFLAGS}"
-		M_ARCH=""
-		LDFLAGS.EXTRA=""
-		POPT="${CFLAGS}"
-	)
-}
-
-src_prepare() {
-	sed -i \
-		-e '/INSTALL/s:-s::' \
-		-e '/$(CC) $(CFLAGS) -o/s:$(CFLAGS):$(CFLAGS) $(LDFLAGS):' \
-		Makefile || die
-
-	if ! use static-libs ; then
-		sed -i \
-			-e '/glew.lib:/s|lib/$(LIB.STATIC) ||' \
-			-e '/glew.lib.mx:/s|lib/$(LIB.STATIC.MX) ||' \
-			-e '/INSTALL.*LIB.STATIC/d' \
-			Makefile || die
-	fi
-
-	# don't do stupid Solaris specific stuff that won't work in Prefix
-	cp config/Makefile.linux config/Makefile.solaris || die
-	# and let freebsd be built as on linux too
-	cp config/Makefile.linux config/Makefile.freebsd || die
-}
-
-src_compile(){
-	emake GLEW_DEST="${EPREFIX}/usr" "${myglewopts[@]}"
-}
-
-src_install() {
-	emake \
-		GLEW_DEST="${ED}/usr" \
-		LIBDIR="${ED}/usr/$(get_libdir)" \
-		"${myglewopts[@]}" \
-		install.all
-
-	dodoc TODO.txt
-	use doc && dohtml doc/*
-}