From b8116f935861ff3e160bf4136e57bf812e37b6c1 Mon Sep 17 00:00:00 2001
From: Tim Harder <radhermit@gentoo.org>
Date: Thu, 29 Jan 2015 06:43:19 +0000
Subject: Version bump.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)
---
 media-libs/glew/ChangeLog          |  9 ++++-
 media-libs/glew/glew-1.12.0.ebuild | 79 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+), 2 deletions(-)
 create mode 100644 media-libs/glew/glew-1.12.0.ebuild

(limited to 'media-libs/glew')

diff --git a/media-libs/glew/ChangeLog b/media-libs/glew/ChangeLog
index b64244afef9f..6673491a5690 100644
--- a/media-libs/glew/ChangeLog
+++ b/media-libs/glew/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/glew
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v 1.106 2014/09/26 23:39:58 radhermit Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v 1.107 2015/01/29 06:43:19 radhermit Exp $
+
+*glew-1.12.0 (29 Jan 2015)
+
+  29 Jan 2015; Tim Harder <radhermit@gentoo.org> +glew-1.12.0.ebuild:
+  Version bump.
 
 *glew-1.11.0 (26 Sep 2014)
 
diff --git a/media-libs/glew/glew-1.12.0.ebuild b/media-libs/glew/glew-1.12.0.ebuild
new file mode 100644
index 000000000000..f24b132893a7
--- /dev/null
+++ b/media-libs/glew/glew-1.12.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/glew-1.12.0.ebuild,v 1.1 2015/01/29 06:43:19 radhermit Exp $
+
+EAPI=5
+inherit multilib multilib-minimal toolchain-funcs versionator
+
+DESCRIPTION="The OpenGL Extension Wrangler Library"
+HOMEPAGE="http://glew.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tgz"
+
+LICENSE="BSD MIT"
+SLOT="0/$(get_version_component_range 1-2)"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc static-libs"
+
+RDEPEND=">=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
+	>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+	>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+	>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+	>=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
+	>=x11-libs/libXmu-1.1.1-r1[${MULTILIB_USEDEP}]
+	abi_x86_32? ( !app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)] )"
+DEPEND=${RDEPEND}
+
+src_prepare() {
+	sed -i \
+		-e '/INSTALL/s:-s::' \
+		-e '/$(CC) $(CFLAGS) -o/s:$(CFLAGS):$(CFLAGS) $(LDFLAGS):' \
+		-e '/^.PHONY: .*\.pc$/d' \
+		Makefile || die
+
+	if ! use static-libs ; then
+		sed -i \
+			-e '/glew.lib:/s|lib/$(LIB.STATIC) ||' \
+			-e '/glew.lib.mx:/s|lib/$(LIB.STATIC.MX) ||' \
+			-e '/INSTALL.*LIB.STATIC/d' \
+			Makefile || die
+	fi
+
+	# don't do stupid Solaris specific stuff that won't work in Prefix
+	cp config/Makefile.linux config/Makefile.solaris || die
+	# and let freebsd be built as on linux too
+	cp config/Makefile.linux config/Makefile.freebsd || die
+
+	multilib_copy_sources
+}
+
+set_opts() {
+	myglewopts=(
+		AR="$(tc-getAR)"
+		STRIP=true
+		CC="$(tc-getCC)"
+		LD="$(tc-getCC) ${LDFLAGS}"
+		M_ARCH=""
+		LDFLAGS.EXTRA=""
+		POPT="${CFLAGS}"
+	)
+
+	# support MinGW targets (bug #523444)
+	[[ ${CHOST} == *-mingw* ]] && myglewopts+=( SYSTEM=mingw )
+}
+
+multilib_src_compile() {
+	set_opts
+	emake GLEW_DEST="${EPREFIX}/usr" LIBDIR="${EPREFIX}/usr/$(get_libdir)" "${myglewopts[@]}"
+}
+
+multilib_src_install() {
+	set_opts
+	emake \
+		GLEW_DEST="${ED}/usr" \
+		LIBDIR="${ED}/usr/$(get_libdir)" \
+		"${myglewopts[@]}" \
+		install.all
+
+	dodoc TODO.txt
+	use doc && dohtml doc/*
+}
-- 
cgit v1.2.3-65-gdbad