mate-base/mate-applets: Bump to 1.24.1

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Adam Feldman <NP-Hardass@gentoo.org>

2 files changed, 98 insertions, 0 deletions

diff --git a/mate-base/mate-applets/Manifest b/mate-base/mate-applets/Manifest
index eafd87668896..146cf78b934d 100644
--- a/mate-base/mate-applets/Manifest
+++ b/mate-base/mate-applets/Manifest
@@ -1 +1,2 @@
 DIST mate-applets-1.24.0.tar.xz 8142812 BLAKE2B cbb76d6d64bb6e9b9f93197dbe79e2751877b0604c5a84ff4b6b00608f2930925bdbc2824dc96848c84496fa5f16ab38458775727b22cb07f4db9ca854f93c42 SHA512 345a80b123c705997d44ac5a4bea5249045d75181c3802cf49b2eb08decc14a12f75f2e06e6ebfae267b937ff10edf7638cd64332e2e2e731695e6260df5222e
+DIST mate-applets-1.24.1.tar.xz 8222540 BLAKE2B f018f131cedda486a28c3a125c07efaf5c3111f95c17b0c3fbdd0b1f084ddf851d46ea4ef511a1e57f6d9f7f29a28e48ab010abc4cc6d87c1315b79bfbf01849 SHA512 d29e39a140310fef84cb0fe631568e0177ca5faaf2bf566211a23b32613fd6aabf06dd8ecd81a16e09553c659a7feda9ba372bb62a70504a235be58e07726ed2
diff --git a/mate-base/mate-applets/mate-applets-1.24.1.ebuild b/mate-base/mate-applets/mate-applets-1.24.1.ebuild
new file mode 100644
index 000000000000..63d6ba9facb2
--- /dev/null
+++ b/mate-base/mate-applets/mate-applets-1.24.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Applets for the MATE Desktop and Panel"
+LICENSE="CC-BY-SA-3.0 FDL-1.1+ GPL-2+ GPL-3+ LGPL-2+"
+SLOT="0"
+
+IUSE="X +cpupower ipv6 policykit +upower"
+
+REQUIRED_USE="policykit? ( cpupower )"
+
+COMMON_DEPEND="
+	dev-libs/atk
+	>=dev-libs/dbus-glib-0.74
+	>=dev-libs/glib-2.50:2
+	>=dev-libs/libmateweather-1.17.0
+	>=dev-libs/libxml2-2.5:2
+	>=gnome-base/libgtop-2.12.0:2=
+	>=gnome-extra/gucharmap-3.0:2.90
+	>=mate-base/mate-panel-1.17.0
+	>=net-wireless/wireless-tools-28_pre9:0
+	>=sys-apps/dbus-1.10.0
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/gtksourceview:3.0
+	>=x11-libs/libnotify-0.7
+	x11-libs/libX11
+	>=x11-libs/libwnck-3.0:3
+	x11-libs/pango
+	cpupower? (
+		sys-power/cpupower
+		policykit? ( >=sys-auth/polkit-0.97:0 )
+	)
+	upower? ( >=sys-power/upower-0.9.23 )
+	!!net-analyzer/mate-netspeed
+"
+
+RDEPEND="${COMMON_DEPEND}
+	mate-base/caja
+	mate-base/mate-desktop
+	>=mate-base/mate-settings-daemon-1.6
+	virtual/libintl
+"
+
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xml-dtd:4.3
+	app-text/rarian
+	>=app-text/scrollkeeper-dtd-1:1.0
+	app-text/yelp-tools
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+
+	# configure.ac logic is a little hinky
+	# and ignores --enable flags for cpufreq
+	use cpupower || myconf="--disable-cpufreq"
+
+	mate_src_configure \
+		--libexecdir=/usr/libexec/mate-applets \
+		$(use_with X x) \
+		$(use_with upower) \
+		$(use_enable ipv6) \
+		$(use_enable policykit polkit) \
+		"${myconf[@]}"
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	emake check
+}
+
+src_install() {
+	mate_src_install
+
+	local APPLETS="accessx-status battstat charpick command cpufreq drivemount
+			geyes mateweather multiload netspeed stickynotes
+			timerapplet trashapplet"
+
+	for applet in ${APPLETS}; do
+		docinto ${applet}
+
+		for d in AUTHORS ChangeLog NEWS README README.themes TODO; do
+			[ -s ${applet}/${d} ] && dodoc ${applet}/${d}
+		done
+	done
+}