From 5f501625700f803404416002fd14bb20b12bdcef Mon Sep 17 00:00:00 2001
From: Brian Dolbec <brian.dolbec@gmail.com>
Date: Sat, 17 Jul 2010 12:30:37 -0700
Subject: edit a copy of layman-9999's ebuild for the development layman api
 branch I am developing.

---
 app-portage/layman/layman-9999.ebuild | 106 ++++++++++++++++++++++++++++++++++
 app-portage/layman/metadata.xml       |  16 +++++
 2 files changed, 122 insertions(+)
 create mode 100644 app-portage/layman/layman-9999.ebuild
 create mode 100644 app-portage/layman/metadata.xml

diff --git a/app-portage/layman/layman-9999.ebuild b/app-portage/layman/layman-9999.ebuild
new file mode 100644
index 0000000..7614610
--- /dev/null
+++ b/app-portage/layman/layman-9999.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header:                                                                                       Exp $
+
+EAPI="2"
+PYTHON_DEPEND="2:2.5"
+SUPPORT_PYTHON_ABIS="1"
+
+inherit eutils distutils git
+
+DESCRIPTION="An experimental development version of a python script for retrieving gentoo overlays."
+HOMEPAGE="http://layman.sourceforge.net"
+SRC_URI=""
+EGIT_REPO_URI="http://dev.gentooexperimental.org/~dol-sen/git/layman.git/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="bazaar cvs darcs git mercurial subversion test"
+
+COMMON_DEPS="dev-lang/python[xml]"
+DEPEND="${COMMON_DEPS}
+	test? ( dev-vcs/subversion )
+	app-text/xmlto"
+RDEPEND="${COMMON_DEPS}
+	bazaar? ( dev-vcs/bzr )
+	cvs? ( dev-vcs/cvs )
+	darcs? ( dev-vcs/darcs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	subversion? (
+		|| (
+			>=dev-vcs/subversion-1.5.4[webdav-neon]
+			>=dev-vcs/subversion-1.5.4[webdav-serf]
+		)
+	)"
+RESTRICT_PYTHON_ABIS="2.4 3.*"
+
+pkg_setup() {
+	if ! has_version dev-vcs/subversion; then
+		ewarn "You do not have dev-vcs/subversion installed!"
+		ewarn "While layman does not exactly depend on this"
+		ewarn "version control system you should note that"
+		ewarn "most available overlays are offered via"
+		ewarn "dev-vcs/subversion. If you do not install it"
+		ewarn "you will be unable to use these overlays."
+		ewarn
+	fi
+}
+
+src_test() {
+	testing() {
+		for suite in layman/tests/{dtest,external}.py ; do
+			PYTHONPATH="." "$(PYTHON)" ${suite} \
+					|| die "test suite '${suite}' failed"
+		done
+	}
+	python_execute_function testing
+}
+
+src_compile() {
+	distutils_src_compile
+	emake -C doc || die "emake -C doc failed"
+}
+
+src_install() {
+	distutils_src_install
+
+	dodir /etc/layman
+
+	cp etc/layman.cfg "${D}"/etc/layman/
+
+	doman doc/layman.8
+	dohtml doc/layman.8.html
+
+	keepdir /var/lib/layman
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+
+	einfo "You are now ready to add overlays into your system."
+	einfo
+	einfo "  layman -L"
+	einfo
+	einfo "will display a list of available overlays."
+	einfo
+	elog  "Select an overlay and add it using"
+	elog
+	elog  "  layman -a overlay-name"
+	elog
+	elog  "If this is the very first overlay you add with layman,"
+	elog  "you need to append the following statement to your"
+	elog  "/etc/make.conf file:"
+	elog
+	elog  "  source /var/lib/layman/make.conf"
+	elog
+	elog  "If you modify the 'storage' parameter in the layman"
+	elog  "configuration file (/etc/layman/layman.cfg) you will"
+	elog  "need to adapt the path given above to the new storage"
+	elog  "directory."
+	elog
+	ewarn "Please add the 'source' statement to make.conf only AFTER "
+	ewarn "you added your first overlay. Otherwise portage will fail."
+	epause 5
+}
diff --git a/app-portage/layman/metadata.xml b/app-portage/layman/metadata.xml
new file mode 100644
index 0000000..e56b051
--- /dev/null
+++ b/app-portage/layman/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>no-herd</herd>
+<maintainer>
+  <email>brian.dolbec@gmail.com</email>
+  <name>Brian Dolbec (dol-sen)</name>
+  <description>This is an experimental version used to develop a public API for consumer apps.</description>
+</maintainer>
+<use>
+  <flag name='bazaar'>Support <pkg>dev-vcs/bzr</pkg> based overlays</flag>
+  <flag name='darcs'>Support <pkg>dev-vcs/darcs</pkg> based overlays</flag>
+  <flag name='git'>Support <pkg>dev-vcs/git</pkg> based overlays</flag>
+  <flag name='mercurial'>Support <pkg>dev-vcs/mercurial</pkg> based overlays</flag>
+</use>
+</pkgmetadata>
-- 
cgit v1.2.3-65-gdbad