Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status
summaryrefslogtreecommitdiff
path: root/dev-util
diff options
context:
space:
mode:
Diffstat (limited to 'dev-util')
-rw-r--r--dev-util/glade/ChangeLog9
-rw-r--r--dev-util/glade/glade-3.10.2.ebuild70
-rw-r--r--dev-util/glade/glade-3.6.7.ebuild56
-rw-r--r--dev-util/glade/glade-3.8.1.ebuild55
4 files changed, 133 insertions, 57 deletions
diff --git a/dev-util/glade/ChangeLog b/dev-util/glade/ChangeLog
index 71387a534e50..daff836bcad3 100644
--- a/dev-util/glade/ChangeLog
+++ b/dev-util/glade/ChangeLog
@@ -1,6 +1,13 @@
# ChangeLog for dev-util/glade
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/ChangeLog,v 1.139 2011/10/14 19:06:24 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/ChangeLog,v 1.140 2011/10/16 00:12:26 pacho Exp $
+
+*glade-3.10.2 (16 Oct 2011)
+*glade-3.8.1 (16 Oct 2011)
+
+ 16 Oct 2011; Pacho Ramos <pacho@gentoo.org> -glade-3.6.7.ebuild,
+ +glade-3.8.1.ebuild, +glade-3.10.2.ebuild:
+ Version bump, remove old.
14 Oct 2011; Samuli Suominen <ssuominen@gentoo.org> glade-3.10.0-r1.ebuild:
amd64 stable wrt #385699
diff --git a/dev-util/glade/glade-3.10.2.ebuild b/dev-util/glade/glade-3.10.2.ebuild
new file mode 100644
index 000000000000..9022831354b6
--- /dev/null
+++ b/dev-util/glade/glade-3.10.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/glade-3.10.2.ebuild,v 1.1 2011/10/16 00:12:26 pacho Exp $
+
+EAPI="4"
+GNOME2_LA_PUNT="yes"
+GCONF_DEBUG="yes"
+
+inherit gnome2 versionator
+
+DESCRIPTION="GNOME GUI Builder"
+HOMEPAGE="http://glade.gnome.org/"
+
+LICENSE="GPL-2"
+SLOT="3.10"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc +introspection python"
+
+RDEPEND=">=x11-libs/gtk+-3.0.2:3
+ >=dev-libs/libxml2-2.4.0:2
+ introspection? ( >=dev-libs/gobject-introspection-0.10.1 )
+ python? ( >=dev-python/pygobject-2.27.0 )
+"
+DEPEND="${RDEPEND}
+ app-text/scrollkeeper
+ >=dev-util/intltool-0.41.0
+ >=dev-util/pkgconfig-0.19
+ >=sys-devel/gettext-0.17
+ >=app-text/gnome-doc-utils-0.18
+ app-text/docbook-xml-dtd:4.1.2
+ doc? ( >=dev-util/gtk-doc-1.13 )
+"
+
+pkg_setup() {
+ DOCS="AUTHORS ChangeLog NEWS README TODO"
+ G2CONF="${G2CONF}
+ --disable-maintainer-mode
+ --disable-static
+ --enable-libtool-lock
+ --disable-scrollkeeper
+ $(use_enable introspection)
+ $(use_enable python)"
+}
+
+src_prepare() {
+ # to avoid file collision with glade:3, rename GNOME help module from
+ # glade to glade-3.10, and gladeui documentation from gladeui to gladeui-2
+ local i
+ sed -e 's:DOC_MODULE = glade:DOC_MODULE = glade-3.10:' -i help/Makefile.in \
+ || die "sed of help/Makefile.in failed"
+ sed -e 's:/glade.xml:/glade-3.10.xml:g' -i help/*/*.po \
+ || die "sed of help .po files failed"
+ for i in help/*/glade.xml ; do
+ mv ${i} ${i/glade/glade-3.10} || die "mv ${i} failed"
+ done
+ sed -e 's:DOC_MODULE = gladeui:DOC_MODULE = gladeui-2:' -i doc/Makefile.in \
+ || die "sed of doc/Makefile.in failed"
+ for i in doc/gladeui-* doc/gladeui.* ; do
+ mv ${i} ${i/gladeui/gladeui-2} || die "mv ${i} failed"
+ done
+
+ gnome2_src_prepare
+}
+
+src_install() {
+ # modify Name in .desktop file to avoid confusion with other slots
+ sed -e 's:^\(Name.*=Glade\):\1 '$(get_version_component_range 1-2): \
+ -i data/glade.desktop || die "sed of data/glade.desktop failed"
+ gnome2_src_install
+}
diff --git a/dev-util/glade/glade-3.6.7.ebuild b/dev-util/glade/glade-3.6.7.ebuild
deleted file mode 100644
index 52aee8ca5f59..000000000000
--- a/dev-util/glade/glade-3.6.7.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/glade-3.6.7.ebuild,v 1.11 2011/03/16 10:23:49 nirbheek Exp $
-
-EAPI="2"
-
-inherit gnome2
-
-MY_PN="glade3"
-MY_P="${MY_PN}-${PV}"
-
-DESCRIPTION="GNOME GUI Builder"
-HOMEPAGE="http://glade.gnome.org/"
-SRC_URI="mirror://gnome/sources/${MY_PN}/${PVP[0]}.${PVP[1]}/${MY_P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="3"
-KEYWORDS="alpha amd64 arm ia64 ppc ppc64 sh sparc x86 ~x86-fbsd"
-IUSE="doc gnome python"
-
-RDEPEND=">=dev-libs/glib-2.8.0:2
- >=x11-libs/gtk+-2.14.0:2
- >=dev-libs/libxml2-2.4:2
- gnome? (
- >=gnome-base/libgnomeui-2.0
- >=gnome-base/libbonoboui-2.0 )
- python? ( >=dev-python/pygtk-2.10.0:2 )
-"
-DEPEND="${RDEPEND}
- >=dev-util/intltool-0.35
- >=dev-util/pkgconfig-0.19
- sys-devel/gettext
- app-text/scrollkeeper
- >=app-text/gnome-doc-utils-0.9
- app-text/docbook-xml-dtd:4.1.2
- doc? ( >=dev-util/gtk-doc-1.9 )
-"
-
-S="${WORKDIR}/${MY_P}"
-DOCS="AUTHORS ChangeLog NEWS README TODO"
-
-pkg_setup() {
- G2CONF="${G2CONF}
- --enable-libtool-lock
- --disable-scrollkeeper
- $(use_enable gnome)
- $(use_enable python)"
-}
-
-src_prepare() {
- gnome2_src_prepare
-
- # Fix intltoolize broken file, see upstream #577133
- sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
- || die "sed 1 failed"
-}
diff --git a/dev-util/glade/glade-3.8.1.ebuild b/dev-util/glade/glade-3.8.1.ebuild
new file mode 100644
index 000000000000..34320b94943d
--- /dev/null
+++ b/dev-util/glade/glade-3.8.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/glade-3.8.1.ebuild,v 1.1 2011/10/16 00:12:26 pacho Exp $
+
+EAPI="4"
+GCONF_DEBUG="yes"
+GNOME_ORG_MODULE="glade3"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2
+
+DESCRIPTION="GNOME GUI Builder"
+HOMEPAGE="http://glade.gnome.org/"
+
+LICENSE="GPL-2"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc gnome python"
+
+RDEPEND=">=dev-libs/glib-2.8:2
+ >=x11-libs/gtk+-2.24:2
+ >=dev-libs/libxml2-2.4:2
+ gnome? (
+ >=gnome-base/libgnomeui-2
+ >=gnome-base/libbonoboui-2 )
+ python? ( >=dev-python/pygtk-2.10:2 )
+"
+DEPEND="${RDEPEND}
+ >=dev-util/intltool-0.35
+ >=dev-util/pkgconfig-0.19
+ sys-devel/gettext
+ app-text/scrollkeeper
+ >=app-text/gnome-doc-utils-0.9
+ app-text/docbook-xml-dtd:4.1.2
+ doc? ( >=dev-util/gtk-doc-1.9 )
+"
+
+pkg_setup() {
+ DOCS="AUTHORS ChangeLog NEWS README TODO"
+ G2CONF="${G2CONF}
+ --enable-libtool-lock
+ --disable-scrollkeeper
+ $(use_enable gnome)
+ $(use_enable python)"
+}
+
+pkg_preinst() {
+ gnome2_pkg_preinst
+ preserve_old_lib /usr/$(get_libdir)/libgladeui-1.so.9
+}
+
+pkg_postinst() {
+ gnome2_pkg_postinst
+ preserve_old_lib_notify /usr/$(get_libdir)/libgladeui-1.so.9
+}