From a084eb8fda1d0aed2229b5de22579fd7e63a6c3c Mon Sep 17 00:00:00 2001
From: Sebastien Fabbro <bicatali@gentoo.org>
Date: Fri, 4 Jul 2008 10:02:07 +0000
Subject: Version bump (Portage version: 2.1.4.4)

---
 media-libs/libafterimage/ChangeLog                 |  8 ++-
 media-libs/libafterimage/libafterimage-1.18.ebuild | 78 ++++++++++++++++++++++
 2 files changed, 85 insertions(+), 1 deletion(-)
 create mode 100644 media-libs/libafterimage/libafterimage-1.18.ebuild

(limited to 'media-libs/libafterimage')

diff --git a/media-libs/libafterimage/ChangeLog b/media-libs/libafterimage/ChangeLog
index a32a447ba132..3a8647f8316a 100644
--- a/media-libs/libafterimage/ChangeLog
+++ b/media-libs/libafterimage/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libafterimage
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libafterimage/ChangeLog,v 1.16 2008/04/08 09:20:34 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libafterimage/ChangeLog,v 1.17 2008/07/04 10:02:07 bicatali Exp $
+
+*libafterimage-1.18 (04 Jul 2008)
+
+  04 Jul 2008; Sébastien Fabbro <bicatali@gentoo.org>
+  +libafterimage-1.18.ebuild:
+  Version bump
 
   08 Apr 2008; Raúl Porcel <armin76@gentoo.org> libafterimage-1.15.ebuild:
   ia64/sparc stable wrt #215898
diff --git a/media-libs/libafterimage/libafterimage-1.18.ebuild b/media-libs/libafterimage/libafterimage-1.18.ebuild
new file mode 100644
index 000000000000..0df60124e27e
--- /dev/null
+++ b/media-libs/libafterimage/libafterimage-1.18.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libafterimage/libafterimage-1.18.ebuild,v 1.1 2008/07/04 10:02:07 bicatali Exp $
+
+inherit eutils
+
+MY_PN="libAfterImage"
+
+DESCRIPTION="Afterstep's standalone generic image manipulation library"
+HOMEPAGE="http://www.afterstep.org/afterimage/index.php"
+SRC_URI="ftp://ftp.afterstep.org/stable/${MY_PN}/${MY_PN}-${PV}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gif jpeg mmx nls png tiff examples"
+
+RDEPEND="media-libs/freetype
+	x11-libs/libSM
+	x11-libs/libXext
+	x11-libs/libXrender
+	png?  ( media-libs/libpng )
+	jpeg? ( media-libs/jpeg )
+	gif?  ( media-libs/giflib )
+	tiff? ( media-libs/tiff )"
+
+DEPEND="${RDEPEND}
+	!x11-wm/afterstep"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	# fix some ldconfig problem in makefile.in
+	epatch "${FILESDIR}"/${PN}-makefile.in.patch
+	# fix lib paths in afterimage-config
+	epatch "${FILESDIR}"/${PN}-config.patch
+	# remove forced flags
+	sed -i \
+		-e 's/CFLAGS="-O3"//' \
+		-e 's/ -rdynamic//' \
+		configure || die "sed failed"
+}
+
+src_compile() {
+	econf \
+		$(use_enable nls i18n) \
+		$(use_enable mmx mmx-optimization) \
+		$(use_with png) \
+		$(use_with jpeg) \
+		$(use_with gif) \
+		$(use_with tiff) \
+		--enable-glx \
+		--enable-sharedlibs \
+		--with-x \
+		--with-xpm \
+		--without-builtin-ungif \
+		--without-afterbase \
+		|| die "econf failed"
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		AFTER_DOC_DIR="${D}/usr/share/doc/${PF}" \
+		install || die "emake install failed"
+	dodoc ChangeLog README || die
+	if use examples; then
+		cd apps || die
+		emake clean
+		rm -f Makefile*
+		insinto /usr/share/doc/${PF}/examples
+		doins * || die "install examples failed"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad