From 00ecf712f40132cdd18a0390b3c2befb0a2e7833 Mon Sep 17 00:00:00 2001
From: Christian Ruppert <idl0r@gentoo.org>
Date: Mon, 4 Jun 2012 16:38:22 +0000
Subject: Version bump. Fix dependencies.

(Portage version: 2.2.0_alpha109/cvs/Linux x86_64)
---
 dev-libs/tntnet/ChangeLog            |  8 +++-
 dev-libs/tntnet/tntnet-1.6.3.ebuild  |  4 +-
 dev-libs/tntnet/tntnet-2.0-r1.ebuild |  4 +-
 dev-libs/tntnet/tntnet-2.1.ebuild    | 90 ++++++++++++++++++++++++++++++++++++
 4 files changed, 101 insertions(+), 5 deletions(-)
 create mode 100644 dev-libs/tntnet/tntnet-2.1.ebuild

(limited to 'dev-libs/tntnet')

diff --git a/dev-libs/tntnet/ChangeLog b/dev-libs/tntnet/ChangeLog
index 6b16b9983a59..3d8b06009731 100644
--- a/dev-libs/tntnet/ChangeLog
+++ b/dev-libs/tntnet/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/tntnet
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/ChangeLog,v 1.19 2012/05/04 18:35:48 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/ChangeLog,v 1.20 2012/06/04 16:38:22 idl0r Exp $
+
+*tntnet-2.1 (04 Jun 2012)
+
+  04 Jun 2012; Christian Ruppert <idl0r@gentoo.org> tntnet-1.6.3.ebuild,
+  tntnet-2.0-r1.ebuild, +tntnet-2.1.ebuild:
+  Version bump. Fix dependencies.
 
   04 May 2012; Jeff Horelick <jdhore@gentoo.org> tntnet-1.6.3.ebuild,
   tntnet-2.0-r1.ebuild:
diff --git a/dev-libs/tntnet/tntnet-1.6.3.ebuild b/dev-libs/tntnet/tntnet-1.6.3.ebuild
index a88ee82b5417..877f20bc4d22 100644
--- a/dev-libs/tntnet/tntnet-1.6.3.ebuild
+++ b/dev-libs/tntnet/tntnet-1.6.3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/tntnet-1.6.3.ebuild,v 1.7 2012/05/04 18:35:48 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/tntnet-1.6.3.ebuild,v 1.8 2012/06/04 16:38:22 idl0r Exp $
 
 EAPI="2"
 
@@ -15,7 +15,7 @@ SLOT="0"
 KEYWORDS="amd64 ~sparc x86"
 IUSE="ssl gnutls examples"
 
-RDEPEND="dev-libs/cxxtools
+RDEPEND="=dev-libs/cxxtools-1*
 	sys-libs/zlib
 	ssl? (
 		gnutls? ( >=net-libs/gnutls-1.2.0 )
diff --git a/dev-libs/tntnet/tntnet-2.0-r1.ebuild b/dev-libs/tntnet/tntnet-2.0-r1.ebuild
index 7915dc446ba7..50302e01d654 100644
--- a/dev-libs/tntnet/tntnet-2.0-r1.ebuild
+++ b/dev-libs/tntnet/tntnet-2.0-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/tntnet-2.0-r1.ebuild,v 1.3 2012/05/04 18:35:48 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/tntnet-2.0-r1.ebuild,v 1.4 2012/06/04 16:38:22 idl0r Exp $
 
 EAPI="3"
 
@@ -15,7 +15,7 @@ SLOT="0"
 KEYWORDS="~amd64 ~sparc ~x86"
 IUSE="cgi doc examples gnutls server sdk ssl"
 
-RDEPEND=">=dev-libs/cxxtools-2.0
+RDEPEND="=dev-libs/cxxtools-2.0*
 	sys-libs/zlib[minizip]
 	ssl? (
 		gnutls? (
diff --git a/dev-libs/tntnet/tntnet-2.1.ebuild b/dev-libs/tntnet/tntnet-2.1.ebuild
new file mode 100644
index 000000000000..42509e55385e
--- /dev/null
+++ b/dev-libs/tntnet/tntnet-2.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/tntnet-2.1.ebuild,v 1.1 2012/06/04 16:38:22 idl0r Exp $
+
+EAPI="4"
+
+inherit autotools eutils
+
+DESCRIPTION="Modular, multithreaded webapplicationserver extensible with C++"
+HOMEPAGE="http://www.tntnet.org/index.hms"
+SRC_URI="http://www.tntnet.org/download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE="cgi doc examples gnutls server sdk ssl"
+
+RDEPEND="=dev-libs/cxxtools-2.1*
+	sys-libs/zlib[minizip]
+	ssl? (
+		gnutls? (
+			>=net-libs/gnutls-1.2.0
+			dev-libs/libgcrypt
+		)
+		!gnutls? ( dev-libs/openssl )
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	examples? ( app-arch/zip )"
+
+src_prepare() {
+	# Both fixed in the next release
+	epatch "${FILESDIR}"/${PN}-2.0-zlib-minizip.patch
+	rm framework/common/{ioapi,unzip}.[ch] || die
+
+	eautoreconf
+
+	sed -i -e 's:@localstatedir@:/var:' etc/tntnet/tntnet.conf.in || die
+}
+
+src_configure() {
+	local myconf=""
+
+	# Prefer gnutls above SSL
+	if use gnutls; then
+		einfo "Using gnutls for ssl support."
+		myconf="${myconf} --with-ssl=gnutls"
+	elif use ssl; then
+		einfo "Using openssl for ssl support."
+		myconf="${myconf} --with-ssl=openssl"
+	else
+		myconf="${myconf} --with-ssl=no"
+	fi
+
+	# demos/examples depend upon sdk
+	if use examples && ! use sdk; then
+		myconf="${myconf} --with-sdk"
+	fi
+
+	econf \
+		$(use_with examples demos) \
+		$(use_with sdk) \
+		$(use_with cgi) \
+		$(use_with server) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog README TODO
+	if use doc; then
+		dodoc doc/*.pdf || die
+	fi
+
+	if use examples; then
+		cd "${S}/sdk/demos"
+		emake clean
+		rm -rf .deps */.deps .libs */.libs
+		cd "${S}"
+
+		insinto /usr/share/doc/${PF}/examples
+		doins -r sdk/demos/* || die
+	fi
+
+	if use server; then
+		rm -f "${D}/etc/init.d/tntnet"
+		newinitd "${FILESDIR}/tntnet.initd" tntnet
+	fi
+}
-- 
cgit v1.2.3-65-gdbad