2 files changed, 74 insertions, 1 deletions
diff --git a/dev-util/debhelper/ChangeLog b/dev-util/debhelper/ChangeLog
index a4179bd35275..5b2fc28f6955 100644
--- a/dev-util/debhelper/ChangeLog
+++ b/dev-util/debhelper/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/debhelper
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/ChangeLog,v 1.59 2012/08/31 16:28:31 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/ChangeLog,v 1.60 2012/09/11 14:13:51 jer Exp $
+
+*debhelper-9.20120909 (11 Sep 2012)
+
+  11 Sep 2012; Jeroen Roovers <jer@gentoo.org> +debhelper-9.20120909.ebuild:
+  Version bump.
 
 *debhelper-9.20120830 (31 Aug 2012)
 
diff --git a/dev-util/debhelper/debhelper-9.20120909.ebuild b/dev-util/debhelper/debhelper-9.20120909.ebuild
new file mode 100644
index 000000000000..28e7d2a51629
--- /dev/null
+++ b/dev-util/debhelper/debhelper-9.20120909.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/debhelper-9.20120909.ebuild,v 1.1 2012/09/11 14:13:51 jer Exp $
+
+EAPI=4
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Collection of programs that can be used to automate common tasks in debian/rules"
+HOMEPAGE="http://packages.qa.debian.org/d/debhelper.html http://joeyh.name/code/debhelper/"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${P/-/_}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~s390 ~sh ~sparc ~x86"
+IUSE="nls linguas_de linguas_es linguas_fr test"
+
+RDEPEND="app-arch/dpkg
+	dev-perl/TimeDate
+	virtual/perl-Getopt-Long
+	>=dev-lang/perl-5.10"
+
+DEPEND="${RDEPEND}
+	nls? ( >=app-text/po4a-0.24 )
+	test? ( dev-perl/Test-Pod )"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-7.4.13-conditional-nls.patch
+}
+
+src_compile() {
+	tc-export CC
+	local USE_NLS=no LANGS=""
+
+	use nls && USE_NLS=yes
+
+	use linguas_de && LANGS="${LANGS} de"
+	use linguas_es && LANGS="${LANGS} es"
+	use linguas_fr && LANGS="${LANGS} fr"
+
+	emake USE_NLS=${USE_NLS} LANGS="${LANGS}" build
+}
+
+src_install() {
+	default
+	dodoc doc/* debian/changelog
+	docinto examples
+	dodoc examples/*
+	for manfile in *.1 *.7 ; do
+		case ${manfile} in
+			*.de.?)	use linguas_de \
+					&& cp ${manfile} "${T}"/${manfile/.de/} \
+					&& doman -i18n=de "${T}"/${manfile/.de/}
+				;;
+			*.es.?)	use linguas_es \
+					&& cp ${manfile} "${T}"/${manfile/.es/} \
+					&& doman -i18n=es "${T}"/${manfile/.es/}
+				;;
+			*.fr.?)	use linguas_fr \
+					&& cp ${manfile} "${T}"/${manfile/.fr/} \
+					&& doman -i18n=fr "${T}"/${manfile/.fr/}
+				;;
+			*)	doman ${manfile}
+				;;
+		esac
+	done
+}