Ânew versionÃ:enca,xvmc,amrÂ

(Portage version: 2.1_rc2-r3)

3 files changed, 656 insertions, 1 deletions

diff --git a/media-video/mplayer/ChangeLog b/media-video/mplayer/ChangeLog
index 7da83c46a715..9f94440a2160 100644
--- a/media-video/mplayer/ChangeLog
+++ b/media-video/mplayer/ChangeLog
@@ -1,6 +1,6 @@
 # ChangeLog for media-video/mplayer
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mplayer/ChangeLog,v 1.396 2006/07/09 21:03:24 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mplayer/ChangeLog,v 1.397 2006/07/11 10:07:03 lu_zero Exp $
 
   09 Jul 2006; Diego Pettenò <flameeyes@gentoo.org>
   mplayer-1.0_pre7-r1.ebuild, mplayer-1.0_pre8.ebuild,
@@ -9,6 +9,12 @@
   mplayer-1.0.20060415.ebuild:
   Pinpoint virtual/x11 version to less than 7.
 
+*mplayer-1.0_pre8-r1 (11 Jul 2006)
+
+  11 Jul 2006; Luca Barbato <lu_zero@gentoo.org>
+  +mplayer-1.0_pre8-r1.ebuild:
+  New ebuild, adds amr, enca and xvmc wrappers support
+
   03 Jul 2006; Thomas Cort <tcort@gentoo.org> mplayer-1.0.20060102.ebuild,
   mplayer-1.0.20060217.ebuild, mplayer-1.0.20060302.ebuild,
   mplayer-1.0.20060408.ebuild, mplayer-1.0.20060415.ebuild:
