From 5f84164e15da8e24a356fd1b05a2979058196d00 Mon Sep 17 00:00:00 2001
From: Sebastien Fabbro <bicatali@gentoo.org>
Date: Sun, 7 Aug 2011 01:23:20 +0000
Subject: Version bump. Added static-libs flag

(Portage version: 2.1.10.10/cvs/Linux x86_64)
---
 sci-libs/mpir/ChangeLog         |  7 ++++-
 sci-libs/mpir/mpir-2.4.0.ebuild | 60 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+), 1 deletion(-)
 create mode 100644 sci-libs/mpir/mpir-2.4.0.ebuild

(limited to 'sci-libs/mpir')

diff --git a/sci-libs/mpir/ChangeLog b/sci-libs/mpir/ChangeLog
index 30e964178c02..931fea931571 100644
--- a/sci-libs/mpir/ChangeLog
+++ b/sci-libs/mpir/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-libs/mpir
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/mpir/ChangeLog,v 1.8 2011/06/29 19:00:09 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/mpir/ChangeLog,v 1.9 2011/08/07 01:23:20 bicatali Exp $
+
+*mpir-2.4.0 (07 Aug 2011)
+
+  07 Aug 2011; Sébastien Fabbro <bicatali@gentoo.org> +mpir-2.4.0.ebuild:
+  Version bump. Added static-libs flag
 
   29 Jun 2011; Brent Baude <ranger@gentoo.org> mpir-2.3.1.ebuild:
   Marking mpir-2.3.1 ~ppc for bug 345207
diff --git a/sci-libs/mpir/mpir-2.4.0.ebuild b/sci-libs/mpir/mpir-2.4.0.ebuild
new file mode 100644
index 000000000000..dfafe2fb349f
--- /dev/null
+++ b/sci-libs/mpir/mpir-2.4.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/mpir/mpir-2.4.0.ebuild,v 1.1 2011/08/07 01:23:20 bicatali Exp $
+
+EAPI=4
+
+inherit eutils autotools
+
+DESCRIPTION="Library for arbitrary precision integer arithmetic derived from version 4.2.1 of gmp"
+HOMEPAGE="http://www.mpir.org/"
+SRC_URI="http://www.mpir.org/${P}.tar.bz2"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="+cxx cpudetection static-libs"
+
+DEPEND="x86? ( dev-lang/yasm )
+	amd64? ( dev-lang/yasm )"
+RDEPEND=""
+
+src_prepare(){
+	epatch \
+		"${FILESDIR}/${PN}-2.2.0-yasm.patch" \
+		"${FILESDIR}/${PN}-1.3.0-ABI-multilib.patch"
+	# In the same way there was QA regarding executable stacks
+	# with GMP we have some here as well. We cannot apply the
+	# GMP solution as yasm is used, at least on x86/amd64.
+	# Furthermore we are able to patch config.ac.
+
+	ebegin "Patching assembler files to remove executable sections"
+	local i
+	for i in $(find . -type f -name '*.asm') ; do
+		cat >> $i <<-EOF
+			#if defined(__linux__) && defined(__ELF__)
+			.section .note.GNU-stack,"",%progbits
+			#endif
+		EOF
+	done
+
+	for i in $(find . -type f -name '*.as') ; do
+		cat >> $i <<-EOF
+			%ifidn __OUTPUT_FORMAT__,elf
+			section .note.GNU-stack noalloc noexec nowrite progbits
+			%endif
+		EOF
+	done
+	eend
+	eautoreconf
+}
+
+src_configure() {
+# beware that cpudetection aka fat binaries is x86/amd64 only.
+# Place mpir in profiles/arch/$arch/package.use.mask when making it available on $arch.
+	econf \
+		$(use_enable cxx) \
+		$(use_enable cpudetection fat) \
+		$(use_enable static-libs static)
+
+}
-- 
cgit v1.2.3-65-gdbad