# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ada/gtkada/gtkada-2.4.0.ebuild,v 1.4 2006/05/13 21:01:51 george Exp $

inherit eutils

Name="GtkAda"
DESCRIPTION="Gtk+ bindings to the Ada language"
HOMEPAGE="http://libre.act-europe.fr/GtkAda"
SRC_URI="http://libre.act-europe.fr/${Name}/${Name}-${PV}.tgz"

LICENSE="GMGPL"
SLOT="1"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="nls opengl"

DEPEND=">=dev-lang/gnat-3.14p
	>=x11-libs/gtk+-2.2.0
	>=sys-apps/sed-4"
RDEPEND=""

S="${WORKDIR}/${Name}-${PV}"

src_compile() {
	local myconf
	myconf=""

	use nls    || myconf="${myconf} --disable-nls"
	use opengl && myconf="${myconf} --with-GL=auto"

	sed -i -e "s|-I\$prefix/include|-I/usr/lib/ada/adainclude|" \
		src/gtkada-config.in
	sed -i -e "s|-L\$prefix/include|-L/usr/lib/ada/adalib|" \
		src/gtkada-config.in

	# Avoid compilation problems during upgrades/reinstalls:
	unset ADA_INCLUDE_PATH
	unset ADA_OBJECTS_PATH

	econf ${myconf} || die "./configure failed"

	make GNATFLAGS="${ADACFLAGS}" || die
}

src_install() {
	make prefix=${D}/usr \
		incdir=${D}/usr/lib/ada/adainclude/gtkada \
		libdir=${D}/usr/lib/ada/adalib/gtkada \
		alidir=${D}/usr/lib/ada/adalib/gtkada install \
		|| die

	dosym /usr/lib/ada/adalib/gtkada/libgtkada_glade-2.4.so.1 /usr/lib
	dosym /usr/lib/ada/adalib/gtkada/libgtkada_gl-2.4.so.1 /usr/lib
	dosym /usr/lib/ada/adalib/gtkada/libgnomeada-2.4.so.1 /usr/lib
	dosym /usr/lib/ada/adalib/gtkada/libgtkada-2.4.so.1 /usr/lib
	dosym /usr/lib/ada/adalib/gtkada/libgtkada_glade.so /usr/lib
	dosym /usr/lib/ada/adalib/gtkada/libgtkada_gl.so /usr/lib
	dosym /usr/lib/ada/adalib/gtkada/libgnomeada.so /usr/lib
	dosym /usr/lib/ada/adalib/gtkada/libgtkada.so /usr/lib

	#arrange docs properly
	dodoc ANNOUNCE AUTHORS COPYING README
	cd ${D}/usr
	mv doc/${Name}/* share/${PN}/examples/ share/doc/${PF}
	rm -rf doc/ share/${PN}/
	cd ${S} #in case need to add anything afterwards

	#set up environment
	dodir /etc/env.d
	echo "ADA_OBJECTS_PATH=/usr/lib/ada/adalib/${PN}" \
		> ${D}/etc/env.d/55gtkada
	echo "ADA_INCLUDE_PATH=/usr/lib/ada/adainclude/${PN}" \
		>> ${D}/etc/env.d/55gtkada
}

pkg_postinst() {
	einfo "The environment has been set up to make gnat automatically find files for"
	einfo "GtkAda. In order to immediately activate these settings please do:"
	einfo "   env-update && source /etc/profile"
	einfo "Otherwise the settings will become active next time you login"
}