From 56c543af60334842029c2d1b29697aa51193aba0 Mon Sep 17 00:00:00 2001
From: Mike Frysinger <vapier@gentoo.org>
Date: Sun, 6 May 2012 18:16:34 +0000
Subject: Version bump.

(Portage version: 2.2.0_alpha100/cvs/Linux x86_64)
---
 dev-libs/gmp/ChangeLog        |   7 ++-
 dev-libs/gmp/gmp-5.0.5.ebuild | 101 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 107 insertions(+), 1 deletion(-)
 create mode 100644 dev-libs/gmp/gmp-5.0.5.ebuild

(limited to 'dev-libs/gmp')

diff --git a/dev-libs/gmp/ChangeLog b/dev-libs/gmp/ChangeLog
index c7411529b2bb..b6137d195e70 100644
--- a/dev-libs/gmp/ChangeLog
+++ b/dev-libs/gmp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/gmp
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmp/ChangeLog,v 1.167 2012/04/26 12:27:18 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmp/ChangeLog,v 1.168 2012/05/06 18:16:34 vapier Exp $
+
+*gmp-5.0.5 (06 May 2012)
+
+  06 May 2012; Mike Frysinger <vapier@gentoo.org> +gmp-5.0.5.ebuild:
+  Version bump.
 
   26 Apr 2012; Alexis Ballier <aballier@gentoo.org> gmp-5.0.4.ebuild:
   keyword ~amd64-fbsd
diff --git a/dev-libs/gmp/gmp-5.0.5.ebuild b/dev-libs/gmp/gmp-5.0.5.ebuild
new file mode 100644
index 000000000000..12f8f9d632fa
--- /dev/null
+++ b/dev-libs/gmp/gmp-5.0.5.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmp/gmp-5.0.5.ebuild,v 1.1 2012/05/06 18:16:34 vapier Exp $
+
+inherit flag-o-matic eutils libtool unpacker toolchain-funcs
+
+MY_PV=${PV/_p*}
+MY_P=${PN}-${MY_PV}
+PLEVEL=${PV/*p}
+DESCRIPTION="Library for arithmetic on arbitrary precision integers, rational numbers, and floating-point numbers"
+HOMEPAGE="http://gmplib.org/"
+SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.xz
+	doc? ( http://gmplib.org/${PN}-man-${MY_PV}.pdf )"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="doc cxx static-libs"
+
+DEPEND="sys-devel/m4
+	app-arch/xz-utils"
+RDEPEND=""
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+	unpacker_src_unpack
+	cd "${S}"
+	[[ -d ${FILESDIR}/${PV} ]] && EPATCH_SUFFIX="diff" EPATCH_FORCE="yes" epatch "${FILESDIR}"/${PV}
+	epatch "${FILESDIR}"/${PN}-4.1.4-noexecstack.patch
+	epatch "${FILESDIR}"/${PN}-5.0.2-x32-support.patch
+
+	# disable -fPIE -pie in the tests for x86  #236054
+	if use x86 && gcc-specs-pie ; then
+		epatch "${FILESDIR}"/${PN}-5.0.1-x86-nopie-tests.patch
+	fi
+
+	# note: we cannot run autotools here as gcc depends on this package
+	elibtoolize
+
+	# GMP uses the "ABI" env var during configure as does Gentoo (econf).
+	# So, to avoid patching the source constantly, wrap things up.
+	mv configure configure.wrapped || die
+	cat <<-\EOF > configure
+	#!/bin/sh
+	exec env ABI="$GMPABI" "${0}.wrapped" "$@"
+	EOF
+	chmod a+rx configure
+}
+
+src_compile() {
+	# Because of our 32-bit userland, 1.0 is the only HPPA ABI that works
+	# http://gmplib.org/manual/ABI-and-ISA.html#ABI-and-ISA (bug #344613)
+	if [[ ${CHOST} == hppa2.0-* ]] ; then
+		export GMPABI="1.0"
+	fi
+
+	# ABI mappings (needs all architectures supported)
+	case ${ABI} in
+		32|x86)       GMPABI=32;;
+		64|amd64|n64) GMPABI=64;;
+		[onx]32)      GMPABI=${ABI};;
+	esac
+	export GMPABI
+
+	tc-export CC
+	econf \
+		--localstatedir=/var/state/gmp \
+		--disable-mpbsd \
+		$(use_enable cxx) \
+		$(use_enable static-libs static) \
+		|| die
+
+	emake || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	# should be a standalone lib
+	rm -f "${D}"/usr/$(get_libdir)/libgmp.la
+	# this requires libgmp
+	local la="${D}/usr/$(get_libdir)/libgmpxx.la"
+	use static-libs \
+		&& sed -i 's:/[^ ]*/libgmp.la:-lgmp:' "${la}" \
+		|| rm -f "${la}"
+
+	dodoc AUTHORS ChangeLog NEWS README
+	dodoc doc/configuration doc/isa_abi_headache
+	dohtml -r doc
+
+	use doc && cp "${DISTDIR}"/gmp-man-${MY_PV}.pdf "${D}"/usr/share/doc/${PF}/
+}
+
+pkg_preinst() {
+	preserve_old_lib /usr/$(get_libdir)/libgmp.so.3
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /usr/$(get_libdir)/libgmp.so.3
+}
-- 
cgit v1.2.3-65-gdbad