re-add to appease old ipythons and an even older revdep needing a stabled arm

(Portage version: 2.2.14/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key 0xB8072B0D)

3 files changed, 126 insertions, 1 deletions

diff --git a/dev-python/pyzmq/ChangeLog b/dev-python/pyzmq/ChangeLog
index c189e618e230..33de456daf47 100644
--- a/dev-python/pyzmq/ChangeLog
+++ b/dev-python/pyzmq/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/pyzmq
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyzmq/ChangeLog,v 1.58 2014/12/08 07:01:57 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyzmq/ChangeLog,v 1.59 2014/12/08 10:08:48 idella4 Exp $
+
+*pyzmq-14.3.1 (08 Dec 2014)
+*pyzmq-13.1.0 (08 Dec 2014)
+
+  08 Dec 2014; Ian Delaney <idella4@gentoo.org> +pyzmq-13.1.0.ebuild,
+  +pyzmq-14.3.1.ebuild:
+  re-add to appease old ipythons and an even older revdep needing a stabled arm
 
   08 Dec 2014; Ian Delaney <idella4@gentoo.org> pyzmq-14.4.1.ebuild:
   set REQUIRED_USE for test, rm old
diff --git a/dev-python/pyzmq/pyzmq-13.1.0.ebuild b/dev-python/pyzmq/pyzmq-13.1.0.ebuild
new file mode 100644
index 000000000000..7890e76356ee
--- /dev/null
+++ b/dev-python/pyzmq/pyzmq-13.1.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyzmq/pyzmq-13.1.0.ebuild,v 1.11 2014/12/08 10:08:48 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
+
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="PyZMQ is a lightweight and super-fast messaging library built on top of the ZeroMQ library"
+HOMEPAGE="http://www.zeromq.org/bindings:python http://pypi.python.org/pypi/pyzmq"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="amd64 arm x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="examples green test"
+
+PY2_USEDEP=$(python_gen_usedep 'python2*')
+
+RDEPEND=">=net-libs/zeromq-2.1.9
+	green? ( dev-python/gevent[${PY2_USEDEP}] )"
+DEPEND="${RDEPEND}
+	test? (
+		!arm? ( dev-python/cffi[${PYTHON_USEDEP}] )
+		dev-python/nose[${PY2_USEDEP}]
+		dev-python/gevent[${PY2_USEDEP}]
+		dev-python/cython[${PY2_USEDEP}]
+	)"
+
+# Configure checks write to cwd.
+# https://github.com/zeromq/pyzmq/issues/318
+DISTUTILS_IN_SOURCE_BUILD=1
+
+REQUIRED_USE="test? ( !arm )"
+
+python_configure_all() {
+	tc-export CC
+}
+
+python_compile() {
+	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	if [[ "${EPYTHON}" == python3* ]]; then
+		einfo "Skipping python3 due to many incompatibilities"
+	else
+		nosetests -svw build/lib/ || die "Tests fail with ${EPYTHON}"
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
diff --git a/dev-python/pyzmq/pyzmq-14.3.1.ebuild b/dev-python/pyzmq/pyzmq-14.3.1.ebuild
new file mode 100644
index 000000000000..e46039ca2646
--- /dev/null
+++ b/dev-python/pyzmq/pyzmq-14.3.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyzmq/pyzmq-14.3.1.ebuild,v 1.6 2014/12/08 10:08:48 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="PyZMQ is a lightweight and super-fast messaging library built on top of the ZeroMQ library"
+HOMEPAGE="http://www.zeromq.org/bindings:python http://pypi.python.org/pypi/pyzmq"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples green test"
+
+PY2_USEDEP=$(python_gen_usedep python2_7)
+RDEPEND=">=net-libs/zeromq-2.1.9
+	dev-python/py[${PYTHON_USEDEP}]
+	dev-python/cffi[${PYTHON_USEDEP}]
+	green? ( dev-python/gevent[${PY2_USEDEP}] )"
+DEPEND="test? ( ${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+python_configure_all() {
+	tc-export CC
+}
+
+python_prepare_all() {
+	sed -e s':intersphinx_mapping:#&:' -i docs/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_compile() {
+	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	if python_is_python3; then
+		einfo "Skipping python3 due to lack of support by gevent"
+	else
+		nosetests -svw "${BUILD_DIR}/lib/"
+	fi
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( examples/. )
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}