# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pydns/pydns-2.3.6-r1.ebuild,v 1.2 2013/07/09 00:09:23 jer Exp $

EAPI=5
PYTHON_COMPAT=( python{2_5,2_6,2_7} pypy2_0 )

inherit distutils-r1

DESCRIPTION="Python module for DNS (Domain Name Service)"
HOMEPAGE="http://pydns.sourceforge.net/ http://pypi.python.org/pypi/pydns"
SRC_URI="http://downloads.sourceforge.net/project/pydns/pydns/${P}/${P}.tar.gz"

LICENSE="CNRI"
SLOT="2"
KEYWORDS="~amd64 ~hppa ~x86"
IUSE="examples"

DEPEND="!dev-python/pydns:0
	virtual/libiconv"
RDEPEND=""

DOCS=( CREDITS )
# Funny a dns package attempts to use the network on tests
# Await the day that gentoo chills out on such a blanket law.
RESTRICT=test

python_prepare_all() {
	# Fix encodings (should be utf-8 but is latin1).
	for i in DNS/{Lib,Type}.py; do
		iconv -f ISO-8859-1 -t UTF-8 < "${i}" > "${i}~" && mv -f "${i}~" "${i}" || rm -f "${i}~"
	done

	# Don't compile bytecode.
	sed -i -e 's:^\(compile\|optimize\).*:\1 = 0:g' setup.cfg

	# cleanup docs
	rm -f -- "README-guido.txt"
	mv -f -- "README.txt" "README"
	mv -f -- "CREDITS.txt" "CREDITS"
}

python_test() {
	local test
	for test in tests/{test.py,test[2-5].py,testsrv.py}
	do
		"${PYTHON}" $test || die
	done
}

python_install_all(){
	use examples && local EXAMPLES=( ./{tests,tools}/. )
	distutils-r1_python_install_all
}