blob: 166461322051bdf6c63d35b4ec8673f9ec82c8d7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
|
# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/maxima/maxima-5.10.0.ebuild,v 1.1 2006/10/31 11:24:06 je_fro Exp $
inherit eutils elisp-common autotools
DESCRIPTION="Free computer algebra environment, based on Macsyma"
HOMEPAGE="http://maxima.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2 AECA"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="cmucl clisp sbcl gcl tetex emacs auctex tk nls unicode"
RDEPEND=">=sci-visualization/gnuplot-4.0
app-text/gv
tetex? ( virtual/tetex )
emacs? ( virtual/emacs )
auctex? ( app-emacs/auctex )
clisp? ( >=dev-lisp/clisp-2.33.2-r1 )
gcl? ( >=dev-lisp/gcl-2.6.7 )
sbcl? ( >=dev-lisp/sbcl-0.9.4 app-misc/rlwrap )
cmucl? ( >=dev-lisp/cmucl-19a app-misc/rlwrap )
!clisp? ( !sbcl? ( !cmucl? ( >=dev-lisp/gcl-2.6.7 ) ) )
tk? ( >=dev-lang/tk-8.3.3 )"
DEPEND="${RDEPEND} >=sys-apps/texinfo-4.3"
for lang in es pt; do
IUSE="${IUSE} linguas_${lang}"
done
# chosen apps are hardcoded in maxima source:
# - ghostview for postscript (changed to gv)
# - acroread for pdf
# - xdvi for dvi. this could change, with pain.
src_unpack() {
unpack ${A}
epatch "${FILESDIR}/${P}.patch"
}
src_compile() {
# automake version mismatch otherwise (sbcl only)
use sbcl && eautoreconf
# remove rmaxima if neither cmucl nor sbcl
if ! use sbcl && ! use cmucl ; then
sed -i -e '/^@WIN32_FALSE@bin_SCRIPTS/s/rmaxima//' src/Makefile.in
fi
# remove xmaxima if no tk in USE
local myconf=""
if use tk; then
myconf="${myconf} --with-wish=wish"
else
myconf="${myconf} --with-wish=none"
sed -i -e '/^SUBDIRS/s/xmaxima//' interfaces/Makefile.in
fi
# enable gcl if no other lisp is selected
if use gcl || (! use cmucl && ! use clisp && ! use sbcl ); then
if ! built_with_use dev-lisp/gcl ansi; then
eerror "GCL must be installed with ANSI."
eerror "Try USE=\"ansi\" emerge gcl"
die "This package needs gcl with USE=ansi"
fi
myconf="${myconf} --enable-gcl"
fi
# use existing translated docs
if use nls; then
for lang in es pt; do
if use linguas_${lang}; then
myconf="${myconf} --enable-lang-${lang}"
use unicode && myconf="${myconf} --enable-lang-${lang}-utf8"
fi
done
fi
econf \
$(use_enable cmucl) \
$(use_enable clisp) \
$(use_enable sbcl) \
${myconf} \
|| die "econf failed"
emake || die "emake failed"
}
src_install() {
make DESTDIR="${D}" install || die "make install failed"
use tk && make_desktop_entry xmaxima xmaxima \
/usr/share/${PN}/${PV}/xmaxima/maxima-new.png
if use emacs; then
sed -e "s/PV/${PV}/" "${FILESDIR}"/50maxima-gentoo.el > 50maxima-gentoo.el
elisp-site-file-install 50maxima-gentoo.el
fi
if use tetex; then
insinto /usr/share/texmf/tex/latex/emaxima
doins interfaces/emacs/emaxima/emaxima.sty
fi
insinto /usr/share/${PN}/${PV}/doc
doins AUTHORS ChangeLog COPYING NEWS README*
dodir /usr/share/doc
dosym /usr/share/${PN}/${PV}/doc /usr/share/doc/${PF}
}
pkg_preinst() {
# some lisp do not gunzip info files on the fly
if use cmucl || use clisp || use sbcl; then
for infofile in $(ls ${D}/usr/share/info/*.gz); do
gunzip ${infofile}
done
fi
}
pkg_postinst() {
use emacs && elisp-site-regen
use tetex && mktexlsr
}
pkg_postrm() {
use emacs && elisp-site-regen
}
|
GitWeb