1 files changed, 57 insertions, 0 deletions
diff --git a/sci-chemistry/gabedit/gabedit-2.3.2.ebuild b/sci-chemistry/gabedit/gabedit-2.3.2.ebuild
new file mode 100644
index 000000000000..364f5e296c02
--- /dev/null
+++ b/sci-chemistry/gabedit/gabedit-2.3.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/gabedit/gabedit-2.3.2.ebuild,v 1.1 2010/11/11 11:38:02 jlec Exp $
+
+EAPI=2
+
+inherit toolchain-funcs versionator
+
+MY_PN=${PN/g/G}
+MY_PV=$(delete_all_version_separators)
+MY_P="${MY_PN}Src${MY_PV}"
+
+DESCRIPTION="GUI for computational chemistry packages"
+HOMEPAGE="http://gabedit.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/GabeditDevloppment/${MY_PN}${MY_PV}/${MY_P}.tar.gz"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="openmp"
+
+RDEPEND=">=x11-libs/gtk+-2.4
+	x11-libs/gtkglext
+	x11-libs/gl2ps
+	virtual/opengl
+	virtual/glu"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	tc-export CC
+}
+
+src_prepare() {
+	sed -e "/GTK_DISABLE_DEPRECATED/s:define:undef:g" \
+		-i "${S}/Config.h" || die
+	cp "${FILESDIR}"/CONFIG.Gentoo "${S}"/CONFIG
+
+	if use openmp && tc-has-openmp; then
+		cat <<- EOF >> "${S}/CONFIG"
+			OMPLIB=-L/usr/$(get_libdir) -lgomp
+			OMPCFLAGS=-DENABLE_OMP -fopenmp
+		EOF
+	fi
+	echo "COMMONCFLAGS = ${CFLAGS} -DENABLE_DEPRECATED \$(OMPCFLAGS) \$(DRAWGEOMGL)" >> CONFIG
+}
+
+src_compile() {
+	emake external_gl2ps=1 || die
+}
+
+src_install() {
+	dobin ${PN} || die
+	dodoc ChangeLog || die
+}