1 files changed, 54 insertions, 0 deletions
diff --git a/kde-base/poxml/poxml-4.11.3.ebuild b/kde-base/poxml/poxml-4.11.3.ebuild
new file mode 100644
index 000000000000..89e7935603a7
--- /dev/null
+++ b/kde-base/poxml/poxml-4.11.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/poxml/poxml-4.11.3.ebuild,v 1.1 2013/11/05 22:23:06 dilfridge Exp $
+
+EAPI=5
+
+JAVA_PKG_OPT_USE=extras
+inherit java-pkg-opt-2 java-ant-2 kde4-base
+
+DESCRIPTION="KDE utility to translate DocBook XML files using gettext po files"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="debug extras"
+
+DEPEND="
+	extras? (
+		>=virtual/jdk-1.5
+		>=dev-java/antlr-2.7.7:0[cxx,java,script]
+	)
+"
+RDEPEND="
+	extras? (
+		>=virtual/jre-1.5
+		>=dev-java/antlr-2.7.7:0[cxx,java,script]
+	)
+	!<=kde-base/kdesdk-misc-4.10.50:4
+"
+
+# java deps on anltr cant be properly explained to cmake deps
+# needs to be run in one thread
+MAKEOPTS+=" -j1"
+
+pkg_setup() {
+	kde4-base_pkg_setup
+	java-pkg-opt-2_pkg_setup
+}
+
+src_prepare() {
+	kde4-base_src_prepare
+	java-pkg-opt-2_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with extras Antlr2)
+	)
+
+	kde4-base_src_configure
+	java-ant-2_src_configure
+}
+
+pkg_preinst() {
+	kde4-base_pkg_preinst
+	java-pkg-2_pkg_preinst
+}