version bump - ebuild submitted by Merlijn Hofstra via bug #287260

(Portage version: 2.1.6.13/cvs/Linux i686)

2 files changed, 138 insertions, 1 deletions

diff --git a/games-fps/nexuiz/ChangeLog b/games-fps/nexuiz/ChangeLog
index 1326ff8f1a4e..67ce355b24d2 100644
--- a/games-fps/nexuiz/ChangeLog
+++ b/games-fps/nexuiz/ChangeLog
@@ -1,6 +1,9 @@
 # ChangeLog for games-fps/nexuiz
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/ChangeLog,v 1.34 2009/08/24 12:25:52 nyhm Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/ChangeLog,v 1.35 2009/10/03 03:44:51 mr_bones_ Exp $
+
+  03 Oct 2009; Michael Sterrett <mr_bones_@gentoo.org> +nexuiz-2.5.2.ebuild:
+  version bump - ebuild submitted by Merlijn Hofstra via bug #287260
 
 *nexuiz-2.5.1-r1 (24 Aug 2009)
 
diff --git a/games-fps/nexuiz/nexuiz-2.5.2.ebuild b/games-fps/nexuiz/nexuiz-2.5.2.ebuild
new file mode 100644
index 000000000000..5c4a9d404de9
--- /dev/null
+++ b/games-fps/nexuiz/nexuiz-2.5.2.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/nexuiz-2.5.2.ebuild,v 1.1 2009/10/03 03:44:51 mr_bones_ Exp $
+
+EAPI=2
+inherit eutils games
+
+MY_PN=Nexuiz
+MY_P=${PN}-${PV//./}
+MAPS=nexmappack_r2
+DESCRIPTION="Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
+HOMEPAGE="http://www.nexuiz.com/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.zip
+	maps? ( mirror://sourceforge/${PN}/${MAPS}.zip )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa dedicated maps opengl sdl"
+
+UIRDEPEND="media-libs/libogg
+	media-libs/libvorbis
+	media-libs/libtheora
+	media-libs/libpng
+	media-libs/libmodplug
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXxf86dga
+	x11-libs/libXxf86vm
+	virtual/opengl
+	alsa? ( media-libs/alsa-lib )
+	sdl? ( media-libs/libsdl[joystick,video] )"
+UIDEPEND="x11-proto/xextproto
+	x11-proto/xf86dgaproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xproto"
+RDEPEND="media-libs/jpeg
+	net-misc/curl
+	opengl? ( ${UIRDEPEND} )
+	!dedicated? ( !opengl? ( ${UIRDEPEND} ) )"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	opengl? ( ${UIDEPEND} )
+	!dedicated? ( !opengl? ( ${UIDEPEND} ) )"
+
+S=${WORKDIR}/darkplaces
+
+src_unpack() {
+	unpack ${MY_P}.zip
+
+	local f
+	for f in "${MY_PN}"/sources/*.zip ; do
+		unpack ./${f}
+	done
+
+	if use maps ; then
+		cd "${WORKDIR}"/${MY_PN}
+		unpack ${MAPS}.zip
+	fi
+}
+
+src_prepare() {
+	# Make the game automatically look in the correct data directory
+	sed -i \
+		-e "/^CC=/d" \
+		-e "s:-O2:${CFLAGS}:" \
+		-e "/-lm/s:$: ${LDFLAGS}:" \
+		-e '/^STRIP/s/strip/true/' \
+		makefile.inc \
+		|| die "sed failed"
+
+	sed -i \
+		-e '1i DP_LINK_TO_LIBJPEG=1' \
+		-e "s:ifdef DP_.*:DP_FS_BASEDIR=${GAMES_DATADIR}/nexuiz\n&:" \
+		makefile \
+		|| die "sed failed"
+
+	if ! use alsa ; then
+		sed -i \
+			-e "/DEFAULT_SNDAPI/s:ALSA:OSS:" \
+			makefile \
+			|| die "sed failed"
+	fi
+}
+
+src_compile() {
+	if use opengl || ! use dedicated ; then
+		emake cl-${PN} || die "emake cl-${PN} failed"
+		if use sdl ; then
+			emake sdl-${PN} || die "emake sdl-${PN} failed"
+		fi
+	fi
+
+	if use dedicated ; then
+		emake sv-${PN} || die "emake sv-${PN} failed"
+	fi
+}
+
+src_install() {
+	if use opengl || ! use dedicated ; then
+		dogamesbin ${PN}-glx || die "dogamesbin glx failed"
+		doicon ${PN}.xpm
+		make_desktop_entry ${PN}-glx "Nexuiz (GLX)"
+		if use sdl ; then
+			dogamesbin ${PN}-sdl || die "dogamesbin sdl failed"
+			make_desktop_entry ${PN}-sdl "Nexuiz (SDL)"
+			dosym ${PN}-sdl "${GAMES_BINDIR}"/${PN}
+		else
+			dosym ${PN}-glx "${GAMES_BINDIR}"/${PN}
+		fi
+	fi
+
+	if use dedicated ; then
+		dogamesbin ${PN}-dedicated || die "dogamesbin dedicated failed"
+	fi
+
+	cd "${WORKDIR}"/${MY_PN}
+
+	dodoc Docs/*.txt
+	dohtml -r readme.html Docs
+
+	insinto "${GAMES_DATADIR}"/${PN}
+
+	if use dedicated ; then
+		doins -r server || die "doins server failed"
+	fi
+
+	doins -r data || die "doins data failed"
+	doins -r havoc || die "doins havoc failed"
+
+	prepgamesdirs
+}