dev-lang/ruby/ruby-1.8.0_pre2-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/ruby/ruby-1.8.0_pre2-r3.ebuild,v 1.1 2003/06/10 22:38:16 twp Exp $

IUSE="socks5 tcltk"

inherit flag-o-matic eutils

S=${WORKDIR}/${P%_pre*}
DESCRIPTION="An object-oriented scripting language"
SRC_URI="ftp://ftp.ruby-lang.org/pub/ruby/1.8/${P/_pre/-preview}.tar.gz"
HOMEPAGE="http://www.ruby-lang.org/"
LICENSE="Ruby"
KEYWORDS="~x86 ~alpha"
SLOT="0"

DEPEND=">=sys-libs/glibc-2.1.3
	>=sys-libs/gdbm-1.8.0
	>=sys-libs/readline-4.1
	>=sys-libs/ncurses-5.2
	socks5? ( >=net-misc/dante-1.1.13 )
	tcltk?  ( dev-lang/tk )
	sys-apps/findutils"

src_unpack() {
	unpack ${A}
	cd ${WORKDIR}

	# Allow Ruby to build correctly with Dante/SOCKS support.
	epatch ${FILESDIR}/ruby-1.8.0_pre2-socks.patch
}

src_compile() {
	local myconf='--enable-shared'

	filter-flags -fomit-frame-pointer

	# Socks support via dante
	if use socks5; then
		myconf="${myconf} --enable-socks"
	else
		# Socks support can't be disabled as long as SOCKS_SERVER is
		# set and socks library is present, so need to unset
		# SOCKS_SERVER in that case.
		myconf="${myconf} --disable-socks"
		unset SOCKS_SERVER
	fi

	econf ${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install () {
	make DESTDIR=${D} install || die "make install failed"
	dodoc COPYING* ChangeLog MANIFEST README* ToDo
	# Fix perms on directories (bug # 22446)
	find ${D} -type d -print0 | xargs -0 chmod 755
}