sci-chemistry/prodecomp/prodecomp-3.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/prodecomp/prodecomp-3.0.ebuild,v 1.1 2010/10/20 06:25:57 jlec Exp $

EAPI="3"

PYTHON_DEPEND="2"
PYTHON_USE_WITH="tk"

inherit python

DESCRIPTION="Decomposition-based analysis of NMR projections"
HOMEPAGE="http://www.lundberg.gu.se/nmr/software.php?program=PRODECOMP"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
LICENSE="GPL-2"
IUSE="examples"

RDEPEND="sci-libs/scipy"
DEPEND=""

S="${WORKDIR}"/NMRProjAnalys

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_install() {
	if use examples; then
		insinto /usr/share/${PN}
		doins -r ExampleData Results || die
	fi

	insinto /usr/share/doc/${PF}
	doins ProjTools/Manual.pdf || die
	rm -rf ProjTools/Manual.pdf ProdecompOutput || die

	insinto $(python_get_sitedir)
	doins -r ProjTools || die
	mv "${ED}"/$(python_get_sitedir)/{ProjTools,${PN}} || die

	cat >> "${T}"/${PN} <<- EOF
	#!/bin/bash
	$(PYTHON) -O "${EPREFIX}"/$(python_get_sitedir)/${PN}/ProjAnalys.py $@
	EOF
	dobin "${T}"/${PN} || die

	dosym ../../../../share/doc/${PF}/Manual.pdf $(python_get_sitedir)/${PN}/Manual.pdf
}