From 3d71d762a3d17b076a16f5495f64e685dde6712c Mon Sep 17 00:00:00 2001
From: Sebastien Fabbro <bicatali@gentoo.org>
Date: Wed, 29 Jan 2014 18:52:01 +0000
Subject: Version bump

(Portage version: 2.2.8-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)
---
 sci-visualization/veusz/ChangeLog         | 10 ++++-
 sci-visualization/veusz/metadata.xml      |  2 +
 sci-visualization/veusz/veusz-1.20.ebuild | 64 +++++++++++++++++++++++++++++++
 3 files changed, 74 insertions(+), 2 deletions(-)
 create mode 100644 sci-visualization/veusz/veusz-1.20.ebuild

(limited to 'sci-visualization')

diff --git a/sci-visualization/veusz/ChangeLog b/sci-visualization/veusz/ChangeLog
index f979ec68a8da..8602f0207886 100644
--- a/sci-visualization/veusz/ChangeLog
+++ b/sci-visualization/veusz/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-visualization/veusz
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/veusz/ChangeLog,v 1.44 2013/07/16 16:29:13 bicatali Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/veusz/ChangeLog,v 1.45 2014/01/29 18:52:01 bicatali Exp $
+
+*veusz-1.20 (29 Jan 2014)
+
+  29 Jan 2014; Sébastien Fabbro <bicatali@gentoo.org> +veusz-1.20.ebuild,
+  metadata.xml:
+  Version bump
 
 *veusz-1.18 (16 Jul 2013)
 
diff --git a/sci-visualization/veusz/metadata.xml b/sci-visualization/veusz/metadata.xml
index f5b277bf9edd..74a84ef2ff38 100644
--- a/sci-visualization/veusz/metadata.xml
+++ b/sci-visualization/veusz/metadata.xml
@@ -10,6 +10,8 @@
 </longdescription>
 <use>
   <flag name="fits">Add FITS format via <pkg>dev-python/pyfits</pkg></flag>
+  <flag name="emf">Add FITS format via <pkg>dev-python/pyemf</pkg></flag>
+  <flag name="vo">Add Virtual Observatory tools via <pkg>dev-python/astropy</pkg></flag>
 </use>
 <upstream>
   <remote-id type="pypi">veusz</remote-id>
diff --git a/sci-visualization/veusz/veusz-1.20.ebuild b/sci-visualization/veusz/veusz-1.20.ebuild
new file mode 100644
index 000000000000..024dd406b211
--- /dev/null
+++ b/sci-visualization/veusz/veusz-1.20.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/veusz/veusz-1.20.ebuild,v 1.1 2014/01/29 18:52:01 bicatali Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
+
+inherit eutils fdo-mime distutils-r1 virtualx
+
+DESCRIPTION="Qt scientific plotting package with good Postscript output"
+HOMEPAGE="http://home.gna.org/veusz/"
+SRC_URI="http://download.gna.org/${PN}/${P}.tar.gz"
+
+IUSE="dbus doc emf fits hdf5 vo"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="GPL-2"
+
+DEPEND="dev-python/numpy[${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}
+	>=dev-python/PyQt4-4.6[X,svg,${PYTHON_USEDEP}]
+	dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+	emf? ( dev-python/pyemf[$(python_gen_usedep 'python2*')] )
+	fits? ( virtual/pyfits[${PYTHON_USEDEP}] )
+	hdf5? ( dev-python/h5py[${PYTHON_USEDEP}] )
+	vo? (
+			dev-python/astropy[${PYTHON_USEDEP}]
+			dev-python/sampy[$(python_gen_usedep 'python2*')]
+		)"
+
+python_test() {
+	distutils_install_for_testing
+	cd tests || die
+	VIRTUALX_COMMAND="${EPYTHON}" \
+		VEUSZ_RESOURCE_DIR="${TEST_DIR}/lib/veusz" \
+		virtualmake runselftest.py
+}
+
+python_install() {
+	distutils-r1_python_install
+	# symlink the license, bug #341653
+	ln -s "${PORTDIR}"/licenses/${LICENSE} \
+		"${D}/$(python_get_sitedir)"/${PN}/COPYING || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use doc && dodoc Documents/manual.pdf && \
+		dohtml -r Documents/{manimages,manual.html}
+
+	doicon icons/veusz.png
+	domenu "${FILESDIR}"/veusz.desktop
+	insinto /usr/share/mime/packages
+	doins "${FILESDIR}"/veusz.xml
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}
-- 
cgit v1.2.3-65-gdbad