From 0a23d3986f75ce712a833cc2b7dc41c17f6f686d Mon Sep 17 00:00:00 2001
From: Piotr Jaroszyński <peper@gentoo.org>
Date: Mon, 26 Nov 2007 20:10:01 +0000
Subject: Add live svn ebuild. (Portage version: 2.1.4_rc3)

---
 app-pda/libsyncml/ChangeLog                   |  7 ++-
 app-pda/libsyncml/files/digest-libsyncml-9999 |  0
 app-pda/libsyncml/libsyncml-9999.ebuild       | 78 +++++++++++++++++++++++++++
 3 files changed, 84 insertions(+), 1 deletion(-)
 create mode 100644 app-pda/libsyncml/files/digest-libsyncml-9999
 create mode 100644 app-pda/libsyncml/libsyncml-9999.ebuild

(limited to 'app-pda/libsyncml')

diff --git a/app-pda/libsyncml/ChangeLog b/app-pda/libsyncml/ChangeLog
index d63b81ba0b99..617f43bb15fd 100644
--- a/app-pda/libsyncml/ChangeLog
+++ b/app-pda/libsyncml/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-pda/libsyncml
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-pda/libsyncml/ChangeLog,v 1.5 2007/03/28 20:13:43 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-pda/libsyncml/ChangeLog,v 1.6 2007/11/26 20:10:00 peper Exp $
+
+*libsyncml-9999 (26 Nov 2007)
+
+  26 Nov 2007; Piotr Jaroszyński <peper@gentoo.org> +libsyncml-9999.ebuild:
+  Add live svn ebuild.
 
 *libsyncml-0.4.4 (28 Mar 2007)
 
diff --git a/app-pda/libsyncml/files/digest-libsyncml-9999 b/app-pda/libsyncml/files/digest-libsyncml-9999
new file mode 100644
index 000000000000..e69de29bb2d1
diff --git a/app-pda/libsyncml/libsyncml-9999.ebuild b/app-pda/libsyncml/libsyncml-9999.ebuild
new file mode 100644
index 000000000000..fba7b6521219
--- /dev/null
+++ b/app-pda/libsyncml/libsyncml-9999.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-pda/libsyncml/libsyncml-9999.ebuild,v 1.1 2007/11/26 20:10:00 peper Exp $
+
+inherit eutils subversion autotools
+
+DESCRIPTION="Implementation of the SyncML protocol"
+HOMEPAGE="http://libsyncml.opensync.org/"
+SRC_URI=""
+
+ESVN_REPO_URI="http://svn.opensync.org/libsyncml/trunk"
+
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+LICENSE="LGPL-2.1"
+IUSE="bluetooth debug doc http obex"
+
+RDEPEND=">=dev-libs/glib-2.0
+	>=dev-libs/libwbxml-0.9.2
+	dev-libs/libxml2
+	http? ( >=net-libs/libsoup-2.2.91 )
+	obex? ( >=dev-libs/openobex-1.1 )
+	bluetooth? ( net-wireless/bluez-libs )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+# Some of the tests are broken
+RESTRICT="test"
+
+pkg_setup() {
+	if ! use obex && ! use http; then
+		eerror "${CATEGORY}/${P} without support for obex nor http is unusable."
+		eerror "Please enable \"obex\" or/and \"http\" USE flags."
+		die "Please enable \"obex\" or/and \"http\" USE flags."
+	fi
+
+	if use bluetooth; then
+		if use obex && ! built_with_use dev-libs/openobex bluetooth; then
+			eerror "You are trying to build ${CATEGORY}/${P} with the \"bluetooth\""
+			eerror "and \"obex\" USE flags, but dev-libs/openobex was built without"
+			eerror "the \"bluetooth\" USE flag."
+			eerror "Please rebuild dev-libs/openobex with \"bluetooth\" USE flag."
+			die "Please rebuild dev-libs/openobex with \"bluetooth\" USE flag."
+		elif ! use obex; then
+			eerror "You are trying to build ${CATEGORY}/${P} with the \"bluetooth\""
+			eerror "USE flag, but you didn't enable the \"obex\" flag, which is"
+			eerror "needed for bluetooth support."
+			eerror "Please enable \"obex\" USE flag."
+			die "Please enable \"obex\" USE flag."
+		fi
+	fi
+}
+
+src_compile() {
+	eautoreconf
+
+	econf \
+		$(use_enable bluetooth) \
+		$(use_enable obex) \
+		$(use_enable http) \
+		$(use_enable debug) \
+		$(use_enable debug tracing) \
+		--disable-unit-tests \
+		|| die "econf failed"
+		#$(use_enable test unit-tests) \
+
+	emake || die "emake failed"
+
+	use doc && doxygen Doxyfile
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog README
+
+	use doc && dohtml docs/html/*
+}
-- 
cgit v1.2.3-65-gdbad