net-p2p/bittorrent/bittorrent-4.2.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/bittorrent/bittorrent-4.2.2.ebuild,v 1.10 2006/02/07 02:47:06 agriffis Exp $

inherit distutils fdo-mime eutils

MY_P="${P/bittorrent/BitTorrent}"
#MY_P="${MY_P/}"
S=${WORKDIR}/${MY_P}

DESCRIPTION="tool for distributing files via a distributed network of nodes"
HOMEPAGE="http://www.bittorrent.com/"
SRC_URI="http://www.bittorrent.com/dl/${MY_P}.tar.gz"

LICENSE="BitTorrent"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ppc sparc x86"
IUSE="gtk"

RDEPEND="gtk? (
		>=x11-libs/gtk+-2.4
		>=dev-python/pygtk-2.4
	)
	>=dev-lang/python-2.3
	>=dev-python/pycrypto-2.0
	!virtual/bittorrent"
DEPEND="${RDEPEND}
	app-arch/gzip
	>=sys-apps/sed-4.0.5
	dev-python/dnspython"
PROVIDE="virtual/bittorrent"

DOCS="TRACKERLESS.txt LICENSE.txt public.key"
PYTHON_MODNAME="BitTorrent"

src_unpack() {
	unpack ${A}
	cd ${S}

	# path for documentation is in lowercase (see bug #109743)
	sed -i -r "s:(dp.*appdir):\1.lower():" BitTorrent/platform.py
}

src_install() {
	distutils_src_install
	if ! use gtk; then
		rm ${D}/usr/bin/bittorrent
	fi
	dohtml redirdonate.html

	mv ${S}/{credits-l10n.txt,credits.txt} \
		${D}/usr/share/doc/${P}
	mv ${D}/usr/share/doc/${PF} ${D}/usr/share/doc/${P}

	if use gtk ; then
		cp ${D}/usr/share/pixmaps/${MY_P}/bittorrent.ico ${D}/usr/share/pixmaps/
		make_desktop_entry "bittorrent" "BitTorrent" \
			/usr/share/pixmaps/bittorrent.ico "Network"
		echo "MimeType=application/x-bittorrent" \
			>> ${D}/usr/share/applications/bittorrent-${PN}.desktop
	fi

	insinto /etc/conf.d
	newins ${FILESDIR}/bittorrent-tracker.confd bittorrent-tracker

	exeinto /etc/init.d
	newexe ${FILESDIR}/bittorrent-tracker.initd bittorrent-tracker
}

pkg_postinst() {
	einfo
	einfo "Remember that BitTorrent has changed file naming scheme"
	einfo "To run BitTorrent just execute /usr/bin/bittorrent"
	einfo
	if [ -f ${ROOT}/etc/init.d/bttrack -o -f ${ROOT}/etc/conf.d/bttrack ]; then
		einfo "Please use /etc/init.d/bittorrent-tracker and "
		einfo "/etc/conf.d/bittorrent-tracker instead of"
		einfo "/etc/init.d/bttrack and /etc/conf.d/bttrack. "
		einfo "You can safety remove the old files"
		einfo
	fi
	distutils_pkg_postinst
	fdo-mime_desktop_database_update
}