From f6269e7150a2191e82af6e2307b8a76435088a06 Mon Sep 17 00:00:00 2001
From: Samuli Suominen <ssuominen@gentoo.org>
Date: Wed, 2 Sep 2009 10:57:50 +0000
Subject: Version bump. (Portage version: 2.2_rc40/cvs/Linux x86_64)

---
 media-sound/mpg123/ChangeLog           |  7 +++-
 media-sound/mpg123/mpg123-1.9.0.ebuild | 71 ++++++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+), 1 deletion(-)
 create mode 100644 media-sound/mpg123/mpg123-1.9.0.ebuild

(limited to 'media-sound')

diff --git a/media-sound/mpg123/ChangeLog b/media-sound/mpg123/ChangeLog
index 84ed851347e5..dd97ceaa9f74 100644
--- a/media-sound/mpg123/ChangeLog
+++ b/media-sound/mpg123/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mpg123
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.199 2009/08/31 19:25:37 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.200 2009/09/02 10:57:50 ssuominen Exp $
+
+*mpg123-1.9.0 (02 Sep 2009)
+
+  02 Sep 2009; Samuli Suominen <ssuominen@gentoo.org> +mpg123-1.9.0.ebuild:
+  Version bump.
 
   31 Aug 2009; Brent Baude <ranger@gentoo.org> mpg123-1.8.1.ebuild:
   stable ppc64, bug 278597
diff --git a/media-sound/mpg123/mpg123-1.9.0.ebuild b/media-sound/mpg123/mpg123-1.9.0.ebuild
new file mode 100644
index 000000000000..22e560450581
--- /dev/null
+++ b/media-sound/mpg123/mpg123-1.9.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/mpg123-1.9.0.ebuild,v 1.1 2009/09/02 10:57:50 ssuominen Exp $
+
+EAPI=2
+
+DESCRIPTION="a realtime MPEG 1.0/2.0/2.5 audio player for layers 1, 2 and 3"
+HOMEPAGE="http://www.mpg123.org"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+	http://www.mpg123.org/download/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="3dnow 3dnowext alsa altivec ipv6 jack mmx nas +network oss portaudio pulseaudio sdl sse"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	nas? ( media-libs/nas )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sdl? ( media-libs/libsdl )
+	!media-sound/mpg321[symlink]"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+src_configure() {
+	local _audio=dummy
+	local _output=dummy
+	local _cpu=generic_fpu
+	local _ipv6=disable
+
+	for flag in nas portaudio sdl oss jack alsa pulseaudio; do
+		if use ${flag}; then
+			_audio="${_audio} ${flag/pulseaudio/pulse}"
+			_output=${flag/pulseaudio/pulse}
+		fi
+	done
+
+	use altivec && _cpu=altivec
+
+	if use amd64 && use sse; then
+		_cpu=x86-64
+	fi
+
+	if use x86; then
+		_cpu=i586
+		use mmx && _cpu=mmx
+		use 3dnow && _cpu=3dnow
+		use sse && _cpu=x86
+		use 3dnowext && _cpu=x86
+	fi
+
+	if use network && use ipv6; then
+		_ipv6=enable
+	fi
+
+	econf \
+		--disable-dependency-tracking \
+		--with-optimization=0 \
+		--with-audio="${_audio}" \
+		--with-default-audio=${_output} \
+		--with-cpu=${_cpu} \
+		$(use_enable network) \
+		--${_ipv6}-ipv6
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS* README
+}
-- 
cgit v1.2.3-65-gdbad