Version bump for Gnome 2.32

(Portage version: 2.1.9.14/cvs/Linux x86_64)

3 files changed, 78 insertions, 1 deletions

diff --git a/gnome-base/libgnome/ChangeLog b/gnome-base/libgnome/ChangeLog
index fb22b64db680..1ef2d4ff72eb 100644
--- a/gnome-base/libgnome/ChangeLog
+++ b/gnome-base/libgnome/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for gnome-base/libgnome
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome/ChangeLog,v 1.197 2010/10/07 21:41:23 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome/ChangeLog,v 1.198 2010/10/12 18:26:11 pacho Exp $
+
+*libgnome-2.32.0 (12 Oct 2010)
+
+  12 Oct 2010; Pacho Ramos <pacho@gentoo.org> +libgnome-2.32.0.ebuild,
+  metadata.xml:
+  Version bump for Gnome 2.32: gnome-sound APIs now use libcanberra
+  internally (behind 'sound' USE flag, enabled by default for better user
+  experience).
 
   07 Oct 2010; Samuli Suominen <ssuominen@gentoo.org>
   libgnome-2.30.0.ebuild:
diff --git a/gnome-base/libgnome/libgnome-2.32.0.ebuild b/gnome-base/libgnome/libgnome-2.32.0.ebuild
new file mode 100644
index 000000000000..ea70344103c0
--- /dev/null
+++ b/gnome-base/libgnome/libgnome-2.32.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome/libgnome-2.32.0.ebuild,v 1.1 2010/10/12 18:26:11 pacho Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+
+inherit gnome2 eutils
+
+DESCRIPTION="Essential Gnome Libraries"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+IUSE="branding doc esd +sound"
+
+SRC_URI="${SRC_URI}
+	branding? ( mirror://gentoo/gentoo-gdm-theme-r3.tar.bz2 )"
+
+RDEPEND=">=gnome-base/gconf-2
+	>=dev-libs/glib-2.16
+	>=gnome-base/gnome-vfs-2.5.3
+	>=gnome-base/libbonobo-2.13
+	>=dev-libs/popt-1.7
+	sound? ( media-libs/libcanberra )
+	esd? (
+		>=media-sound/esound-0.2.26
+		>=media-libs/audiofile-0.2.3 )"
+
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.17
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+PDEPEND="gnome-base/gvfs"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-schemas-install
+		$(use_enable esd)
+		$(use_enable sound canberra)"
+	DOCS="AUTHORS ChangeLog NEWS README"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Make sure menus have icons. People don't like change
+	epatch "${FILESDIR}/${PN}-2.28.0-menus-have-icons.patch"
+
+	use branding && epatch "${FILESDIR}"/${PN}-2.26.0-branding.patch
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use branding; then
+		# Add gentoo backgrounds
+		dodir /usr/share/pixmaps/backgrounds/gnome/gentoo
+		insinto /usr/share/pixmaps/backgrounds/gnome/gentoo
+		doins "${WORKDIR}"/gentoo-emergence/gentoo-emergence.png || die "doins 1 failed"
+		doins "${WORKDIR}"/gentoo-cow/gentoo-cow-alpha.png || die "doins 2 failed"
+	fi
+}
diff --git a/gnome-base/libgnome/metadata.xml b/gnome-base/libgnome/metadata.xml
index da6fd63d0085..550423e1b55b 100644
--- a/gnome-base/libgnome/metadata.xml
+++ b/gnome-base/libgnome/metadata.xml
@@ -2,4 +2,8 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>gnome</herd>
+<use>
+	<flag name='sound'>Enable sound using
+	<pkg>media-libs/libcanberra</pkg></flag>
+</use>
 </pkgmetadata>