diff --git a/media-video/mplayer/files/digest-mplayer-1.0_pre8-r1 b/media-video/mplayer/files/digest-mplayer-1.0_pre8-r1
new file mode 100644
index 000000000000..fab3e15ad0b7
--- /dev/null
+++ b/media-video/mplayer/files/digest-mplayer-1.0_pre8-r1
@@ -0,0 +1,24 @@
+MD5 9b575d01f94f50dd4dcf570cd8a14dda 26104-510.zip 291836
+RMD160 0ff97a27fe5d08dd43571fd1982ce0f07bce3bca 26104-510.zip 291836
+SHA256 75fdf6416950c155ccbfd7fae4ffd6529f162ad6b427ab242c3e00685e303f46 26104-510.zip 291836
+MD5 607a14d090898ffb0f72c1aa6aa6ce31 26204-510.zip 246663
+RMD160 1b68232bc40d84298b134c57697e29a842e63ffd 26204-510.zip 246663
+SHA256 069ebd6ed8ef846d99bdd13d6c47fdb99fe5583b0ed5f405e1392a1a21a1b991 26204-510.zip 246663
+MD5 371fa9457f0f23295ddaa93b57d862a0 Blue-1.5.tar.bz2 222679
+RMD160 5c6b72c9ffeb247acb5a77bfeabf9329f29ff040 Blue-1.5.tar.bz2 222679
+SHA256 5bbcdea819643d99922e2ccc1b79bffb323650d78a7174f8b8d044d595a9789a Blue-1.5.tar.bz2 222679
+MD5 f82bb2bc51b6cd5e5dd96f88f6f98582 MPlayer-1.0pre8.tar.bz2 8166628
+RMD160 23fd13fe75a5c4029ead043aa4b3b08fe5fe44f0 MPlayer-1.0pre8.tar.bz2 8166628
+SHA256 4e611138efb3709e650e3770bb3f33609f3fd04047932c830e52a02e0e97efcc MPlayer-1.0pre8.tar.bz2 8166628
+MD5 d0afd83cd04c29a714a62b427aace5c5 font-arial-cp1250.tar.bz2 249705
+RMD160 a2fc7ae07b0d80936ea58e168e1047efccb9eb91 font-arial-cp1250.tar.bz2 249705
+SHA256 423a07e780bb130cd8e4730715545c5d919c248dda595aab7a0a01de3c83fd12 font-arial-cp1250.tar.bz2 249705
+MD5 1ecd31d17b51f16332b1fcc7da36b312 font-arial-iso-8859-1.tar.bz2 234242
+RMD160 666697cd5efd9387057a898c714175e7c2aacbcd font-arial-iso-8859-1.tar.bz2 234242
+SHA256 9730f481764f367c9089d0166fb6ccf9148808ffbbfeca635cf0e6db75765d29 font-arial-iso-8859-1.tar.bz2 234242
+MD5 7b47904a925cf58ea546ca15f3df160c font-arial-iso-8859-2.tar.bz2 222208
+RMD160 562d4d92c4f5f3d537340fde3ad8d1495ac41acb font-arial-iso-8859-2.tar.bz2 222208
+SHA256 71debfc960007c2f6242dfc91e8b1c005b30a99e129aeb00ab8c03f4371b41c1 font-arial-iso-8859-2.tar.bz2 222208
+MD5 3f1b9eb2ba639bf42c61f7b9189f6524 svgalib_helper-1.9.17-mplayer.tar.bz2 7234
+RMD160 e0c4ae039478732404dd743e250e1061cc9cf0a4 svgalib_helper-1.9.17-mplayer.tar.bz2 7234
+SHA256 016edd27d74b5c66481ddb4563c961fbb579e3a95dd846cc857a639df09999e5 svgalib_helper-1.9.17-mplayer.tar.bz2 7234
diff --git a/media-video/mplayer/mplayer-1.0_pre8-r1.ebuild b/media-video/mplayer/mplayer-1.0_pre8-r1.ebuild
new file mode 100644
index 000000000000..76e33eae6654
--- /dev/null
+++ b/media-video/mplayer/mplayer-1.0_pre8-r1.ebuild
@@ -0,0 +1,625 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mplayer/mplayer-1.0_pre8-r1.ebuild,v 1.1 2006/07/11 10:07:03 lu_zero Exp $
+
+inherit eutils flag-o-matic
+
+RESTRICT="nostrip"
+IUSE="3dfx 3dnow 3dnowext aac aalib alsa altivec amr arts bidi bl bindist
+cpudetection custom-cflags debug dga doc dts dvb cdparanoia directfb dvd dv
+dvdread encode esd fbcon gif ggi gtk ipv6 jack joystick jpeg libcaca
+lirc live livecd lzo mad matrox mmx mmxext musepack nas unicode vorbis
+opengl openal oss png real rtc samba sdl speex sse sse2 svga tga theora
+truetype v4l v4l2 win32codecs X x264 xanim xinerama xmms xv xvid xvmc"
+
+BLUV=1.5
+SVGV=1.9.17
+
+# Handle PREversions as well
+MY_P="MPlayer-${PV/_/}"
+S="${WORKDIR}/${MY_P}"
+AMR_URI="http://www.3gpp.org/ftp/Specs/archive"
+SRC_URI="mirror://mplayer/releases/${MY_P}.tar.bz2
+	mirror://mplayer/releases/fonts/font-arial-iso-8859-1.tar.bz2
+	mirror://mplayer/releases/fonts/font-arial-iso-8859-2.tar.bz2
+	mirror://mplayer/releases/fonts/font-arial-cp1250.tar.bz2
+	svga? ( http://mplayerhq.hu/~alex/svgalib_helper-${SVGV}-mplayer.tar.bz2 )
+	gtk? ( mirror://mplayer/Skin/Blue-${BLUV}.tar.bz2 )
+	amr? ( ${AMR_URI}/26_series/26.104/26104-510.zip
+		   ${AMR_URI}/26_series/26.204/26204-510.zip )"
+
+# Only install Skin if GUI should be build (gtk as USE flag)
+DESCRIPTION="Media Player for Linux "
+HOMEPAGE="http://www.mplayerhq.hu/"
+
+# 'encode' in USE for MEncoder.
+RDEPEND="xvid? ( >=media-libs/xvid-0.9.0 )
+	win32codecs? ( >=media-libs/win32codecs-20040916 )
+	x86? ( real? ( >=media-video/realplayer-10.0.3 ) )
+	aalib? ( media-libs/aalib )
+	alsa? ( media-libs/alsa-lib )
+	arts? ( kde-base/arts )
+	openal? ( media-libs/openal )
+	bidi? ( dev-libs/fribidi )
+	cdparanoia? ( media-sound/cdparanoia )
+	dga? ( || ( x11-libs/libXxf86dga virtual/x11 ) )
+	directfb? ( dev-libs/DirectFB )
+	dts? ( media-libs/libdts )
+	dvb? ( media-tv/linuxtv-dvb-headers )
+	dvd? ( dvdread? ( media-libs/libdvdread ) )
+	encode? (
+		media-sound/lame
+		dv? ( >=media-libs/libdv-0.9.5 )
+		x264? ( >=media-libs/x264-svn-20060612 )
+		)
+	esd? ( media-sound/esound )
+	enca? ( app-i18n/enca )
+	gif? ( media-libs/giflib )
+	ggi? ( media-libs/libggi )
+	gtk? (
+		media-libs/libpng
+		|| ( ( x11-libs/libXxf86vm
+				x11-libs/libXext
+				x11-libs/libXi
+			)
+			<virtual/x11-7
+		)
+		=x11-libs/gtk+-2*
+		=dev-libs/glib-2*
+		)
+	jpeg? ( media-libs/jpeg )
+	libcaca? ( media-libs/libcaca )
+	lirc? ( app-misc/lirc )
+	lzo? ( =dev-libs/lzo-1* )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-libs/libmpcdec-1.2.2 )
+	nas? ( media-libs/nas )
+	opengl? ( virtual/opengl )
+	png? ( media-libs/libpng )
+	samba? ( >=net-fs/samba-2.2.8a )
+	sdl? ( media-libs/libsdl )
+	speex? ( media-libs/speex )
+	svga? ( media-libs/svgalib )
+	theora? ( media-libs/libtheora )
+	live? ( >=media-plugins/live-2004.07.20 )
+	truetype? ( >=media-libs/freetype-2.1 )
+	xinerama? ( || ( ( x11-libs/libXinerama
+				x11-libs/libXxf86vm
+				x11-libs/libXext
+			)
+			<virtual/x11-7
+		)
+	)
+	xmms? ( media-sound/xmms )
+	xanim? ( >=media-video/xanim-2.80.1-r4 )
+	sys-libs/ncurses
+	xv? ( || ( ( x11-libs/libXv
+				x11-libs/libXxf86vm
+				x11-libs/libXext
+			)
+			<virtual/x11-7
+		)
+	)
+	xvmc? ( x11-libs/libXvMC )
+	X? ( || ( ( x11-libs/libXxf86vm
+				x11-libs/libXext
+			)
+			<virtual/x11-7
+		)
+	)"
+
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	doc? ( >=app-text/docbook-sgml-dtd-4.1.2
+		   app-text/docbook-xml-dtd
+		   >=app-text/docbook-xml-simple-dtd-1.50.0
+		   dev-libs/libxslt
+		   )
+	dga? ( || ( x11-proto/xf86dgaproto virtual/x11 ) )
+	xinerama? ( || ( x11-proto/xineramaproto virtual/x11 ) )
+	xv? ( || ( ( x11-proto/videoproto
+				x11-proto/xf86vidmodeproto
+			)
+			<virtual/x11-7
+		)
+	)
+	gtk? ( || ( ( x11-proto/xextproto
+				x11-proto/xf86vidmodeproto
+			)
+			<virtual/x11-7
+		)
+	)
+	X? ( || ( ( x11-proto/xextproto
+				x11-proto/xf86vidmodeproto
+			)
+			<virtual/x11-7
+		)
+	)
+	unicode? ( virtual/libiconv )"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc-macos ~ppc64 ~x86"
+
+pkg_setup() {
+	if use real && use x86; then
+		REALLIBDIR="/opt/RealPlayer/codecs"
+	fi
+}
+
+src_unpack() {
+
+	unpack ${MY_P}.tar.bz2 \
+		font-arial-iso-8859-1.tar.bz2 font-arial-iso-8859-2.tar.bz2 \
+		font-arial-cp1250.tar.bz2
+
+	use svga && unpack svgalib_helper-${SVGV}-mplayer.tar.bz2
+
+	use gtk && unpack Blue-${BLUV}.tar.bz2
+
+	use amr && unpack 26104-510.zip && unpack 26204-510.zip
+
+	# amr (float) support
+	if use amr; then
+		einfo "Including amr wide and narrow band (float) support ... "
+
+		# narrow band codec
+		mkdir ${S}/libavcodec/amr_float
+		cd ${S}/libavcodec/amr_float
+		unzip -q ${WORKDIR}/26104-510_ANSI_C_source_code.zip
+		# wide band codec
+		mkdir ${S}/libavcodec/amrwb_float
+		cd ${S}/libavcodec/amrwb_float
+		unzip -q ${WORKDIR}/26204-510_ANSI-C_source_code.zip
+	fi
+
+	cd ${S}
+
+	# Fix hppa compilation
+	[ "${ARCH}" = "hppa" ] && sed -i -e "s/-O4/-O1/" "${S}/configure"
+
+	if use svga
+	then
+		echo
+		einfo "Enabling vidix non-root mode."
+		einfo "(You need a proper svgalib_helper.o module for your kernel"
+		einfo " to actually use this)"
+		echo
+
+		mv ${WORKDIR}/svgalib_helper ${S}/libdha
+	fi
+
+	# Remove kernel-2.6 workaround as the problem it works around is
+	# fixed, and the workaround breaks sparc
+	use sparc && sed -i 's:#define __KERNEL__::' osdep/kerneltwosix.h
+
+	# minor fix
+	sed -i -e "s:-O4:-O4 -D__STDC_LIMIT_MACROS:" configure
+
+}
+
+linguas_warn() {
+	ewarn "Language ${LANG[0]} or ${LANG_CC} not avaliable"
+	ewarn "Language set to English"
+	ewarn "If this is a mistake, please set the"
+	ewarn "First LINGUAS language to one of the following"
+	ewarn
+	ewarn "bg - Bulgarian"
+	ewarn "cs - Czech"
+	ewarn "de - German"
+	ewarn "dk - Danish"
+	ewarn "el - Greek"
+	ewarn "en - English"
+	ewarn "es - Spanish"
+	ewarn "fr - French"
+	ewarn "hu - Hungarian"
+	ewarn "ja - Japanese"
+	ewarn "ko - Korean"
+	ewarn "mk - FYRO Macedonian"
+	ewarn "nl - Dutch"
+	ewarn "no - Norwegian"
+	ewarn "pl - Polish"
+	ewarn "pt_BR - Portuguese - Brazil"
+	ewarn "ro - Romanian"
+	ewarn "ru - Russian"
+	ewarn "sk - Slovak"
+	ewarn "tr - Turkish"
+	ewarn "uk - Ukranian"
+	ewarn "zh_CN - Chinese - China"
+	ewarn "zh_TW - Chinese - Taiwan"
+	export LINGUAS="en ${LINGUAS}"
+}
+
+src_compile() {
+
+	# have fun with LINGUAS variable
+	if [[ -n $LINGUAS ]]
+	then
+		# LINGUAS has stuff in it, start the logic
+		LANG=( $LINGUAS )
+		if [ -e ${S}/help/help_mp-${LANG[0]}.h ]
+		then
+			einfo "Setting MPlayer messages to language: ${LANG[0]}"
+		else
+			LANG_CC=${LANG[0]}
+			if [ ${#LANG_CC} -ge 2 ]
+			then
+				LANG_CC=${LANG_CC:0:2}
+				if [ -e ${S}/help/help_mp-${LANG_CC}.h ]
+				then
+					einfo "Setting MPlayer messages to language ${LANG_CC}"
+					export LINGUAS="${LANG_CC} ${LINGUAS}"
+				else
+					linguas_warn
+				fi
+			else
+				linguas_warn
+			fi
+		fi
+	else
+		# sending blank LINGUAS, make it default to en
+		einfo "No LINGUAS given, defaulting to English"
+		export LINGUAS="en ${LINGUAS}"
+	fi
+
+
+
+
+	local myconf="--disable-external-faad --disable-tv-bsdbt848"
+	myconf="${myconf} --disable-external-vidix"
+	################
+	#Optional features#
+	###############
+	if use cpudetection || use livecd || use bindist
+	then
+	myconf="${myconf} --enable-runtime-cpudetection"
+	fi
+
+	myconf="${myconf} $(use_enable bidi fribidi)"
+
+	if use unicode
+	then
+		myconf="${myconf} --charset=UTF-8"
+	else
+		myconf="${myconf} --charset=noconv"
+	fi
+
+	if use enca
+	then
+		myconf="${myconf} --enable-enca"
+	else
+		myconf="${myconf} --disable-enca"
+	fi
+
+	myconf="${myconf} $(use_enable cdparanoia)"
+
+	if use dvd
+	then
+		myconf="${myconf} $(use_enable dvdread) $(use_enable !dvdread mpdvdkit)"
+	else
+		myconf="${myconf} --disable-dvdread --disable-mpdvdkit"
+	fi
+
+	if use encode
+	then
+		myconf="${myconf} --enable-mencoder $(use_enable dv libdv) \
+											$(use_enable x264)"
+	else
+		myconf="${myconf} --disable-mencoder --disable-libdv --disable-x264"
+	fi
+
+	myconf="${myconf} $(use_enable gtk gui)"
+
+	if use !gtk && use !X && use !xv && use !xinerama
+	then
+		myconf="${myconf} --disable-gui --disable-x11 --disable-xv --disable-xmga --disable-xinerama --disable-vm --disable-xvmc"
+	else
+		#note we ain't touching --enable-vm.  That should be locked down in the future.
+		myconf="${myconf} --enable-x11 $(use_enable xinerama) $(use_enable xv) $(use_enable gtk gui)"
+	fi
+
+	# this looks like a hack, but the
+	# --enable-dga needs a paramter, but there's no surefire
+	# way to tell what it is.. so I'm letting MPlayer decide
+	# the enable part
+	if ! use dga && ! use 3dfx
+	then
+		myconf="${myconf} --disable-dga"
+	fi
+	# disable png *only* if gtk && png aren't on
+	if use png || use gtk
+	then
+		myconf="${myconf} --enable-png"
+	else
+		myconf="${myconf} --disable-png"
+	fi
+	myconf="${myconf} $(use_enable ipv6 inet6)"
+	myconf="${myconf} $(use_enable joystick)"
+	myconf="${myconf} $(use_enable lirc)"
+	myconf="${myconf} $(use_enable live)"
+	myconf="${myconf} $(use_enable rtc)"
+	myconf="${myconf} $(use_enable samba smb)"
+	myconf="${myconf} $(use_enable truetype freetype)"
+	myconf="${myconf} $(use_enable v4l tv-v4l)"
+	myconf="${myconf} $(use_enable v4l2 tv-v4l2)"
+	use jack || myconf="${myconf} --disable-jack"
+
+	#########
+	# Codecs #
+	########
+	myconf="${myconf} $(use_enable gif)"
+	myconf="${myconf} $(use_enable jpeg)"
+	#myconf="${myconf} $(use_enable ladspa)"
+	myconf="${myconf} $(use_enable dts libdts)"
+	myconf="${myconf} $(use_enable lzo liblzo)"
+	myconf="${myconf} $(use_enable musepack)"
+	myconf="${myconf} $(use_enable aac internal-faad)"
+	myconf="${myconf} $(use_enable vorbis)"
+	myconf="${myconf} $(use_enable theora)"
+	use speex || myconf="${myconf} --disable-speex"
+	myconf="${myconf} $(use_enable xmms)"
+	myconf="${myconf} $(use_enable xvid)"
+	use x86 && myconf="${myconf} $(use_enable real)"
+	myconf="${myconf} $(use_enable win32codecs win32)"
+
+	#############
+	# Video Output #
+	#############
+	myconf="${myconf} $(use_enable 3dfx)"
+	if use 3dfx
+	then
+		myconf="${myconf} --enable-tdfxvid"
+	else
+		myconf="${myconf} --disable-tdfxvid"
+	fi
+	if use fbcon && use 3dfx
+	then
+		myconf="${myconf} --enable-tdfxfb"
+	else
+		myconf="${myconf} --disable-tdfxfb"
+	fi
+
+	if use dvb
+	then
+		myconf="${myconf} --enable-dvbhead --with-dvbincdir=/usr/include"
+	else
+		myconf="${myconf} --disable-dvbhead"
+	fi
+
+	use aalib || myconf="${myconf} --disable-aa"
+	myconf="${myconf} $(use_enable directfb)"
+	myconf="${myconf} $(use_enable fbcon fbdev)"
+	myconf="${myconf} $(use_enable ggi)"
+	myconf="${myconf} $(use_enable libcaca caca)"
+	if use matrox && use X
+	then
+		myconf="${myconf} $(use_enable matrox xmga)"
+	fi
+	myconf="${myconf} $(use_enable matrox mga)"
+	myconf="${myconf} $(use_enable opengl gl)"
+	myconf="${myconf} $(use_enable sdl)"
+
+	if use svga
+	then
+		myconf="${myconf} --enable-svga"
+	else
+		myconf="${myconf} --disable-svga --disable-internal-vidix"
+	fi
+
+	myconf="${myconf} $(use_enable tga)"
+
+	if use xvmc
+	then
+		myconf="${myconf} --enable-xvmc --with-xvmclib=XvMCW"
+	else
+		myconf="${myconf} --disable-xvmc"
+	fi
+
+	#############
+	# Audio Output #
+	#############
+	use alsa || myconf="${myconf} --disable-alsa"
+	use arts || myconf="${myconf} --disable-arts"
+	use esd || myconf="${myconf} --disable-esd"
+	use mad || myconf="${myconf} --disable-mad"
+	use nas || myconf="${myconf} --disable-nas"
+	use openal || myconf="${myconf} --disable-openal"
+	use oss || myconf="${myconf} --disable-ossaudio"
+
+	#################
+	# Advanced Options #
+	#################
+	# Platform specific flags, hardcoded on amd64 (see below)
+	use x86 && myconf="${myconf} $(use_enable 3dnow)"
+	use x86 && myconf="${myconf} $(use_enable 3dnowext)";
+	use x86 && myconf="${myconf} $(use_enable sse)"
+	use x86 && myconf="${myconf} $(use_enable sse2)"
+	use x86 && myconf="${myconf} $(use_enable mmx)"
+	use x86 && myconf="${myconf} $(use_enable mmxext)"
+	use debug && myconf="${myconf} --enable-debug=3"
+
+	# mplayer now contains SIMD assembler code for amd64
+	# AMD64 Team decided to hardenable SIMD assembler for all users
+	# Danny van Dyk <kugelfang@gentoo.org> 2005/01/11
+	if use amd64; then
+		myconf="${myconf} --enable-3dnow --enable-3dnowext --enable-sse --enable-sse2 --enable-mmx --enable-mmxext"
+	fi
+
+	if use ppc64
+	then
+		myconf="${myconf} --disable-altivec"
+	else
+		myconf="${myconf} $(use_enable altivec)"
+		use altivec && append-flags -maltivec -mabi=altivec
+	fi
+
+
+	if use xanim
+	then
+		myconf="${myconf} --with-xanimlibdir=/usr/lib/xanim/mods"
+	fi
+
+	if [ -e /dev/.devfsd ]
+	then
+		myconf="${myconf} --enable-linux-devfs"
+	fi
+
+	use xmms && myconf="${myconf} --with-xmmslibdir=/usr/$(get_libdir)"
+
+	use live && myconf="${myconf} --with-livelibdir=/usr/$(get_libdir)/live"
+
+	# support for blinkenlights
+	use bl && myconf="${myconf} --enable-bl"
+
+	#leave this in place till the configure/compilation borkage is completely corrected back to pre4-r4 levels.
+	# it's intended for debugging so we can get the options we configure mplayer w/, rather then hunt about.
+	# it *will* be removed asap; in the meantime, doesn't hurt anything.
+	echo "${myconf}" > ${T}/configure-options
+
+	if use custom-cflags
+	then
+	# let's play the filtration game!  MPlayer hates on all!
+	strip-flags
+	# ugly optimizations cause MPlayer to cry on x86 systems!
+		if use x86 ; then
+			replace-flags -O0 -O2
+			replace-flags -O3 -O2
+			filter-flags -fPIC -fPIE
+		fi
+	append-flags -D__STDC_LIMIT_MACROS
+	else
+	unset CFLAGS CXXFLAGS
+	fi
+
+	CFLAGS="$CFLAGS" ./configure \
+		--prefix=/usr \
+		--confdir=/usr/share/mplayer \
+		--datadir=/usr/share/mplayer \
+		--enable-largefiles \
+		--enable-menu \
+		--enable-network --enable-ftp \
+		--with-reallibdir=${REALLIBDIR} \
+		--with-x11incdir=/usr/X11R6/include \
+		--disable-external-faad \
+		${myconf} || die
+
+	# we run into problems if -jN > -j1
+	# see #86245
+	MAKEOPTS="${MAKEOPTS} -j1"
+
+	einfo "Make"
+	emake || die "Failed to build MPlayer!"
+	use doc && make -C DOCS/xml html-chunked
+	einfo "Make completed"
+}
+
+src_install() {
+
+	einfo "Make install"
+	make prefix=${D}/usr \
+		 BINDIR=${D}/usr/bin \
+		 LIBDIR=${D}/usr/$(get_libdir) \
+		 CONFDIR=${D}/usr/share/mplayer \
+		 DATADIR=${D}/usr/share/mplayer \
+		 MANDIR=${D}/usr/share/man \
+		 install || die "Failed to install MPlayer!"
+	einfo "Make install completed"
+
+	dodoc AUTHORS ChangeLog README
+	# Install the documentation; DOCS is all mixed up not just html
+	if use doc ; then
+		find "${S}/DOCS" -type d | xargs -- chmod 0755
+		find "${S}/DOCS" -type f | xargs -- chmod 0644
+		cp -r "${S}/DOCS" "${D}/usr/share/doc/${PF}/" || die
+	fi
+
+	# Copy misc tools to documentation path, as they're not installed directly
+	# and yes, we are nuking the +x bit.
+	find "${S}/TOOLS" -type d | xargs -- chmod 0755
+	find "${S}/TOOLS" -type f | xargs -- chmod 0644
+	cp -r "${S}/TOOLS" "${D}/usr/share/doc/${PF}/" || die
+
+	# Install the default Skin and Gnome menu entry
+	if use gtk; then
+		dodir /usr/share/mplayer/Skin
+		cp -r ${WORKDIR}/Blue ${D}/usr/share/mplayer/Skin/default || die
+
+		# Fix the symlink
+		rm -rf ${D}/usr/bin/gmplayer
+		dosym mplayer /usr/bin/gmplayer
+
+		insinto /usr/share/pixmaps
+		newins ${S}/Gui/mplayer/pixmaps/logo.xpm mplayer.xpm
+		insinto /usr/share/applications
+		doins ${FILESDIR}/mplayer.desktop
+	fi
+
+	dodir /usr/share/mplayer/fonts
+	local x=
+	# Do this generic, as the mplayer people like to change the structure
+	# of their zips ...
+	for x in $(find ${WORKDIR}/ -type d -name 'font-arial-*')
+	do
+		cp -pPR ${x} ${D}/usr/share/mplayer/fonts
+	done
+	# Fix the font symlink ...
+	rm -rf ${D}/usr/share/mplayer/font
+	dosym fonts/font-arial-14-iso-8859-1 /usr/share/mplayer/font
+
+	insinto /etc
+	newins ${S}/etc/example.conf mplayer.conf
+	dosed -e 's/include =/#include =/' /etc/mplayer.conf
+	dosed -e 's/fs=yes/fs=no/' /etc/mplayer.conf
+	dosym ../../../etc/mplayer.conf /usr/share/mplayer/mplayer.conf
+
+	#mv the midentify script to /usr/bin for emovix.
+	cp ${D}/usr/share/doc/${PF}/TOOLS/midentify ${D}/usr/bin
+	chmod a+x ${D}/usr/bin/midentify
+
+	insinto /usr/share/mplayer
+	doins ${S}/etc/codecs.conf
+	doins ${S}/etc/input.conf
+	doins ${S}/etc/menu.conf
+}
+
+pkg_preinst() {
+
+	if [ -d "${ROOT}/usr/share/mplayer/Skin/default" ]
+	then
+		rm -rf ${ROOT}/usr/share/mplayer/Skin/default
+	fi
+}
+
+pkg_postinst() {
+
+	if use matrox; then
+		depmod -a &>/dev/null || :
+	fi
+
+	if use alsa ; then
+		einfo "For those using alsa, please note the ao driver name is no longer"
+		einfo "alsa9x or alsa1x.  It is now just 'alsa' (omit quotes)."
+		einfo "The syntax for optional drivers has also changed.  For example"
+		einfo "if you use a dmix driver called 'dmixer,' use"
+		einfo "ao=alsa:device=dmixer instead of ao=alsa:dmixer"
+		einfo "Some users may not need to specify the extra driver with the ao="
+		einfo "command."
+	fi
+}
+
+pkg_postrm() {
+
+	# Cleanup stale symlinks
+	if [ -L ${ROOT}/usr/share/mplayer/font -a \
+	     ! -e ${ROOT}/usr/share/mplayer/font ]
+	then
+		rm -f ${ROOT}/usr/share/mplayer/font
+	fi
+
+	if [ -L ${ROOT}/usr/share/mplayer/subfont.ttf -a \
+	     ! -e ${ROOT}/usr/share/mplayer/subfont.ttf ]
+	then
+		rm -f ${ROOT}/usr/share/mplayer/subfont.ttf
+	fi
+}
+