app-text/pinfo/pinfo-0.6.10-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/pinfo/pinfo-0.6.10-r3.ebuild,v 1.8 2013/02/27 20:20:39 jer Exp $

EAPI=4

inherit eutils flag-o-matic

DESCRIPTION="Hypertext info and man viewer based on (n)curses"
HOMEPAGE="http://pinfo.alioth.debian.org/"
SRC_URI="https://alioth.debian.org/frs/download.php/3351/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 hppa ia64 ~mips ppc ppc64 sparc x86 ~x86-fbsd"
IUSE="nls readline"

RDEPEND="
	sys-libs/ncurses[-tinfo]
	nls? ( virtual/libintl )
"

DEPEND="
	${RDEPEND}
	sys-devel/bison
	nls? ( sys-devel/gettext )
"

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-0.6.9-as-needed.patch \
		"${FILESDIR}"/${PN}-0.6.9-GROFF_NO_SGR.patch \
		"${FILESDIR}"/${PN}-0.6.9-lzma-xz.patch \
		"${FILESDIR}"/${P}-version.patch \
		"${FILESDIR}"/${P}-info-suffix.patch \
		"${FILESDIR}"/${P}-dir-file.patch

	# autoconf does not work as expected
	./autogen.sh || die

	append-cflags -D_BSD_SOURCE # sbrk()
}

src_configure() {
	econf $(use_with readline) $(use_enable nls)
}

src_install() {
	emake DESTDIR="${D}" sysconfdir=/etc install
}