Version bump. Move to EAPI=2, make gconf non-optional, gtk+ flag for gdk support in thumbnailer.

(Portage version: 2.2_rc42/cvs/Linux x86_64)

3 files changed, 93 insertions, 1 deletions

diff --git a/gnome-extra/libgsf/ChangeLog b/gnome-extra/libgsf/ChangeLog
index 0486ae6d0d78..0fbbd8c99df6 100644
--- a/gnome-extra/libgsf/ChangeLog
+++ b/gnome-extra/libgsf/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/libgsf
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgsf/ChangeLog,v 1.142 2009/10/16 23:16:22 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgsf/ChangeLog,v 1.143 2009/10/19 21:14:39 eva Exp $
+
+*libgsf-1.14.16 (19 Oct 2009)
+
+  19 Oct 2009; Gilles Dartiguelongue <eva@gentoo.org +libgsf-1.14.16.ebuild,
+  metadata.xml:
+  Version bump. Move to EAPI=2, make gconf non-optional, gtk+ flag for gdk
+  support in thumbnailer.
 
   16 Oct 2009; Markus Meier <maekke@gentoo.org> libgsf-1.14.15.ebuild:
   x86 stable, bug #281427
diff --git a/gnome-extra/libgsf/libgsf-1.14.16.ebuild b/gnome-extra/libgsf/libgsf-1.14.16.ebuild
new file mode 100644
index 000000000000..c35465267102
--- /dev/null
+++ b/gnome-extra/libgsf/libgsf-1.14.16.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgsf/libgsf-1.14.16.ebuild,v 1.1 2009/10/19 21:14:39 eva Exp $
+
+EAPI="2"
+GCONF_DEBUG="no"
+
+inherit eutils gnome2 python multilib
+
+DESCRIPTION="The GNOME Structured File Library"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="bzip2 doc gnome gtk python"
+
+# FIXME: gconf is actually automagic and only needed for thumbnailer
+RDEPEND="
+	>=dev-libs/glib-2.16
+	>=dev-libs/libxml2-2.4.16
+	>=gnome-base/gconf-2
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	gnome? (
+		>=gnome-base/libbonobo-2
+		>=gnome-base/gnome-vfs-2.2 )
+	gtk? ( >=x11-libs/gtk+-2 )
+	python? (
+		>=dev-python/pygobject-2.10
+		>=dev-python/pygtk-2.10 )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	>=dev-util/intltool-0.35.0
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+PDEPEND="gnome? ( media-gfx/imagemagick )"
+
+DOCS="AUTHORS BUGS ChangeLog HACKING NEWS README TODO"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--with-gio
+		--disable-static
+		$(use_with bzip2 bz2)
+		$(use_with gnome gnome-vfs)
+		$(use_with gnome bonobo)
+		$(use_with python)
+		$(use_with gtk gdk-pixbuf)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# disable pyc compiling
+	mv py-compile py-compile.orig
+	ln -s $(type -P true) py-compile
+}
+
+pkg_preinst() {
+	gnome2_pkg_preinst
+	preserve_old_lib /usr/$(get_libdir)/libgsf-1.so.1
+	preserve_old_lib /usr/$(get_libdir)/libgsf-gnome-1.so.1
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	if use python; then
+		python_need_rebuild
+		python_mod_optimize $(python_get_sitedir)/gsf
+	fi
+
+	preserve_old_lib_notify /usr/$(get_libdir)/libgsf-1.so.1
+	preserve_old_lib_notify /usr/$(get_libdir)/libgsf-gnome-1.so.1
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/gsf
+}
diff --git a/gnome-extra/libgsf/metadata.xml b/gnome-extra/libgsf/metadata.xml
index da6fd63d0085..43c4f8a3a929 100644
--- a/gnome-extra/libgsf/metadata.xml
+++ b/gnome-extra/libgsf/metadata.xml
@@ -2,4 +2,8 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>gnome</herd>
+<use>
+	<flag name="gtk">Enable use of gdk in thumbnailer</flag>
+	<!-- <flag name="thumbnail">Enable libgsf supported formats thumbnailer</flag> -->
+</use>
 </pkgmetadata>