# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
AUTOTOOLS_AUTORECONF="1"

inherit flag-o-matic linux-info linux-mod autotools-utils

MY_PV=${PV/_rc/rc}
MY_P="${PN}-${MY_PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="Skyld AV: on-access scanning daemon for ClamAV using fanotify"
#SRC_URI="https://github.com/xypron/skyldav/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
SRC_URI="http://dev.gentoo.org/~wschlich/src/${CATEGORY}/${PN}/${MY_P}.tar.gz"
HOMEPAGE="http://xypron.github.io/skyldav/"

KEYWORDS="~amd64 ~x86"
SLOT="0"
LICENSE="Apache-2.0"
IUSE="libnotify"

RDEPEND="sys-apps/util-linux
	sys-libs/libcap
	libnotify? (
		media-libs/libcanberra[gtk]
		x11-libs/libnotify
		x11-libs/gtk+:2
	)"
DEPEND="${RDEPEND}
	sys-devel/autoconf-archive"

DOCS=( AUTHORS NEWS README )

AUTOTOOLS_IN_SOURCE_BUILD="1"

pkg_setup() {
	linux-info_pkg_setup
	kernel_is ge 3 8 0 || die "Linux 3.8.0 or newer recommended"
	CONFIG_CHECK="FANOTIFY FANOTIFY_ACCESS_PERMISSIONS"
	check_extra_config
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-0.2_rc3-examples.patch"
	epatch "${FILESDIR}/${PN}-0.2_rc3-sbin.patch"
	epatch "${FILESDIR}/${PN}-0.2_rc3-conf.patch"
	use libnotify || epatch "${FILESDIR}/${P}-disable-skyldavnotify.patch"
	autotools-utils_src_prepare
}

src_install() {
	autotools-utils_src_install
	newinitd "${FILESDIR}/${PN}.initd" ${PN}
	newconfd "${FILESDIR}/${PN}.confd" ${PN}
}