# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3
inherit eutils git linux-mod

DESCRIPTION="a general purpose writeback block cache for Linux"
HOMEPAGE="https://github.com/facebook/flashcache"
EGIT_REPO_URI="https://github.com/facebook/flashcache.git"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=">=virtual/linux-sources-2.6.18"
RDEPEND=""

CONFIG_CHECK="BLK_DEV_DM"

MODULE_NAMES="flashcache(kernel/drivers/block:${S}:${S}/src)
	flashcache-wt(kernel/drivers/block:${S}/flashcache-wt:${S}/flashcache-wt/src)"

src_prepare() {
	epatch "${FILESDIR}/${P}-2.6.37.patch"
}

src_compile() {
	set_arch_to_kernel

	emake KERNEL_TREE="${KERNEL_DIR}" || die

	cd flashcache-wt
	emake KERNEL_TREE="${KERNEL_DIR}" || die
}

src_install() {
	linux-mod_src_install

	(
		cd "${S}/src/utils"
		dosbin flashcache_create flashcache_destroy flashcache_load || die
	)
	(
		cd "${S}/flashcache-wt/src/utils"
		dosbin flashcache_wt_create || die
	)

	dodoc README* doc/* || die
	newdoc flashcache-wt/README README.flashcache-wt || die
}